WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

UnateQ[bexpr,{x1,x2,…}]

ブール式 bexpr が変数 x1, x2, …において正ユネイトかどうかの検定を行う．

UnateQ[bexpr,{¬x1,¬x2,…}]

ブール式 bexpr が変数 x1, x2, …において負ユネイトかどうかの検定を行う．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

UnateQ

UnateQ[bexpr,{x1,x2,…}]

ブール式 bexpr が変数 x1, x2, …において正ユネイトかどうかの検定を行う．

UnateQ[bexpr,{¬x1,¬x2,…}]

ブール式 bexpr が変数 x1, x2, …において負ユネイトかどうかの検定を行う．

詳細

  • 正ユネイトブール関数はブール増加関数としても知られている．
  • 負ユネイトブール関数はブール減少関数としても知られている．
  • 他変数のすべての値についてBoole[bexpr/.xi->False]≤Boole[bexpr/.xi->True]のとき，ブール式 bexpr は変数 xiにおいて正ユネイトである．
  • 他の変数のすべての値についてBoole[bexpr/.xi->False]≥Boole[bexpr/.xi->True]のとき，ブール式 bexpr は変数 xiにおいては負ユネイトである．
  • 任意の変数の組合せとその否定を使うことができる．
  • UnateQ[bf,{ind1,ind2,…}]はブール関数 bf が変数 k においてユネイトかどうかを識別子 indkに照らして検定する．
  • 識別し indk の取り得る値
  • True,1正ユネイトについての検定を行う
    False,0負ユネイトについての検定を行う
    _ユネイトかどうかの検定は行わない

例題

すべて開く すべて閉じる

例  (2)

ブール式が正ユネイトかどうかの検定を行う：

Wolfram Language code: UnateQ[(x∧y)∨z]
Wolfram Language code: UnateQ[(¬x∧y)∨z]

ブール式が負ユネイトかどうかの検定を行う：

Wolfram Language code: UnateQ[(¬x∧¬y)∨¬z, {¬x, ¬y, ¬z}]
Wolfram Language code: UnateQ[(¬x∧y)∨z, {¬x, ¬y, ¬z}]

スコープ  (5)

正ユネイトについて検定を行う：

Wolfram Language code: UnateQ[(x∧y)∨z]

負ユネイトについて検定を行う：

Wolfram Language code: UnateQ[(x∧y)∨z, {¬x, ¬y, ¬z}]

1つの変数についての正ユネイト性を検定を行う：

Wolfram Language code: UnateQ[(x∧y)∨z, {z}]

1つの変数について正ユネイト性の検定を行い，他の変数について負ユネイト性の検定を行う：

Wolfram Language code: UnateQ[Implies[x, y], {¬x, y}]

純関数のユネイト性を調べる：

Wolfram Language code: UnateQ[#1∧#2∨#3&]
Wolfram Language code: UnateQ[BooleanFunction[30, 3]]

第1変数について負のユネイト性の，第2変数について正のユネイト性の検定を行う：

Wolfram Language code: UnateQ[Implies[#1, #2]&, {False, True}]

関数がその第1変数と最終の変数について正ユネイトかどうかの検定を行う：

Wolfram Language code: UnateQ[#1∧¬#2∨#3&, {True, _, True}]

アプリケーション  (2)

3変数のすべてのユネイト関数を列挙する：

Wolfram Language code: Select[Table[BooleanFunction[i, {x, y, z}], {i, 0, 2 ^ 2 ^ 3 - 1}], UnateQ]

ReliabilityDistributionは正ユネイト関数しか取らない：

Wolfram Language code: vars = Array[Subscript[x, #]&, 5]; dists = Table[{Subscript[x, i], ExponentialDistribution[λ]}, {i, 5}];
Wolfram Language code: f = BooleanFunction[4294967282, 5, vars]//BooleanConvert
Wolfram Language code: DistributionParameterQ[ReliabilityDistribution[f, dists]]

どの変数が正ユネイトではないかを求める：

Wolfram Language code: Extract[Array[Subscript[x, #]&, 5], Position[Map[UnateQ[f, #]&, vars], False]]

Falseと設定することで x4を削除する：

Wolfram Language code: f /. Subscript[x, 4] -> False
Wolfram Language code: DistributionParameterQ[ReliabilityDistribution[%, dists]]

特性と関係  (6)

基本的な正ユネイト関数：

Wolfram Language code: UnateQ /@ {x, And[x, y], Or[x, y], Majority[x, y, z]}

基本的な負ユネイト関数：

Wolfram Language code: UnateQ[#, {¬x, ¬y}]& /@ {Not[x], Nand[x, y], Nor[x, y]}

Impliesは1つの変数について負ユネイトであり，他の変数については正ユネイトである：

Wolfram Language code: UnateQ[Implies[x, y], {¬x, y}]

ブール関数の中にはどの変数についてもユネイトではないものもある：

Wolfram Language code: Table[UnateQ[Xor[x, y], {v}], {v, {x, y, ¬x, ¬y}}]
Wolfram Language code: Table[UnateQ[Xnor[x, y], {v}], {v, {x, y, ¬x, ¬y}}]
Wolfram Language code: Table[UnateQ[Equivalent[x, y], {v}], {v, {x, y, ¬x, ¬y}}]

次元 で正ユネイトであるブール関数の割合：

Wolfram Language code: countFraction[n_] := Count[Table[BooleanFunction[i, n], {i, 0, 2 ^ 2 ^ n - 1}], _ ? UnateQ] / 2 ^ 2 ^ n
Wolfram Language code: BarChart[Table[countFraction[i], {i, 4}], ChartLabels -> Range[4], AxesLabel -> {n, None}]

正ユネイト関数の組合せはユネイトである：

Wolfram Language code: UnateQ[(x∧y)∨z]

負ユネイト関数の組合せは必ずしも負ユネイトであるとは限らない：

Wolfram Language code: UnateQ[(x⊼y)⊼z, {¬x, ¬y, ¬z}]

正ユネイト関数の否定は負ユネイトである：

Wolfram Language code: expr = (x∨y)∧z;
Wolfram Language code: UnateQ[expr, {x, y, z}]
Wolfram Language code: UnateQ[¬expr, {¬x, ¬y, ¬z}]

おもしろい例題  (1)

各3変数のブール関数のいくつの変数が正ユネイトであるか示す：

Wolfram Language code: PieChart[Map[{Total[#], 3 - Total[#]}&, Boole@Table[Map[UnateQ[BooleanFunction[i, 3][x, y, z], #]&, {x, y, z}], {i, 0, 2 ^ 2 ^ 3 - 1}]], ChartBaseStyle -> Directive[EdgeForm[None]], ChartLegends -> {"Positive unate", "Not positive unate"}, ChartStyle -> "TemperatureMap", ImageSize -> Medium]
Wolfram Research (2012), UnateQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/UnateQ.html.

テキスト

Wolfram Research (2012), UnateQ, Wolfram言語関数， https://reference.wolfram.com/language/ref/UnateQ.html.

CMS

Wolfram Language. 2012. "UnateQ." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/UnateQ.html.

APA

Wolfram Language. (2012). UnateQ. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/UnateQ.html

BibTeX

@misc{reference.wolfram_2026_unateq, author="Wolfram Research", title="{UnateQ}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/UnateQ.html}", note=[Accessed: 02-November-2026]}

BibLaTeX

@online{reference.wolfram_2026_unateq, organization={Wolfram Research}, title={UnateQ}, year={2012}, url={https://reference.wolfram.com/language/ref/UnateQ.html}, note=[Accessed: 02-November-2026]}