"Table"

GUIKit`

"Table"

GUIKitで提供されていた機能は，組込みのWolfram言語にネイティブのインターフェース構造およびコントロール関数で利用できるようになった．

Widget["Table"]

表を表す．

詳細

Widget["Table"]を使用する際は，まずNeeds["GUIKit`"]を使って GUIKit をロードする必要がある．
デフォルトでは，すべてのセルが編集可能である．Widget["DisplayOnlyTable"]内のセルはすべて編集不可能である．
デフォルトで，表中のほとんどのデータは数列でありセル内で左揃えになっている．しかし，チェックボックス，右揃えのテキスト，アイコンをそれぞれについて使って，表中の列からブール値，数値，画像をよりネイティブに制御して取り出すことができる．
画像の表示にはもとの画像の破損を防ぐために"columnEditable"をFalseに設定する必要があるだろう．
表は現在のところ同じ列内の異なる行の異なるデータタイプの描画をサポートしていないので，指定の列内のすべてのデータが第1行のタイプまたは，指定されているのであれば"prototype"特性タイプにマッチすることが重要である
使用可能な特性：

"items"	{}	表のコンテンツ
"tableHeader"	Null	表のヘッダ
"rowSelectionAllowed"	True	行ごとの選択が可能かどうか
"columnSelectionAllowed"	False	列ごとの選択が可能かどうか
"columnEditable"	Null	各列内のセルが編集可能かどうか
"columnSortable"	Null	各列がヘッダのクリックでソートできるかどうか
"prototype"	Null	典型的なデータの行をどのようにフォーマットするか
"model"		ユーザインターフェースと表中のデータを仲介するモデル

例題

すべて開くすべて閉じる

例 (1)

Wolfram Language code: Needs["GUIKit`"]

Wolfram Language code:

ref = GUIRun[
	Widget["Table", {}, InitialArguments -> {2, 3}]
	];

Wolfram Language code: GUIScreenShot[ref]

スクロールビュー内に基本的な表を作る：

Wolfram Language code:

ref = GUIRun[
	Widget["Panel", {
	Widget["ScrollPane", {
	"preferredSize" -> Widget["Dimension", {"width" -> 200, "height" -> 110}], 
	"viewportView" -> Widget["Table", {
	"items" -> {{"a1", "b1", "c1"}, {"a2", "b2", "c2"}}, 
	PropertyValue["model", Name -> "myTableModel"]
	}, Name -> "myTable"]
	}]
	}]
	]

Wolfram Language code: GUIScreenShot[ref]

表全体のコンテンツを得る：

Wolfram Language code: ref @ PropertyValue[{"myTable", "items"}]

個々の行を得，設定する：

Wolfram Language code:

ref @ SetPropertyValue[{"myTable", "items"}, 
	 Table[ToString[{i, j}], {i, 1, 4}, {j, 1, 3}]]

Wolfram Language code: GUIScreenShot[ref]

Wolfram Language code: ref @ PropertyValue[{"myTable", "item", 2}]

Wolfram Language code:

ref @ SetPropertyValue[{"myTable", "item", 1}, 
	 {"10", "100", "1000"}]

Wolfram Language code: GUIScreenShot[ref]

列のヘッダを変更する：

Wolfram Language code:

ref @ SetPropertyValue[{"myTableModel", "columnIdentifiers"}, 
	{"One", "Two", "Three"}]

Wolfram Language code: GUIScreenShot[ref]

"model"コンポーネントを使って行を追加する：

Wolfram Language code: ref @ InvokeMethod[{"myTableModel", "addRow"}, {"x", "y", "z"}]

Wolfram Language code: GUIScreenShot[ref]

列を追加する：

Wolfram Language code: ref @ InvokeMethod[{"myTableModel", "addColumn"}, "Id", {"1", "2", "3", "4", "5"}]

Wolfram Language code: GUIScreenShot[ref]

行を削除する：

Wolfram Language code: ref @ InvokeMethod[{"myTableModel", "removeRow"}, 0]

Wolfram Language code: GUIScreenShot[ref]

Wolfram Language code: ref @ InvokeMethod[{"myTableModel", "insertRow"}, 2, {"i", "j", "k"}]

Wolfram Language code: GUIScreenShot[ref]

クエリを行って個々のセルを変更する：

Wolfram Language code: ref @ InvokeMethod[{"myTableModel", "getValueAt"}, 1, 1]

