Wolfram 语言与系统参考资料中心

URLFetchAsynchronous

在版本 11 中，URLFetchAsynchronous 已经被 URLSubmit 取代.

URLFetchAsynchronous["url",func]

在后台中执行链接，当发起事件时，调用 func.

更多信息和选项

可能发起的事件类型：

	"data"	返回字节列表，并且表明连接已经完成
	"progress"	返回关于形如 {dlnow,dltotal,ulnow,ultotal} 的当前链接的信息
	"error"	表明当尝试连接到 URL 时出现错误
	"headers"	从网络服务器接收到的头部
	"cookies"	所有已知 cookies 的列表
	"statuscode"	服务器所返回的状态代码

可以给出下列选项：

Method	"GET"	用于请求的方法
"Parameters"	{}	发送给请求的参数
"Body"	""	发送的消息体内容
"MultipartElements"	{}	发送的多部分数据元素的列表
"Username"	""	用于请求的用户名
"Password"	""	用于请求的密码
"Headers"	{}	手动发送给 HTTP 服务器的头部
"Cookies"	Automatic	是否存储接收到的 cookie
"StoreCookies"	True	传递给服务器的cookie
"VerifyPeer"	True	使用 SSL 证明验证身份
"UserAgent"	Automatic	发送的用户代理字符串
"ReadTimeout"	0	允许用于上传或者下载数据的时间
"ConnectTimeout"	0	允许连接服务器的时间
"Progress"	False	是否发起 "progress" 事件
"Transfer"	Automatic	如果 Automatic，"data" 事件返回一次，并且返回所有下载的数据；如果 "Chunks"，将从上一次事件开始多次发起具有下载数据的 "data"事件
"UserData"	None	传递给该选项的任意表达式将存储用于在事件函数内使用的AsynchronousTaskObject；数据可以通过检查传递给事件函数的选项 AsynchronousTaskObject 找到
"FollowRedirects"	True	是否重定向

默认情况下，允许的时间以秒为单位给出.
多部分元素的格式为 {"name","mimetype"}->val，其中 val 是一个字符串或者字节列表.
当发起一个事件时，将执行传递给 URLFetchAsynchronous 的事件函数 . 将有三个参数被传递给事件函数，分别是：AsynchronousTaskObject、事件名称和从事件获取到的数据. 事件函数是处理从 URLFetchAsynchronous 获取的数据的唯一方法.

范例

打开所有单元关闭所有单元

基本范例 (3)

这里打开一个对话框，当下载完成时：

Wolfram Language code:

url = "wolfram.com";
func = Function[{asyncObj, eventType, document}, If[eventType === "data", MessageDialog["Finished downloading " <> url]]];
URLFetchAsynchronous[url, func]

存储头部和 cookies：

Wolfram Language code:

headers = {};
cookies = {};
eventFunction[_, "headers", data_] := headers = data
eventFunction[_, "cookies", data_] := cookies = data
URLFetchAsynchronous["wolfram.com", eventFunction]

Wolfram Language code:

headers
cookies

使用状态代码和错误事件来判断 URL 的可用性：

Wolfram Language code:

statusList = {};
statusFunction[async_, "statuscode", status_] := AppendTo[statusList, {async, status}]
statusFunction[async_, "error", errorStr_] := AppendTo[statusList, {async, errorStr}]
	
URLFetchAsynchronous["http://wolfram.com", statusFunction]
URLFetchAsynchronous["http://wolframalpha.com", statusFunction]
URLFetchAsynchronous["http://notreal", statusFunction]

Wolfram Language code: statusList

选项 (16)

"Method" (1)

"Method" 可用以指定链接所使用的 HTTP 方法：

Wolfram Language code:

headerData;
eventFunction[_, "headers", headers_] := headerData = headers
URLFetchAsynchronous["http://wolfram.com", eventFunction, "Method" -> "HEAD"]

Wolfram Language code: headerData

"Parameters" (1)

指定应该发送到服务器的参数：

Wolfram Language code:

contentData;
eventFunction[_, "data", data_] := contentData = data
URLFetchAsynchronous["http://exampledata.wolfram.com/httpget.php", eventFunction, "Parameters" -> {"name" -> "Joe", "age" -> "30"}]

Wolfram Language code: FromCharacterCode[contentData]

"VerifyPeer" (1)

验证服务器所使用的 SSL 证书是有效的：

Wolfram Language code:

statusData;
eventFunction[_, "statuscode", status_] := statusData = status;
URLFetchAsynchronous["https://wolfram.com", eventFunction, "VerifyPeer" -> True]

Wolfram Language code: statusData

"Username" (1)

指定应该发送到服务器的用户名：

Wolfram Language code:

contentData;
eventFunction[_, "data", data_] := contentData = data
URLFetchAsynchronous["http://exampledata.wolfram.com/authentication.php", eventFunction, "Username" -> "Joe", "Password" -> ""]

Wolfram Language code: FromCharacterCode[contentData]

"Password" (1)

指定应该发送到服务器的密码：

Wolfram Language code:

contentData;
eventFunction[_, "data", data_] := contentData = data
URLFetchAsynchronous["http://exampledata.wolfram.com/authentication.php", eventFunction, "Username" -> "Joe", "Password" -> "topsecret"]

Wolfram Language code: FromCharacterCode[contentData]

"UserAgent" (1)

指定应该发送给服务器的用户代理：

Wolfram Language code:

contentData;
eventFunction[_, "data", data_] := contentData = data
URLFetchAsynchronous["http://exampledata.wolfram.com/useragent.php", eventFunction, "UserAgent" -> "Web Browser"]

Wolfram Language code: FromCharacterCode[contentData]

"Cookies" (1)

手动控制 URLFetchAsynchronous 所使用的 cookie：

