WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

生成されたコードを調べる

MicrocontrollerEmbedCodeは生成されたソースコードと，そのコードの他の特性を調べるのに使用できるMicrocontrollerCodeDataオブジェクトを返す．

パッケージをロードする．
Wolfram Language code: Needs["MicrocontrollerKit`"]
MicrocontrollerEmbedCodeはMicrocontrollerCodeDataオブジェクトを返す．
Wolfram Language code: ℳ1 = MicrocontrollerEmbedCode[StateSpaceModel[{{}, {}, {}, {{1}}}, SamplingPeriod -> 1, SystemsModelLabels -> None], <|"Target" -> "ArduinoUno", "Inputs" -> "A0" -> "Analog", "Outputs" -> "3" -> "Analog"|>, "/dev/tty.usbmodem14101"]

"SourceCode"特性を使って生成されたソースコードを取得する．

ソースコード．
Wolfram Language code: Framed[StringTrim[ℳ1["SourceCode"]], Background -> Lighter[LightGreen, 0.4]]

ソースコードは特定の作業ディレクトリに送り出すこともできる．

ソースコードを置く一時ディレクトリを作成する．
Wolfram Language code: wdir = CreateDirectory[];
Wolfram Language code: ℳ2 = MicrocontrollerEmbedCode[StateSpaceModel[{{}, {}, {}, {{1}}}, SamplingPeriod -> 1, SystemsModelLabels -> None], <|"Target" -> "ArduinoUno", "Inputs" -> "Serial", "Outputs" -> "Serial"|>, "/dev/tty.usbmodem14101", <|"WorkingDirectory" -> wdir, "CleanIntermediate" -> False|>]
ディレクトリにはソースコードとその他の中間ファイルがある．
Wolfram Language code: FileNames["*", wdir]

ソースコードは生成されたコードすべての最も完全な情報を有しているが，マイクロコントローラのレジスタの特定の設定が何を意味しているのかを理解するためには，マイクロコントローラのデータシートも相互参照する必要がある．

このような情報には，特性を使って直接得られるものもある．

シリアル通信の設定．
Wolfram Language code: Dataset[ℳ2["Serial"]]

生成されたコードの対象となるマイクロコントローラの指定を示す特性もある．

一般的なマイクロコントローラの指定．
Wolfram Language code: Table[{p, ℳ1[p]}, {p, {"Target", "Microcontroller", "OperatingVoltage", "ClockFrequency"}}];
Wolfram Language code: Grid[%, Background -> {None, {{LightBlue, White}}}, Frame -> True]

診断情報を示す特定もある．

プログラマによって標準エラーに送られたデータ．
Wolfram Language code: Framed[StringTrim[ℳ1["StandardError"]], Background -> Lighter[LightGray, 0.8]]
終了コード．
Wolfram Language code: ℳ1["ExitCode"]
ファイルサイズ．
Wolfram Language code: Table[{p, ℳ1[p]}, {p, {"SourceCodeByteCount", "MachineCodeByteCount"}}];
Wolfram Language code: Grid[%, Background -> {None, {{Lighter[Brown, 0.7], White}}}, Frame -> True]

利用できる全特性は，特性データを使って調べられる．

利用できる特性．
Wolfram Language code: ℳ2["Properties"];
Wolfram Language code: Grid[Partition[%, 4], Frame -> All, Background -> {None, {{LightYellow, White}}}]
すべての場合にすべての特性が利用できるわけではない．
Wolfram Language code: ℳ1["Serial"]