WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

アップグレード情報：

LinearAlgebra`MatrixManipulation`

AppendColumns，AppendRows，BlockMatrixが Mathematica カーネル関数のJoin，ArrayFlattenで利用できるようになった．
TakeRows，TakeColumns，TakeMatrix，SubMatrixが Mathematica カーネル関数のTakeで利用できるようになった．
HankelMatrixとHilbertMatrixがカーネル関数のHankelMatrix，HilbertMatrixとして利用できるようになった．
ZeroMatrixの機能が，新しいカーネル関数のConstantArrayを使って得られるようになった．
PolarDecompositionの機能が，向上した Mathematica カーネル関数のSingularValueDecompositionを使って得られるようになった．
MatrixPlotがカーネル関数のMatrixPlotとして利用できるようになった．

2つの行列を結合する：

Version 5.2 << LinearAlgebra`MatrixManipulation`; A = Array[a, {2, 2}]; B = Array[b, {2, 2}]; AppendRows[A, B] // MatrixForm
Wolfram Language code: A = Array[a, {2, 2}];B = Array[b, {2, 2}]; Join[A, B, 2]//MatrixForm

部分行列からブロック行列を生成する：

Version 5.2 << LinearAlgebra`MatrixManipulation`; A = Array[a, {2, 2}]; B = Array[b, {2, 2}]; BlockMatrix[{{A, B}, {B, {{0, 0}, {0, 0}}}}] // MatrixForm
Wolfram Language code: A = Array[a, {2, 2}];B = Array[b, {2, 2}]; ArrayFlatten[{{A, B}, {B, 0}}]//MatrixForm

部分行列を選ぶ：

Version 5.2 << LinearAlgebra`MatrixManipulation`; TakeMatrix[Array[a, {5, 5}], {2, 2}, {3, 4}] // MatrixForm
Wolfram Language code: Take[Array[a, {5, 5}], {2, 3}, {2, 4}]//MatrixForm

特殊な型の行列を生成する：

Version 5.2 << LinearAlgebra`MatrixManipulation`; HankelMatrix[3] // MatrixForm
Wolfram Language code: HankelMatrix[3]//MatrixForm
Version 5.2 << LinearAlgebra`MatrixManipulation`; HilbertMatrix[3] // MatrixForm
Wolfram Language code: HilbertMatrix[3]//MatrixForm

LowerDiagonalMatrix，UpperDiagonalMatrix，TridiagonalMatrixは以下の定義で置き換えることができる：

Version 5.2 << LinearAlgebra`MatrixManipulation`; LowerDiagonalMatrix[a, 5] // MatrixForm
Wolfram Language code: LowerDiagonalMatrix[f_, n_Integer ? NonNegative] := Array[If[# ≥ #2, f[##], 0]&, {n, n}] LowerDiagonalMatrix[a, 5]//MatrixForm
Version 5.2 << LinearAlgebra`MatrixManipulation`; UpperDiagonalMatrix[a, 5] // MatrixForm
Wolfram Language code: UpperDiagonalMatrix[f_, n_Integer ? NonNegative] := Array[If[# ≤ #2, f[##], 0]&, {n, n}] UpperDiagonalMatrix[a, 5]//MatrixForm
Version 5.2 << LinearAlgebra`MatrixManipulation`; TridiagonalMatrix[a, 5] // MatrixForm
Wolfram Language code: TridiagonalMatrix[f_, n_Integer ? NonNegative] := Array[If[Abs[# - #2] ≤ 1, f[##], 0]&, {n, n}] TridiagonalMatrix[a, 5]//MatrixForm

LUMatricesは次の定義で置き換えることができる：

Version 5.2 << LinearAlgebra`MatrixManipulation`; LUMatrices[First@LUDecomposition[{{1., 2.}, {3., 4.}}]]
Wolfram Language code: LUMatrices[m_ ? MatrixQ] := {m - # + IdentityMatrix[Length@m], #}&[ m * Array[Boole[# ≤ #2]&, Dimensions@m]] LUMatrices[First@LUDecomposition[{{1., 2.}, {3., 4.}}]]

SquareMatrixQは次の定義で置き換えることができる：

Version 5.2 << LinearAlgebra`MatrixManipulation`; SquareMatrixQ[{{x}}]
Wolfram Language code: SquareMatrixQ = MatrixQ@# && Equal@@Dimensions@#&; SquareMatrixQ[{{x}}]

零行列を構築する：

Version 5.2 << LinearAlgebra`MatrixManipulation`; ZeroMatrix[2] // MatrixForm
Wolfram Language code: ConstantArray[0, {2, 2}]//MatrixForm

行列の極分解を計算する：

Version 5.2 << LinearAlgebra`MatrixManipulation`; PolarDecomposition[{{1, 1}, {1, I}}] // RootReduce
Wolfram Language code: {u, w, v} = SingularValueDecomposition[{{1, 1}, {1, I}}]; {u.ConjugateTranspose[v], v.w.ConjugateTranspose[v]}//RootReduce

行列の構造を表示する：

Version 5.2 << LinearAlgebra`MatrixManipulation`; MatrixPlot[Reverse@IdentityMatrix[10]]
Wolfram Language code: MatrixPlot[Reverse@IdentityMatrix[10], ColorFunction -> "Monochrome"]

これまでのバージョンの Mathematica で利用できた以下の関数が，Web (library.wolfram.co.jp/infocenter/MathSource/6770)から利用できるようになった．

LinearEquationsToMatrices
InverseMatrixNorm
MatrixConditionNumber