WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ElementMeshRegionProduct[mesh1,mesh2]

mesh1 と mesh2 のElementMeshの直積を表す．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
"RegionMarkerFunction"  
アプリケーション  
関連項目
テクニカルノート
関連するガイド
引用書式
NDSolve`FEM`
NDSolve`FEM`

ElementMeshRegionProduct

ElementMeshRegionProduct[mesh1,mesh2]

mesh1 と mesh2 のElementMeshの直積を表す．

詳細とオプション

  • ElementMeshRegionProductは，外積領域あるいは領域の押し出しとしても知られている．
  • ElementMeshRegionProduct[mesh1,mesh2]は，領域を表す．
  • 積の領域の埋込み次元は，埋込み次元の和であり，幾何学的次元は，幾何学的次元の和である．
  • サポートされる積の最高次元は3である．
  • ElementMeshRegionProductには，以下の追加と変更に加えて，ToElementMeshと同じオプションが使える．
  • "RegionMarkerFunction" None領域のマーカーを指定する

例題

すべて開く すべて閉じる

例  (2)

パッケージをロードする：

Wolfram Language code: Needs["NDSolve`FEM`"]

ElementMeshを作成する：

Wolfram Language code: mesh = ToElementMesh[Line[{{0}, {1}}]]

ElementMeshの領域の積を計算する：

Wolfram Language code: productMesh = ElementMeshRegionProduct[mesh, mesh]

領域の積のメッシュを可視化する：

Wolfram Language code: productMesh["Wireframe"]

ElementMeshのインスタンスを3個作成する：

Wolfram Language code: meshX = ToElementMesh[Line[{{0}, {2}}]]; meshY = ToElementMesh[Line[{{0}, {1}}]]; meshZ = ToElementMesh[Line[{{0}, {3}}]];

ElementMeshの領域の積を計算する：

Wolfram Language code: productMesh = ElementMeshRegionProduct[meshX, meshY, meshZ]

領域の積のメッシュを可視化する：

Wolfram Language code: productMesh["Wireframe"]

スコープ  (1)

ElementMeshのインスタンスを2個作成する：

Wolfram Language code: meshXY = ToElementMesh[Disk[], MaxCellMeasure -> 0.1]; meshZ = ToElementMesh[Line[{{0}, {3}}]];

領域の積を形成することによって，1つ目のElementMeshを2つ目に押し出す：

Wolfram Language code: productMesh = ElementMeshRegionProduct[meshXY, meshZ]

領域の積のメッシュを可視化する：

Wolfram Language code: productMesh["Wireframe"]

オプション  (2)

"RegionMarkerFunction"  (2)

マーカーの連想と領域メンバー関数を作成する：

Wolfram Language code: regs = <|"solid" -> 10, "fluid" -> 20|>; rmf = RegionMember[Rectangle[{1.2, 0}, {1.8, 3}]];

領域マーカー関数を定義する：