Wolfram Language code: ref @ InvokeMethod[{"myTableModel", "setValueAt"}, "Test", 1, 1]

Wolfram Language code: GUIScreenShot[ref]

特性と関係 (4)

表のヘッダ (1)

Wolfram Language code: Needs["GUIKit`"]

"tableHeader"特性をNullに設定して列のヘッダが表示されないようにする：

Wolfram Language code:

ref = GUIRun[
	Widget["Panel", {
	Widget["ScrollPane", {
	"preferredSize" -> Widget["Dimension", {"width" -> 200, "height" -> 80}], 
	"viewportView" -> Widget["Table", {
	"tableHeader" -> Null, 
	"items" -> Script[{{"a1", "b1", "c1"}, {"a2", "b2", "c2"}}], 
	PropertyValue["model", Name -> "myTableModel"]
	}, Name -> "myTable"]
	}]
	}]
	]

Wolfram Language code: GUIScreenShot[ref]

編集可能性 (1)

Wolfram Language code: Needs["GUIKit`"]

画像を表示する場合は"columnEditable"を常にFalseにする：

Wolfram Language code:

ref = GUIRun[
	Widget["Panel", {
	Widget["ScrollPane", {
	"preferredSize" -> Widget["Dimension", {"width" -> 200, "height" -> 110}], 
	"viewportView" -> Widget["Table", {
	"columnEditable" -> {False, True, True}, 
	"items" -> {
	{Widget["Icon", {"path" -> "Wolfram/Example/Play16.gif"}], True, 45.0}, 
	{Widget["Icon", {"data" -> Script[ExportString[ToBoxes[f''[β], TraditionalForm], "GIF", "TransparentColor" -> GrayLevel[1]]]}], False, 67.9}
	}, 
	PropertyValue["model", Name -> "myTableModel"]
	}, Name -> "myTable"]
	}]
	}]
	]

Wolfram Language code: GUIScreenShot[ref]

ブール値のチェックボックス列のみ編集可とする：

Wolfram Language code:

ref = GUIRun[
	Widget["Panel", {
	Widget["ScrollPane", {
	"preferredSize" -> Widget["Dimension", {"width" -> 200, "height" -> 110}], 
	"viewportView" -> Widget["Table", {
	"columnEditable" -> {True, False, False}, 
	"items" -> {{True, "b1", 45.0}, {False, "b2", 67.9}}, 
	PropertyValue["model", Name -> "myTableModel"]
	}, Name -> "myTable"]
	}]
	}]
	]

Wolfram Language code: GUIScreenShot[ref]

ソート (1)

Wolfram Language code: Needs["GUIKit`"]

最初の2列のみソート可とする：

Wolfram Language code:

ref = GUIRun[
	Widget["Panel", {
	Widget["ScrollPane", {
	"preferredSize" -> Widget["Dimension", {"width" -> 200, "height" -> 110}], 
	"viewportView" -> Widget["Table", {
	"columnSortable" -> {True, True, False}, 
	"items" -> {{"Alpha", 65, True}, {"Beta", 89, False}, {"Gamma", 40, True}}, 
	PropertyValue["model", Name -> "myTableModel"], 
	SetPropertyValue[{"myTableModel", "columnIdentifiers"}, 
	{"Name", "Value", "Display"}], 
	}, Name -> "myTable"]
	}
	 ]
	}]
	]

Wolfram Language code: GUIScreenShot[ref]

ソートをやり直した後：

Wolfram Language code: GUIScreenShot[ref]

ソート順が変わるたびに新たな順で出力する（外部から保存されたデータをソートし直すのに便利である）：

Wolfram Language code:

ref = GUIRun[
	Widget["Panel", {
	Widget["ScrollPane", {
	"preferredSize" -> Widget["Dimension", {"width" -> 200, "height" -> 110}], 
	"viewportView" -> Widget["Table", {
	"columnSortable" -> {True, True, False}, 
	"items" -> {{"Alpha", 65, True}, {"Beta", 89, False}, {"Gamma", 40, True}}, 
	PropertyValue["model", Name -> "myTableModel"], 
	SetPropertyValue[{"myTableModel", "columnIdentifiers"}, 
	{"Name", "Value", "Display"}]
	}, Name -> "myTable"]
	}], 
	BindEvent[{"myTableModel", "tableSorted"}, 
	Script[Print[ PropertyValue[{"myTableModel", "ordering"}]]
	] ]
	}]
	]

