WOLFRAM

Wolfram 语言与系统参考资料中心

UnionedEntityClass[class1,…]

表示一个实体类，其中包含 classi 中所有不同的实体.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
SameTestProperties  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

UnionedEntityClass

UnionedEntityClass[class1,…]

表示一个实体类，其中包含 classi 中所有不同的实体.

更多信息和选项

  • UnionedEntityClass[class1,class2,…] 实际上等价于应用 EntityList 时出现的每个 classi 中的实体的未排序并集.
  • 在 EntityList 中进行简化后，出现在 UnionedEntityClass 中的类别实际上具有相同的类型时，所得实体将具有该类型. 在求不兼容类型的并集时，生成的实体将具有新的类型.
  • UnionedEntityClass[class1,class2,…,SameTestProperties {props1,props2,…}] 使用来自 classi 的属性 propsi 来测试实体是否相等.
  • UnionedEntityClass[class,SameTestProperties{prop1,prop2,…}] 可用来删除所有属性 propi 的值都相同的实体.
  • UnionedEntityClass[class1,class2,…,SameTestPropertiesFull] 将所有实体视为不同，可用于将多个类合并为一个类.
  • EntityProperties[UnionedEntityClass[class1,class2,…]]返回每个 classi 的所有属性以及 EntityProperty[UnionedEntityClass[…],"propj"]，其中 "propj" 是当这些类具有不同的实体类型时，出现在至少两个 classi 中的属性.

范例

打开所有单元 关闭所有单元

基本范例  (3)

计算两个类型相同的类别的并集：

Wolfram Language code: EntityList[UnionedEntityClass[EntityClass["Element", "NobleGas"], EntityClass["Element", "Period1"]]]

混合不同类型的实体：

Wolfram Language code: UnionedEntityClass[EntityClass["AdministrativeDivision", "AllUSStatesPlusDC"], EntityClass["Country", "EuropeanUnion"]][{"Name", "Population"}]//Dataset

当与关系数据库支持的实体一起使用时，UnionedEntityClass 可用于生成不同的 SQL 语句：

Wolfram Language code: EntityRegister[EntityStore[RelationalDatabase[FindFile["ExampleData/ecommerce-database.sqlite"]]]]

突出情况下，它对应于 UNION 语句：

Wolfram Language code: UnionedEntityClass[EntityClass["offices", "country" -> "USA"], EntityClass["offices", "country" -> "Germany"]][{"officeCode", "country"}]

当与 SameTestPropertiesFalse 一起使用时，对应于 UNION ALL 语句：

Wolfram Language code: UnionedEntityClass["offices", "offices", SameTestProperties -> False]["officeCode"]

当与一个参数和 SameTestProperties 的明确列表一起使用时，对应于 PostgreSQL DISTINCT ON：

Wolfram Language code: UnionedEntityClass["customers", SameTestProperties -> {"country"}][{"customerName", "country"}]

范围  (4)

用 UnionedEntityClass 将相同类型的实体组合在一起：

Wolfram Language code: EntityList[UnionedEntityClass[EntityClass["Country", "GroupOf8"], EntityClass["Country", "BeneluxEconomicUnion"]]]

将不同类型的实体组合在一起：

Wolfram Language code: EntityList[UnionedEntityClass[EntityClass["Chemical", "Fullerenes"], EntityClass["Building", "Architect" -> ContainsExactly[{Entity["Person", "RBuckminsterFuller::2976y"]}]]]]

将不同类型的实体组合在一起时，将所有实体视为不同：

Wolfram Language code: EntityList[UnionedEntityClass[EntityClass["Chemical", "HomonuclearDiatomics"], EntityClass["Element", "Gas"]]]

使用选项 SameTestProperties 删除重复的实体：

Wolfram Language code: EntityList[UnionedEntityClass[EntityClass["Chemical", "HomonuclearDiatomics"], EntityClass["Element", "Gas"], SameTestProperties -> "Name"]]

UnionedEntityClass 可与一个参数和 SameTestProperties 一起使用来表示一类实体，其中已根据某些条件删除了重复的项：

