WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

WattsStrogatzGraphDistribution[n,p]

再配線確率が p で n 個の頂点を持つグラフのWatts–Strogatzグラフ分布を表す．

WattsStrogatzGraphDistribution[n,p,k]

再配線確率が p で2k 正則グラフから始まる n 個の頂点を持つグラフのWatts–Strogatzグラフ分布を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
関連するガイド
履歴
引用書式

WattsStrogatzGraphDistribution

WattsStrogatzGraphDistribution[n,p]

再配線確率が p で n 個の頂点を持つグラフのWatts–Strogatzグラフ分布を表す．

WattsStrogatzGraphDistribution[n,p,k]

再配線確率が p で2k 正則グラフから始まる n 個の頂点を持つグラフのWatts–Strogatzグラフ分布を表す．

詳細

例題

すべて開く すべて閉じる

例  (2)

擬似ランダムグラフを生成する：

Wolfram Language code: RandomGraph[WattsStrogatzGraphDistribution[50, 0.05]]

再配線の確率の関数としてのGlobalClusteringCoefficient：

Wolfram Language code: ListLogLinearPlot[Table[{p, GlobalClusteringCoefficient[RandomGraph[WattsStrogatzGraphDistribution[10 ^ 3, p, 5]]]}, {p, 10 ^ Range[-4, 0, 0.05]}], Joined -> True]

スコープ  (3)

単純無向グラフを生成する：

Wolfram Language code: RandomGraph[WattsStrogatzGraphDistribution[30, 0.03, 3]]

擬似ランダムグラフの集合を生成する：

Wolfram Language code: RandomGraph[WattsStrogatzGraphDistribution[20, 0.07], 4]

確率と統計の特性を計算する：

Wolfram Language code: 𝒟 = GraphPropertyDistribution[GlobalClusteringCoefficient[g], gWattsStrogatzGraphDistribution[10, 0.2]];
Wolfram Language code: NExpectation[x, x𝒟]

アプリケーション  (3)

Western States Power GridはWattsStrogatzGraphDistributionでモデル化することができる：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "PowerGrid"}];
Wolfram Language code: 𝒢 = WattsStrogatzGraphDistribution[VertexCount[g], 0.25, Round[EdgeCount[g] / VertexCount[g]]]

このモデルは，短い平均グラフ距離と高いクラスタリングで，経験的ネットワークというスモールワールドの特性を捉えている：

Wolfram Language code: {N[MeanGraphDistance[g]], N[MeanClusteringCoefficient[g]]}
Wolfram Language code: h = RandomGraph[WattsStrogatzGraphDistribution[10 ^ 3, 0.25, 2]];{N[MeanGraphDistance[h]], N[MeanClusteringCoefficient[h]]}

人口100人で住民1人あたりの知人の平均数が20人という小さい村のソーシャルネットワークはWattsStrogatzGraphDistributionでモデル化することができる．もっとも知人が少ない人の知人の期待数を求める：

Wolfram Language code: 𝒢 = WattsStrogatzGraphDistribution[100, 0.1, 20 / 2];
Wolfram Language code: g = RandomGraph[𝒢]

もっとも知人が少ない人の知人の期待数：

Wolfram Language code: 𝒟 = GraphPropertyDistribution[Min[VertexDegree[h]], h𝒢]; NExpectation[x, x𝒟]

期待される分離度：

Wolfram Language code: 𝒟 = GraphPropertyDistribution[GraphDiameter[h], h𝒢];Round[N[Mean[𝒟]]]

以下はソーシャルネットワーク内での感染症の拡散モデルの簡約版を表す．感染症は各段階で確率0.4で罹患者から感染しやすい隣人に伝染し，感染した患者には回復後は免疫がある：

Wolfram Language code: network = RandomGraph[WattsStrogatzGraphDistribution[100, 0.1, 3]]

感染のシミュレーションを行い感染した人を求める：