データタイプ (1)

Wolfram Language code: Needs["GUIKit`"]

第1列にブール値，最終列に数値の入った表を構築する：

Wolfram Language code:

ref = GUIRun[
	Widget["Panel", {
	Widget["ScrollPane", {
	"preferredSize" -> Widget["Dimension", {"width" -> 200, "height" -> 110}], 
	"viewportView" -> Widget["Table", {
	"items" -> {{True, "b1", 45.0}, {False, "b2", 67.9}}, 
	PropertyValue["model", Name -> "myTableModel"]
	}, Name -> "myTable"]
	}]
	}]
	]

Wolfram Language code: GUIScreenShot[ref]

値を適切な形式で得る：

Wolfram Language code: ref @ PropertyValue[{"myTable", "items"}] // InputForm

"prototype"特性を使ってデータタイプのデフォルト描画を無効にする：

Wolfram Language code:

ref = GUIRun[
	Widget["Panel", {
	Widget["ScrollPane", {
	"preferredSize" -> Widget["Dimension", {"width" -> 200, "height" -> 110}], 
	"viewportView" -> Widget["Table", {
	"prototype" -> {"a", "a", "a"}, 
	"items" -> {{True, "b1", 45.0}, {False, "b2", 67.9}}, 
	PropertyValue["model", Name -> "myTableModel"]
	}, Name -> "myTable"]
	}]
	}]
	]

Wolfram Language code: GUIScreenShot[ref]

インタラクティブな例題 (1)

Wolfram Language code: Needs["GUIKit`"]

表がいつ変更されたかを知らせるバインディングを設定する：

Wolfram Language code:

ref = GUIRun[
	Widget["Panel", {
	Widget["ScrollPane", {
	"preferredSize" -> Widget["Dimension", {"width" -> 300, "height" -> 60}], 
	"viewportView" -> Widget["Table", {
	"tableHeader" -> Null, 
	"items" -> Script[{{"a1", "b1", "c1"}, {"a2", "b2", "c2"}}], 
	PropertyValue["model", Name -> "myTableModel"]
	}, Name -> "myTable"]
	}], 
	
	BindEvent[{"myTableModel", "tableChanged"}, 
	Script[
	Switch[PropertyValue[{"#", "type"}], 
	PropertyValue[{"#", "INSERT"}], 
		InvokeMethod[{"messageArea", "append"}, "inserted "], 
	PropertyValue[{"#", "UPDATE"}], 
		InvokeMethod[{"messageArea", "append"}, "updated "], 
	PropertyValue[{"#", "DELETE"}], 
		InvokeMethod[{"messageArea", "append"}, "deleted "]
	];
	InvokeMethod[{"messageArea", "append"}, "from row " <> ToString[PropertyValue[{"#", "firstRow"}] ] <> 
	" to row " <> ToString[PropertyValue[{"#", "lastRow"}] ] <> 
	" in column " <>   ToString[PropertyValue[{"#", "column"}] ] <> "
"]
	]], 
	
	Widget["ScrollPane", {
	"viewportView" -> Widget["TextArea", {
	"columns" -> 20, "rows" -> 5
	}, Name -> "messageArea"]
	}]
	}]
	]

Wolfram Language code: GUIScreenShot[ref]

値を更新し行を加える：

Wolfram Language code: ref @ InvokeMethod[{"myTableModel", "setValueAt"}, "Test", 1, 1]

Wolfram Language code: ref @ InvokeMethod[{"myTableModel", "addRow"}, {"x", "y", "z"}]

Wolfram Language code: GUIScreenShot[ref]

Top

その他のラーニングリソース

テクニカルサポート

Wolframソリューション

教育のためのWolframソリューション

使い始める

Grow Your Skills

Wolframと繋がる

大人用の教育プログラム

若者のための教育プログラム

読む

"Table"

詳細

例題

例 (1)

特性と関係 (4)

表のヘッダ (1)

編集可能性 (1)

ソート (1)

データタイプ (1)

インタラクティブな例題 (1)

"Table"

詳細

例題

例 (1)

特性と関係 (4)

表のヘッダ (1)

編集可能性 (1)

ソート (1)

データタイプ (1)

インタラクティブな例題 (1)

関連項目

テクニカルノート