InitializePDECoefficients::femcsp

詳細

このメッセージは，偏微分方程式が移流に支配されており，数値的に不安定性が見られる場合に生成される．
詳細は，「有限要素法の使用上のヒント」のチュートリアルに記載されている．
Off[message]はメッセージを非表示にし，On[message]はメッセージを表示させる．例えば，Off[InitializePDECoefficients::femcsp]のように使う．

例題

例 (3)

Wolfram Language code: Needs["NDSolve`FEM`"]

この例では，計算されたペクレ（Péclet）数は，微分方程式が不安定である可能性があることを示す．ペクレ数は明示的なメッシュが与えられた場合にのみ計算される：

Wolfram Language code:

NDSolveValue[{D[c[t, x], t] + Inactive[Div][{{-0.005}} . Inactive[Grad][c[t, x], {x}], {x}] + Derivative[0, 1][c][t, x] == 0, c[0, x] == 100, DirichletCondition[c[t, x] == 100, x == 0]}, c, {t, 0, 500}, x∈ToElementMesh[Line[{{0}, {1}}]]]

より細かいメッシュを使うことによってこの問題は回避できる：

Wolfram Language code:

NDSolveValue[{D[c[t, x], t] + Inactive[Div][{{-0.005}} . Inactive[Grad][c[t, x], {x}], {x}] + Derivative[0, 1][c][t, x] == 0, c[0, x] == 100, DirichletCondition[c[t, x] == 100, x == 0]}, c, {t, 0, 500}, x∈ToElementMesh[Line[{{0}, {1}}], "MaxCellMeasure" -> 0.01]]

この例では，初期条件がないので，時間依存の偏微分方程式は三次元の空間偏微分方程式として取り扱われる．三次元偏微分方程式は，移流に支配される：

Wolfram Language code:

NDSolveValue[{D[F[t, tt], t] == Cos[t] - Cos[tt] + 0.1 * Laplacian[F[t, tt], {t, tt}], F[0, tt] == 0}, F, Element[{t, tt}, ToElementMesh[Triangle[{{0, 0}, {50, 0}, {0, 50}}]]]]

時間依存の微分方程式を純粋な空間解として計算することが目的である場合には，メッセージが示す問題は，より細かいメッシュを使うことによって避けることができる：

Wolfram Language code:

NDSolveValue[{D[F[t, tt], t] == Cos[t] - Cos[tt] + 0.1 * Laplacian[F[t, tt], {t, tt}], F[0, tt] == 0}, F, Element[{t, tt}, ToElementMesh[Triangle[{{0, 0}, {50, 0}, {0, 50}}], MaxCellMeasure -> 0.1]]]

もし時間依存の微分方程式を空間離散化を持つ時間依存方程式として計算することが目的である場合には，与えられた初期条件と時間領域は空間領域から切り離されるべきである：

Wolfram Language code:

NDSolveValue[{D[F[t, tt], t] == Cos[t] - Cos[tt] + 0.1 * Laplacian[F[t, tt], {tt}], F[0, tt] == 0}, F, {t, 0, 50}, Element[{tt}, ToElementMesh[Line[{{0}, {50}}]]]]