WOLFRAM

Wolfram 语言与系统参考资料中心

WattsStrogatzGraphDistribution[n,p]

表示具有重连概率 p 的 n 顶点图的 Watts–Strogatz 图分布.

WattsStrogatzGraphDistribution[n,p,k]

表示起始于一个 2k 正则图，重连概率为 p 的 n 顶点图的 Watts–Strogatz 图分布.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
巧妙范例  
参见
相关指南
历史
按以下格式引用：

WattsStrogatzGraphDistribution

WattsStrogatzGraphDistribution[n,p]

表示具有重连概率 p 的 n 顶点图的 Watts–Strogatz 图分布.

WattsStrogatzGraphDistribution[n,p,k]

表示起始于一个 2k 正则图，重连概率为 p 的 n 顶点图的 Watts–Strogatz 图分布.

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (2)

生成伪随机图：

Wolfram Language code: RandomGraph[WattsStrogatzGraphDistribution[50, 0.05]]

GlobalClusteringCoefficient 作为重连概率的函数：

Wolfram Language code: ListLogLinearPlot[Table[{p, GlobalClusteringCoefficient[RandomGraph[WattsStrogatzGraphDistribution[10 ^ 3, p, 5]]]}, {p, 10 ^ Range[-4, 0, 0.05]}], Joined -> True]

范围  (3)

生成简单无向图：

Wolfram Language code: RandomGraph[WattsStrogatzGraphDistribution[30, 0.03, 3]]

生成伪随机图集合：

Wolfram Language code: RandomGraph[WattsStrogatzGraphDistribution[20, 0.07], 4]

计算概率和统计属性：

Wolfram Language code: 𝒟 = GraphPropertyDistribution[GlobalClusteringCoefficient[g], gWattsStrogatzGraphDistribution[10, 0.2]];
Wolfram Language code: NExpectation[x, x𝒟]

应用  (3)

Western States Power Grid （西部各州电力网格）可以使用 WattsStrogatzGraphDistribution 建模：

Wolfram Language code: g = ExampleData[{"NetworkGraph", "PowerGrid"}];
Wolfram Language code: 𝒢 = WattsStrogatzGraphDistribution[VertexCount[g], 0.25, Round[EdgeCount[g] / VertexCount[g]]]

在短均值图距离和高度集群下，该模型捕捉了经验网络的“小世界”特性：

Wolfram Language code: {N[MeanGraphDistance[g]], N[MeanClusteringCoefficient[g]]}
Wolfram Language code: h = RandomGraph[WattsStrogatzGraphDistribution[10 ^ 3, 0.25, 2]];{N[MeanGraphDistance[h]], N[MeanClusteringCoefficient[h]]}

下面是一个100人的村庄中的社交网络，其中每个人平均有20个关系，这个社交网络可以使用 WattsStrogatzGraphDistribution 建模. 求具有最少连接的人的期望关系数目：

Wolfram Language code: 𝒢 = WattsStrogatzGraphDistribution[100, 0.1, 20 / 2];
Wolfram Language code: g = RandomGraph[𝒢]

具有最少连接的人的期望关系数目：

Wolfram Language code: 𝒟 = GraphPropertyDistribution[Min[VertexDegree[h]], h𝒢]; NExpectation[x, x𝒟]

期望度分隔：

Wolfram Language code: 𝒟 = GraphPropertyDistribution[GraphDiameter[h], h𝒢];Round[N[Mean[𝒟]]]

这表示社交网络中传染性疾病传播的简化模型. 该疾病以每步概率 0.4 从受感染的人传播到周边易感人群，而受感染的人复原并且具有抵抗力：

Wolfram Language code: network = RandomGraph[WattsStrogatzGraphDistribution[100, 0.1, 3]]

模拟感染传播，查找受感染的人群：