Wolfram Language code:

contentData;
eventFunction[_, "data", data_] := contentData = data
URLFetchAsynchronous["http://exampledata.wolfram.com/cookies.php", eventFunction, "Cookies" -> {{"Domain" -> ".exampledata.wolfram.com", "Path" -> "/", "Secure" -> "FALSE", "Expires" -> DateString[{2020, 1, 1, 0, 0, 0}], "Name" -> "MyCookie", "Value" -> "CookieData"}}]

Wolfram Language code: FromCharacterCode[contentData]

"StoreCookies" (1)

如果 False，当链接到全局 cookie share 中的站点时，"StoreCookies" 不会放置找到的任何 cookie：

Wolfram Language code:

cookiesData;
eventFunction[_, "cookies", cookies_] := cookiesData = cookies
URLFetchAsynchronous["http://wolfram.com/", eventFunction, "StoreCookies" -> False]

Wolfram Language code: cookiesData

Wolfram Language code: $HTTPCookies

"Headers" (1)

指定发送到服务器的头部：

Wolfram Language code:

contentData;
eventFunction[_, "data", headers_] := contentData = headers
URLFetchAsynchronous["http://exampledata.wolfram.com/headers.php", eventFunction, "Headers" -> {"MyHeader" -> "42"}]

Wolfram Language code: FromCharacterCode[contentData]

"BodyData" (1)

指定当链接到服务器应该发送的消息体：

Wolfram Language code:

contentData;
eventFunction[_, "data", data_] := contentData = data
URLFetchAsynchronous["http://exampledata.wolfram.com/bodydata.php", eventFunction, "BodyData" -> "Message body data sent to server."]

Wolfram Language code: FromCharacterCode[contentData]

"MultipartData" (1)

指定多部分消息体的内容：

Wolfram Language code:

contentData;
eventFunction[_, "data", data_] := contentData = data
URLFetchAsynchronous["http://exampledata.wolfram.com/multipartdata.php", eventFunction, "MultipartData" -> {{"partName", "mime/type", {1, 2, 3, 4, 5}}}]

Wolfram Language code: FromCharacterCode[contentData]

"ReadTimeout" (1)

指定完成从服务器下载数据所分配的最大时间（以秒为单位）：

Wolfram Language code:

errorString;
eventFunction[_, "error", error_] := errorString = error
URLFetchAsynchronous["http://exampledata.wolfram.com/50mb.dat", eventFunction, "ReadTimeout" -> 1]

Wolfram Language code: errorString

"ConnectTimeout" (1)

以秒为单位指定建立到服务器的链接所分配的最大时间：

Wolfram Language code:

errorString;
eventFunction[_, "error", error_] := errorString = error
URLFetchAsynchronous["http://127.0.0.1", eventFunction, "ConnectTimeout" -> 1]

Wolfram Language code: errorString

"Progress" (1)

如果 True，将发起 "progress" 事件，返回下载和上传的进度信息：

Wolfram Language code: progressData = {};

Wolfram Language code:

progressFunction[_, "progress", progress_] := progressData  = progress
URLFetchAsynchronous["http://exampledata.wolfram.com/5mb.dat", progressFunction, "Progress" -> True];
Dynamic[progressData]

"Transfer" (1)

如果 "Transfer" 设为 "Chunks"，当服务器可以访问数据时，将立即返回数据，而不用等到整个链接完成：

Wolfram Language code: chunks = {};

Wolfram Language code:

chunkFunction[_, "data", data_] := AppendTo[chunks, data]
URLFetchAsynchronous["http://wolfram.com", chunkFunction, "Transfer" -> "Chunks"];

Wolfram Language code: Length[chunks]

"UserData" (1)

当调用事件时，"UserData" 是包含可用信息的任意表达式：

Wolfram Language code:

dataString;
eventFunction[async_, "data", data_] := dataString = "UserData" /. Options[async]
URLFetchAsynchronous["http://wolfram.com", eventFunction, "UserData" -> "stored data"];

Wolfram Language code: dataString

属性和关系 (1)

使用 URLSaveAsynchronous 把输出存储在文件中：

Wolfram Language code:

f[_, "statuscode", _] := CreateDialog[{"Finished download", DefaultButton[]}]
URLSaveAsynchronous["http://wolfram.com", FileNameJoin[{$TemporaryDirectory, "index.html"}], f]

Top

更多学习资源

技术支持

数据科学、金融与商业

工程

科学与技术

教育科技

教育举措

开始

提高你的技能

与我们合作

成人教育计划

青少年教育计划

欢迎阅读

URLFetchAsynchronous

更多信息和选项

范例

基本范例 (3)

选项 (16)

"Method" (1)

"Parameters" (1)

"VerifyPeer" (1)

"Username" (1)

"Password" (1)

"UserAgent" (1)

"Cookies" (1)

"StoreCookies" (1)

"Headers" (1)

"BodyData" (1)

"MultipartData" (1)

"ReadTimeout" (1)

"ConnectTimeout" (1)

"Progress" (1)

"Transfer" (1)

"UserData" (1)

属性和关系 (1)

文本

CMS

APA

BibTeX

BibLaTeX

URLFetchAsynchronous

更多信息和选项

范例

基本范例 (3)

选项 (16)

"Method" (1)

"Parameters" (1)

"VerifyPeer" (1)

"Username" (1)

"Password" (1)

"UserAgent" (1)

"Cookies" (1)

"StoreCookies" (1)

"Headers" (1)

"BodyData" (1)

"MultipartData" (1)

"ReadTimeout" (1)

"ConnectTimeout" (1)

"Progress" (1)

"Transfer" (1)

"UserData" (1)

属性和关系 (1)

历史

文本

CMS

APA

BibTeX

BibLaTeX