Wolfram Language code: myRegionMarkerFunction = With[{rmf = rmf, rs = regs["solid"], rf = regs["fluid"]}, If[rmf[#], rs, rf]&];

各方向に使われるElementMeshを作成する：

Wolfram Language code: mesh = ToElementMesh[Line[{{0.}, {3.}}]];

ElementMesh領域の積を計算する：

Wolfram Language code: mesh = ElementMeshRegionProduct[mesh, mesh, "RegionMarkerFunction" -> myRegionMarkerFunction]

生成されたメッシュの"MeshElementMarkerUnion"を調べる：

Wolfram Language code: mesh["MeshElementMarkerUnion"]

領域マーカーと一緒に領域の積のメッシュを可視化する：

Wolfram Language code: Show[mesh["Wireframe"["MeshElementStyle" -> {Directive[FaceForm[Red]], Directive[FaceForm[Green]]}]], AspectRatio -> 1]

マーカーの連想と領域メンバー関数を作成する：

Wolfram Language code: regs = <|"left" -> 1, "central" -> 3, "right" -> 2|>; rLeft = RegionMember[Cuboid[{0, 0, 0}, {0.8, 2, 2}]]; rCentral = RegionMember[Cuboid[{0.8, 0, 0}, {1.2, 2, 2}]]; rRight = RegionMember[Cuboid[{1.2, 0, 0}, {2, 2, 2}]];

領域マーカー関数を定義する：

Wolfram Language code: myRegionMarkerFunction = With[{rmf = rmf, rl = regs["left"], rc = regs["central"], rr = regs["right"]}, If[rLeft[#], rl, If[rCentral[#], rc, rr]]&];

各方向に使われるElementMeshを作成する：

Wolfram Language code: mesh = ToElementMesh[Line[{{0.}, {2.}}]];

ElementMesh領域の積を計算する：

Wolfram Language code: mesh = ElementMeshRegionProduct[mesh, mesh, mesh, "RegionMarkerFunction" -> myRegionMarkerFunction]

生成されたメッシュの"MeshElementMarkerUnion"を調べる：

Wolfram Language code: mesh["MeshElementMarkerUnion"]

領域マーカーと一緒に領域の積のメッシュを可視化する：

Wolfram Language code: Show[Map[mesh["Wireframe"[ElementMarker == #[[1]], "MeshElement" -> "MeshElements", "ElementMeshDirective" -> Directive[EdgeForm[], FaceForm[#[[2]]]]]]&, {{1, Green}, {2, Orange}, {3, Red}}] , PlotRange -> {All, {1, 2}, All}]

アプリケーション  (2)

2つの1Dグレーデッドメッシュの積から2Dグレーデッドメッシュを作成する：

Wolfram Language code: mesh = ToGradedMesh[Line[{{0}, {2}}], <| "Alignment" -> "Left"|>]; productMesh = ElementMeshRegionProduct[mesh, mesh]; productMesh["Wireframe"]

"Central"の点分布を持つ1Dグレーデッドメッシュを作成する：

Wolfram Language code: meshX = ToGradedMesh[Line[{{0}, {2}}], <|"Alignment" -> "Central"|>];

"Central"の点分布と50個の要素を持つ，2つ目の1Dグレーデッドメッシュを作成する：

Wolfram Language code: meshY = ToGradedMesh[Line[{{0}, {1}}], <|"Alignment" -> "Central", "ElementCount" -> 50|>];
Wolfram Language code: [image]

領域の積を構築する：

Wolfram Language code: productMesh = ElementMeshRegionProduct[meshX, meshY]

異方性メッシュの領域の積を可視化する：

Wolfram Language code: productMesh["Wireframe"]

"BothEnds"の点分布と50個の要素を持ち，端点の距離が1/200である3つ目の1Dグレーデッドメッシュを作成する：

Wolfram Language code: meshZ = ToGradedMesh[Line[{{0}, {1}}], <| "Alignment" -> "BothEnds", "ElementCount" -> 50, "MinimalDistance" -> 1 / 200|>]

領域の積を構築する：

Wolfram Language code: productMesh = ElementMeshRegionProduct[productMesh, meshZ]

3Dグレーデッドメッシュを可視化する：

Wolfram Language code: productMesh["Wireframe"]
Wolfram Research (2021), ElementMeshRegionProduct, Wolfram言語関数， https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshRegionProduct.html （2023年に更新）.

テキスト

Wolfram Research (2021), ElementMeshRegionProduct, Wolfram言語関数， https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshRegionProduct.html （2023年に更新）.

CMS

Wolfram Language. 2021. "ElementMeshRegionProduct." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshRegionProduct.html.

APA

Wolfram Language. (2021). ElementMeshRegionProduct. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshRegionProduct.html

BibTeX

@misc{reference.wolfram_2026_elementmeshregionproduct, author="Wolfram Research", title="{ElementMeshRegionProduct}", year="2023", howpublished="\url{https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshRegionProduct.html}", note=[Accessed: 14-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_elementmeshregionproduct, organization={Wolfram Research}, title={ElementMeshRegionProduct}, year={2023}, url={https://reference.wolfram.com/language/FEMDocumentation/ref/ElementMeshRegionProduct.html}, note=[Accessed: 14-August-2026]}