Wolfram Language code: infect[z_, p_] := Pick[z, RandomChoice[{p, 1 - p} -> {1, 0}, Length[z]], 1]; step[g_, {i_, q_}, p_] := {Complement[infect[AdjacencyList[g, i], p], i, q], Join[q, i]}; infected[g_, i_, p_] := Last[FixedPoint[step[g, #, p]&, {i, {}}]]
Wolfram Language code: infected[network, {1}, 0.4] //Short

突出显示受感染的人群：

Wolfram Language code: HighlightGraph[network, %]

受感染的人群的比率，以传输概率的函数表示：

Wolfram Language code: count[p_] := Mean[Table[Length[infected[network, {1}, p]], {100}]];
Wolfram Language code: DiscretePlot[count[p], {p, 0, 1, 0.1}, Joined -> True]

属性和关系  (5)

顶点数分布：

Wolfram Language code: GraphPropertyDistribution[VertexCount[g], gWattsStrogatzGraphDistribution[n, p, k]]

边数分布：

Wolfram Language code: GraphPropertyDistribution[EdgeCount[g], gWattsStrogatzGraphDistribution[n, p, k]]

顶点度的分布：

Wolfram Language code: 𝒟[n_, p_, k_] := HistogramDistribution[Flatten[Table[VertexDegree[g], {g, RandomGraph[WattsStrogatzGraphDistribution[n, p, k], 1000]}]], {-1 / 2, n, 1}];
Wolfram Language code: DiscretePlot[Evaluate@Table[PDF[𝒟[50, p, 2], d], {p, 0, 1, 1 / 3}], {d, 0, 8}, PlotRange -> All, ExtentSize -> 4 / 5]

使用 BinomialDistribution 和 PoissonDistribution 之和求近似：

Wolfram Language code: ℱ[n_, p_, k_] := TransformedDistribution[x + y, {xBinomialDistribution[2k, 1 - p / 2], yPoissonDistribution[k p]}]
Wolfram Language code: DiscretePlot[Evaluate@{PDF[𝒟[100, 0.4, 3], d], PDF[ℱ[100, 0.4, 3], d]}, {d, 0, 15}, PlotRange -> All, ExtentSize -> 4 / 5]

当重连概率增加时，平均距离迅速降低：

Wolfram Language code: ListLogLinearPlot[Table[{p, MeanGraphDistance[RandomGraph[WattsStrogatzGraphDistribution[10 ^ 3, p, 5]]]}, {p, Table[10 ^ x, {x, -3, 0, 0.3}]}], Joined -> True, PlotRange -> All]

集群系数慢慢降低：

Wolfram Language code: ListLogLinearPlot[Table[{p, GlobalClusteringCoefficient[RandomGraph[WattsStrogatzGraphDistribution[10 ^ 3, p, 5]]]}, {p, Table[10 ^ x, {x, -3, 0, 0.3}]}], Joined -> True]

WattsStrogatzGraphDistribution[n,0,k] 是一个 2k 正则图：

Wolfram Language code: RandomGraph[WattsStrogatzGraphDistribution[13, 0, 6]]
Wolfram Language code: VertexDegree[%]

对于 n≤2k，它是 (n-1) 正则图：

Wolfram Language code: RandomGraph[WattsStrogatzGraphDistribution[12, 0, 6]]
Wolfram Language code: VertexDegree[%]

巧妙范例  (1)

随机着色的顶点：

Wolfram Language code: RandomGraph[WattsStrogatzGraphDistribution[10 ^ 3, 0.05], VertexStyle -> Table[i -> RandomChoice[ColorData[45, "ColorList"]], {i, 10 ^ 3}], VertexSize -> {"Scaled", 0.015}]
Wolfram Research (2010)，WattsStrogatzGraphDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/WattsStrogatzGraphDistribution.html.

文本

Wolfram Research (2010)，WattsStrogatzGraphDistribution，Wolfram 语言函数，https://reference.wolfram.com/language/ref/WattsStrogatzGraphDistribution.html.

CMS

Wolfram 语言. 2010. "WattsStrogatzGraphDistribution." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/WattsStrogatzGraphDistribution.html.

APA

Wolfram 语言. (2010). WattsStrogatzGraphDistribution. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/WattsStrogatzGraphDistribution.html 年

BibTeX

@misc{reference.wolfram_2026_wattsstrogatzgraphdistribution, author="Wolfram Research", title="{WattsStrogatzGraphDistribution}", year="2010", howpublished="\url{https://reference.wolfram.com/language/ref/WattsStrogatzGraphDistribution.html}", note=[Accessed: 18-October-2026]}

BibLaTeX

@online{reference.wolfram_2026_wattsstrogatzgraphdistribution, organization={Wolfram Research}, title={WattsStrogatzGraphDistribution}, year={2010}, url={https://reference.wolfram.com/language/ref/WattsStrogatzGraphDistribution.html}, note=[Accessed: 18-October-2026]}