Wolfram Language code: EntityList[UnionedEntityClass["Pokemon", SameTestProperties -> "Generation"]]

选项  (2)

SameTestProperties  (2)

使用选定的属性定义实体之间的相等性：

Wolfram Language code: UnionedEntityClass[EntityClass["Movie", "Name" -> "The Godfather"], EntityClass["Book", "Name" -> "The Godfather"], SameTestProperties -> "Name"][{"FirstPublished", "ReleaseDate"}]

将 SameTestProperties 设为 False 实际上相当于合并类别：

Wolfram Language code: elements = UnionedEntityClass[EntityClass["Element", "NobleGas"], EntityClass["Element", "Period1"], SameTestProperties -> False]["Name"]

注意氦气在列表中出现了两次：

Wolfram Language code: DuplicateFreeQ[elements]

属性和关系  (3)

UnionedEntityClass 通常等价于 Union：

Wolfram Language code: EntityList[UnionedEntityClass[EntityClass["Country", "GroupOf8"], EntityClass["Country", "EuropeanUnion"]]] === Union[EntityList[EntityClass["Country", "GroupOf8"]], EntityList[EntityClass["Country", "EuropeanUnion"]]]

带有 SameTestPropertiesFalse 的 UnionedEntityClass 大约等价于 Join：

Wolfram Language code: UnionedEntityClass[EntityClass["Element", "Metal"], EntityClass["Element", "Period5"], SameTestProperties -> False]["Name"] === Join[EntityClass["Element", "Metal"]["Name"], EntityClass["Element", "Period5"]["Name"]]

含有一个参数和明确设置的 SameTestProperties 的 UnionedEntityClass 大约等价于 DeleteDuplicatesBy：

Wolfram Language code: Sort[EntityValue[UnionedEntityClass["Element", SameTestProperties -> {"Period"}], {"Name", "Period"}, "PropertyAssociation"]] === DeleteDuplicatesBy[Sort[EntityValue["Element", {"Name", "Period"}, "PropertyAssociation"]], Key["Period"]]

在将隐式 EntityClass 或 FilteredEntityClass 表达式合并到一起时，在条件中使用析取会更有效：

Wolfram Language code: EntityList[UnionedEntityClass[FilteredEntityClass["Element", EntityFunction[x, x["Group"] == 1]], FilteredEntityClass["Element", EntityFunction[x, x["Period"] == 1]]]]

除顺序外，两个类别是等价的：

Wolfram Language code: EntityList[FilteredEntityClass["Element", EntityFunction[x, x["Period"] == 1 || x["Group"] == 1]]]

可能存在的问题  (1)

对于关系数据库支持的实体还有一些其他限制：

Wolfram Language code: EntityRegister[EntityStore[RelationalDatabase[FindFile["ExampleData/ecommerce-database.sqlite"]]]]

某些关系数据库后端不能保证保留此操作所产生的行的顺序，例如，此处 "employees" 出现在 "offices" 之前：

Wolfram Language code: UnionedEntityClass["offices", "employees"]["firstName"]
Wolfram Research (2020)，UnionedEntityClass，Wolfram 语言函数，https://reference.wolfram.com/language/ref/UnionedEntityClass.html.

文本

Wolfram Research (2020)，UnionedEntityClass，Wolfram 语言函数，https://reference.wolfram.com/language/ref/UnionedEntityClass.html.

CMS

Wolfram 语言. 2020. "UnionedEntityClass." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/UnionedEntityClass.html.

APA

Wolfram 语言. (2020). UnionedEntityClass. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/UnionedEntityClass.html 年

BibTeX

@misc{reference.wolfram_2026_unionedentityclass, author="Wolfram Research", title="{UnionedEntityClass}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/UnionedEntityClass.html}", note=[Accessed: 31-July-2026]}

BibLaTeX

@online{reference.wolfram_2026_unionedentityclass, organization={Wolfram Research}, title={UnionedEntityClass}, year={2020}, url={https://reference.wolfram.com/language/ref/UnionedEntityClass.html}, note=[Accessed: 31-July-2026]}