Wolfram Language code: infect[z_, p_] := Pick[z, RandomChoice[{p, 1 - p} -> {1, 0}, Length[z]], 1]; step[g_, {i_, q_}, p_] := {Complement[infect[AdjacencyList[g, i], p], i, q], Join[q, i]}; infected[g_, i_, p_] := Last[FixedPoint[step[g, #, p]&, {i, {}}]]
Wolfram Language code: infected[network, {1}, 0.4] //Short

感染した人をハイライトする：

Wolfram Language code: HighlightGraph[network, %]

感染確率の関数としての感染した人の割合：

Wolfram Language code: count[p_] := Mean[Table[Length[infected[network, {1}, p]], {100}]];
Wolfram Language code: DiscretePlot[count[p], {p, 0, 1, 0.1}, Joined -> True]

特性と関係  (5)

頂点数の分布：

Wolfram Language code: GraphPropertyDistribution[VertexCount[g], gWattsStrogatzGraphDistribution[n, p, k]]

辺の数の分布：

Wolfram Language code: GraphPropertyDistribution[EdgeCount[g], gWattsStrogatzGraphDistribution[n, p, k]]

頂点次数の分布：

Wolfram Language code: 𝒟[n_, p_, k_] := HistogramDistribution[Flatten[Table[VertexDegree[g], {g, RandomGraph[WattsStrogatzGraphDistribution[n, p, k], 1000]}]], {-1 / 2, n, 1}];
Wolfram Language code: DiscretePlot[Evaluate@Table[PDF[𝒟[50, p, 2], d], {p, 0, 1, 1 / 3}], {d, 0, 8}, PlotRange -> All, ExtentSize -> 4 / 5]

BinomialDistributionとPoissonDistributionの和による近似：

Wolfram Language code: ℱ[n_, p_, k_] := TransformedDistribution[x + y, {xBinomialDistribution[2k, 1 - p / 2], yPoissonDistribution[k p]}]
Wolfram Language code: DiscretePlot[Evaluate@{PDF[𝒟[100, 0.4, 3], d], PDF[ℱ[100, 0.4, 3], d]}, {d, 0, 15}, PlotRange -> All, ExtentSize -> 4 / 5]

再配線の確率が増すにつれて平均距離は急速に短くなる：

Wolfram Language code: ListLogLinearPlot[Table[{p, MeanGraphDistance[RandomGraph[WattsStrogatzGraphDistribution[10 ^ 3, p, 5]]]}, {p, Table[10 ^ x, {x, -3, 0, 0.3}]}], Joined -> True, PlotRange -> All]

クラスタリング係数は緩やかに減少する：

Wolfram Language code: ListLogLinearPlot[Table[{p, GlobalClusteringCoefficient[RandomGraph[WattsStrogatzGraphDistribution[10 ^ 3, p, 5]]]}, {p, Table[10 ^ x, {x, -3, 0, 0.3}]}], Joined -> True]

WattsStrogatzGraphDistribution[n,0,k]は 2k 正則グラフである：

Wolfram Language code: RandomGraph[WattsStrogatzGraphDistribution[13, 0, 6]]
Wolfram Language code: VertexDegree[%]

n≤2k のときは(n-1)正則である：

Wolfram Language code: RandomGraph[WattsStrogatzGraphDistribution[12, 0, 6]]
Wolfram Language code: VertexDegree[%]

おもしろい例題  (1)

ランダムに彩色された頂点：

Wolfram Language code: RandomGraph[WattsStrogatzGraphDistribution[10 ^ 3, 0.05], VertexStyle -> Table[i -> RandomChoice[ColorData[45, "ColorList"]], {i, 10 ^ 3}], VertexSize -> {"Scaled", 0.015}]
Wolfram Research (2010), WattsStrogatzGraphDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/WattsStrogatzGraphDistribution.html.

テキスト

Wolfram Research (2010), WattsStrogatzGraphDistribution, Wolfram言語関数， https://reference.wolfram.com/language/ref/WattsStrogatzGraphDistribution.html.

CMS

Wolfram Language. 2010. "WattsStrogatzGraphDistribution." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/WattsStrogatzGraphDistribution.html.

APA

Wolfram Language. (2010). WattsStrogatzGraphDistribution. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/WattsStrogatzGraphDistribution.html

BibTeX

@misc{reference.wolfram_2026_wattsstrogatzgraphdistribution, author="Wolfram Research", title="{WattsStrogatzGraphDistribution}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/WattsStrogatzGraphDistribution.html}", note=[Accessed: 29-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_wattsstrogatzgraphdistribution, organization={Wolfram Research}, title={WattsStrogatzGraphDistribution}, year={2010}, url={https://reference.wolfram.com/language/ref/WattsStrogatzGraphDistribution.html}, note=[Accessed: 29-October-2026]}