WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター
データの選択

データの選択

SQLSelectはデータベースのデータを選択して返す．これは，「生SQLを使ったデータの選択」に記載のように，SQLコマンドをそのまま使ってもできる．

このセクションの例を実際に試してみて，記載の通りに動作しなかった場合は，「データベースの例の使用」で述べているように"DatabaseLink`DatabaseExamples`"パッケージを使ってデータベースをもとの状態に戻す必要があるかもしれない．.

SQLSelect[conn,table,opts]表のすべてのデータを選択する
SQLSelect[conn,{tables},{columns}]表の特定の列のデータを選択する
SQLSelect[conn,{tables},{columns},condition,opts]
条件を満たす表の特定の列のデータを選択する

データベースからのデータの取出し

DatabaseLink をロードし，publisherデータベースに接続する．

Wolfram Language code: Needs["DatabaseLink`"]; conn = OpenSQLConnection["publisher"];

表ROYSCHED内のすべてのデータを取り出す．

Wolfram Language code: SQLSelect[conn, "ROYSCHED"]

SQLSelectの第3パラメータは，特定の列のみを選択したいときに使用できる．次の例では列TITLE_IDとROYALTYだけを選択する．

Wolfram Language code: data = SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}]

データベース操作の結果はそのままWolfram言語で使える．

Wolfram Language code: Histogram[data[[All, -1]]]

SQLSelectには数々のオプションが使える．

オプション名
デフォルト値
"Distinct"False重複しない結果だけを返すかどうかの設定
"FetchSize"AutomaticJDBCドライバへの結果セットの大きさの提示
"GetAsStrings"False結果を文字列として返すかどうかの設定
"MaxFieldSize"Automatic可変長の列のタイプのバイト制限
"MaxRows"Automatic返される最大行数を設定する
"ShowColumnHeadings"False結果とともに列見出しを返すかどうかの設定
"SortingColumns"Noneデータのソート方法
"ColumnSymbols"None結果と関連付けるシンボル
"Timeout"$SQLTimeoutクエリのタイムアウトを設定する

SQLSelectのオプション

複数の表の複数の列からデータを選択することもできる．複数の表は，第2引数で表の名前のリストを指定すると選べる．列名のリストは前述のように第3パラメータで指定する．表の名前と列名をペアでリストにして第3引数で指定することで，特定の表の名前と列の名前を関連付けることもできる．これは複数の表で同じ列名が使われているときに重要である．次は2つの表のデータを組み合せて外積を求める例であるが，最初の5つの結果のみを表示させるためにオプション"MaxRows"を使う．

Wolfram Language code: SQLSelect[conn, {"TITLES", "ROYSCHED"}, {{"TITLES", "TITLE"}, {"TITLES", "TITLE_ID"}, {"ROYSCHED", "TITLE_ID"}, {"ROYSCHED", "ROYALTY"}}, "MaxRows" -> 5, "ShowColumnHeadings" -> True]//TableForm

次の例でも同じクエリを繰り返すが，2つの表のTITLE_IDが同じでなければならないという条件を加える．条件を使うと検索結果を絞り込むことができ，便利である．

Wolfram Language code: SQLSelect[conn, {"TITLES", "ROYSCHED"}, {{"TITLES", "TITLE"}, {"TITLES", "TITLE_ID"}, {"ROYSCHED", "TITLE_ID"}, {"ROYSCHED", "ROYALTY"}}, SQLColumn[{"TITLES", "TITLE_ID"}] == SQLColumn[{"ROYSCHED", "TITLE_ID"}], "MaxRows" -> 5, "ShowColumnHeadings" -> True]//TableForm

列の値が特定の範囲内でなければならないという指定もできる．

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, .10 < SQLColumn["ROYALTY"] < .15]
Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, .13 > SQLColumn["ROYALTY"] > .10]

次は列の値が特定の値でなければならないことを指定する．

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLColumn["ROYALTY"] == .12]

今度は列の値が特定の値に等しくてはならないことを指定する．

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLColumn["ROYALTY"] != .12]

列の値が特定の値より大きくなければならないことを指定する．

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLColumn["ROYALTY"] > .12]

列の値が特定の値より小さくなければならないことを指定する．

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLColumn["ROYALTY"] < .12]

列の値が特定の値以上でなければならないことを指定する．

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLColumn["ROYALTY"] >= .12]

列の値が特定のパターンに合致しなければならないことを指定することもできる．0文字以上のマッチングのためにはメタ文字「%」，1文字用にはメタ文字「_」を使う．

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLStringMatchQ[SQLColumn["TITLE_ID"], "C%"]]
Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLStringMatchQ[SQLColumn["TITLE_ID"], "_S%"]]

列の値がリストの一部として含まれていなければならないことを指定する．

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLMemberQ[{.14, .16}, SQLColumn["ROYALTY"]]]

列の値が特定の値以下でなければならないことを指定する．

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLColumn["ROYALTY"] <= .12]

AndやOrを使って条件を組み合せることもできる．

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "LORANGE", "ROYALTY"}, SQLColumn["ROYALTY"] == .12 && SQLColumn["LORANGE"] > 1000]
Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLColumn["ROYALTY"] == .12 || SQLColumn["ROYALTY"] == .14]

オプション"GetAsStrings"を使うと，データをWolfram言語型に変換しないで取り出すことができる．次の式はデータを変換せずに前と同じクエリを実行する．

Wolfram Language code: SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, SQLColumn["ROYALTY"] == .12 || SQLColumn["ROYALTY"] == .14, "GetAsStrings" -> True]//InputForm

オプション"SortingColumns"を使ってデータをどのようにソートするかを指定することもできる．このオプションは規則のリストを取る．規則の左辺で列を指定し，右辺で増加列，減少列のどちらでソートするのかを指定する．リストの最初の項目は，補助的な項目に優先する．

Wolfram Language code: data = SQLSelect[conn, "ROYSCHED", {"TITLE_ID", "ROYALTY"}, "SortingColumns" -> {SQLColumn["ROYALTY"] -> "Ascending", SQLColumn["TITLE_ID"] -> "Ascending"}]

プロットすると，データがソートされたことが分かる．

Wolfram Language code: ListLinePlot[Last /@ data]

オプション"Timeout"を使うと，実行に時間がかかりすぎるクエリをキャンセルすることができる．

接続を閉じる．

Wolfram Language code: CloseSQLConnection[conn];

Wolfram言語式がデータベースに保管されている型にどのようにマップされるかについては「データ型マッピング」に詳しく記載されている．