WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

スパイラルベベルギア

このチュートリアルは，OpenCascadeLinkを使った，スパイラルベベルギヤ（まがりばかさ歯車）の生成方法を示すためのものである．その形状と作成過程は，コンピュータを使用した設計(CAD)のチュートリアル[1]に基づく．

1.gif

歯車の作成は，数ステップに分けて行う．まず，軸（シャフト）を作成する．次に歯車（ギア）を作成する．軸と歯車を繋げる．軸にボスを加え，最後に歯車に穴を開ける．

パッケージをロードする．
Wolfram Language code: Needs["OpenCascadeLink`"] Needs["NDSolve`FEM`"]

軸

軸は，X-Z平面の横断面を指定して作成する．この横断面が，X軸の周りで回転させて作成する立体の基礎となる．

2.gif

横断面は，2つの線分と1つの半円からなる．

軸の横断面を指定する．
Wolfram Language code: length = 163; radius = 11; s1 = Line[{{0, 0, 0}, {0, 0, 45}, {5, 0, 45}, {5, 0, 39}, {-112 + length, 0, 39}, {-112 + length, 0, 38}, {-80 + length - 2 radius, 0, 38}, {-80 + length - 2 radius, 0, 36}}]; s2 = OpenCascadeCircle[{{length - 80 - radius, 0, 36}, {0, -1, 0}}, radius, {π, 2π}]; s3 = Line[{{-80 + length, 0, 36}, {-32 + length, 0, 36}, {-32 + length, 0, 32.5}, {length, 0, 32.5}, {length, 0, 0}, {0, 0, 0}}];

ここで線分の方向が重要となる．線分の方向が逆であると，回転の結果できる立体は，軸外の領域を指定することになる．線分の方向が逆向きになっている場合には，回転軸を正反対の方向にすればよい．こうすれば，線分を再度指定せずに済む．

横断面を指定する．
Wolfram Language code: crossSection = {s1, s2, s3};
軸の横断面を可視化する．
Wolfram Language code: Show[ Graphics3D[crossSection /. OpenCascadeCircle -> Circle3D], OpenCascadeAxis3D[{0, 0, 0}, {200, 25, 50}], Boxed -> False]
横断面から OpenCascade オブジェクトを作成する．
Wolfram Language code: s = OpenCascadeShape /@ crossSection
線分を組み合せて，1つのワイヤオブジェクトにする．
Wolfram Language code: shape = OpenCascadeShapeWire[s] OpenCascadeShapeType[shape]

OpenCascadeShapeUnionを使って線分を組み合せて単一のオブジェクトにすることも可能だが， そうするとOpenCascadeShapeUnionが複合物を返す．複合物だと，中に何があるのかが分かりにくい．

次に，横断面をX軸に沿って回転軸の周りで回転させる．

回転軸を作成する．
Wolfram Language code: rotationAxis = {{0, 0, 0}, {200, 0, 0}}; Graphics3D[{crossSection /. OpenCascadeCircle -> Circle3D, {Red, Arrow[rotationAxis]}}]
回転軸の周りで横断面の回転スイープを作成する．
Wolfram Language code: shaft = OpenCascadeShapeRotationalSweep[shape, rotationAxis]
作成した形状オブジェクトのタイプを調べる．
Wolfram Language code: OpenCascadeShapeType[shaft]

横断面を回転させて出来たものは，殻である．回転させた入力がワイヤであったからである．しかし，ここで必要なのは中空ではない立体である．

殻から立体を作成し，タイプを調べる．
Wolfram Language code: shaft = OpenCascadeShapeSolid[shaft] OpenCascadeShapeType[shaft]

横断面を作成するもう一つの方法として，Polygonを使うこともできる．これらは，面タイプの OpenCascade オブジェクトであり，回転させると OpenCascade の立体になる．

境界要素メッシュを抽出する．
Wolfram Language code: bmesh = OpenCascadeShapeSurfaceMeshToBoundaryMesh[shaft(*,"ShapeSurfaceMeshOptions"->{"LinearDeflection"->0.001}*)]
軸の境界要素メッシュを可視化する．
Wolfram Language code: Show[ shaftGR = bmesh["Wireframe"["MeshElementStyle" -> Directive[FaceForm[LightGray]]]], OpenCascadeAxis3D[{-10, 0, 0}, {200, 75, 75}]]

意図した通りに境界メッシュが構築できたかどうかを確かめるために，完全な要素メッシュを生成する．

完全な要素メッシュを作成する．
Wolfram Language code: ToElementMesh[bmesh, "MeshOrder" -> 1]

デフォルトよりも小さい"LinearDeflection"の値で境界要素メッシュを作成した場合には，警告メッセージは表示されない．

歯車

歯車の作成は，2ステップで行う．まず，歯車の歯の半分をYZ平面でモデル化する．半分の歯は，円の3つのセクションを組み合せることによって構築する．この半分の歯を軸で鏡映して完全な歯を作る．この1つの歯を回転させ，YZ平面で歯車の歯一式を作る．その後，YZ平面の歯車をYZ平面に平行な2つめの平面で平行移動，回転，スケールさせる．この過程をもう一度繰り返して，YZ平面に平行な3つ目の平面に3つ目の歯一式を作る．実際の歯車は，これらの平面を押し出す形で作成する．これでロフトが作成される．

4.gif

歯車の歯

歯車の歯は，3つの円を交差させ，その境界部分を取ることで作成する．

5.gif

まず，2Dでの歯車の歯の生成の過程を示すことから始める．

長さの異なる半径を定義する．
Wolfram Language code: r1 = 85; r2 = 50; r3 = 65;
交差点を指定する．
Wolfram Language code: N[p1 = r1 {Cos[θ], Sin[θ]} /. θ -> (π - ArcCos[6 / r1])] N[p2 = r2{Cos[θ], Sin[θ]} /. θ -> (π - ArcCos[15 / r2])]
指定の交差点を通り，指定の半径 r3 を持つ3つ目の円の座標を求める．
Wolfram Language code: eqn = (x - x1) ^ 2 + (y - y1) ^ 2 == r3 ^ 2; N[p3 = {x, y} /. Solve[{eqn /. Thread[Rule[{x1, y1}, p1]], eqn /. Thread[Rule[{x1, y1}, p2]], x > 0, y > 0}, {x, y}][[1]]]
3つの円と関連する交差点を可視化する．
Wolfram Language code: Graphics[{Circle[{0, 0}, r1], Circle[{0, 0}, r2], Circle[p3, r3], {Green, Dashed, Arrow[{{0, 0}, {0, 120}}]}, {Red, PointSize[0.02], Point[p1], Point[p2]}, {Gray, Dashed, Line[{{0, 0}, 120{Cos[θ], Sin[θ]} /. θ -> (π / 2 + 2 π / 16)}]}}]
p3 から3つの円について弧の角度を計算する．
Wolfram Language code: N[θ1 = (θ /. Solve[r3 {Cos[θ], Sin[θ]} + p3 == p1, θ] /. C[1] -> 0)[[1]]] N[θ2 = (θ /. Solve[r3 {Cos[θ], Sin[θ]} + p3 == p2, θ] /. C[1] -> 0)[[1]]]
歯車の歯の半分を形成する円弧を可視化する．
Wolfram Language code: Graphics[{ {LightGray, Circle[{0, 0}, r1], Circle[{0, 0}, r2], Circle[p3, r3]}, Circle[{0, 0}, r1, {π / 2, π - ArcCos[6 / r1]}], Circle[{0, 0}, r2, {π - ArcCos[15 / r2], (π / 2 + 2 π / 16)}], Circle[p3, r3, {θ1, 2π + θ2}], {Red, PointSize[0.02], Point[p1], Point[p2]}, {Blue, PointSize[0.02], Point[p3]}, {Blue, Dashed, Line[{p3, p1}], Line[{p3, p2}]}, {Green, Dashed, Arrow[{{0, 0}, {0, 120}}]}, {Gray, Dashed, Line[{{0, 0}, 120{Cos[θ], Sin[θ]} /. θ -> (π / 2 + 2 π / 16)}]}}]
半分の歯を鏡映させ，歯を回転させて，歯車の歯一式を作る．
Wolfram Language code: halfTooth = { Circle[{0, 0}, r1, {π / 2, π - ArcCos[6 / r1]}], Circle[{0, 0}, r2, {π - ArcCos[15 / r2], (π / 2 + 2 π / 16)}], Circle[p3, r3, {θ1, 2π + θ2}]}; rft = ReflectionTransform[{1, 0}]; tooth = {halfTooth, GeometricTransformation[halfTooth, rft]}; rot = RotationTransform[2π / 8]; gr2D = Graphics[NestList[GeometricTransformation[#, rot]&, tooth, 7]]

次に，この方法を3Dに応用する．Wolfram言語には，3Dで使えるCircleプリミティブがないので，OpenCascadeLinkを使う．プリミティブを使うと，円が通過する座標を指定することができる．

3つ目の弧の端点を計算する．
Wolfram Language code: N[p4 = r2{Cos[θ], Sin[θ]} /. θ -> (π / 2 + 2 π / 16)]
OpenCascadeの3DのCircleプリミティブを設定する．
Wolfram Language code: c1 = OpenCascadeCircle[{{0, 0, 0}, {1, 0, 0}}, r1, {{0, 0, r1}, Join[{0}, p1]}]; c2 = OpenCascadeCircle[{Join[{0}, p3], {1, 0, 0}}, r3, {Join[{0}, p1], Join[{0}, p2]}]; c3 = OpenCascadeCircle[{{0, 0, 0}, {1, 0, 0}}, r2, {Join[{0}, p2], Join[{0}, p4]}];
OpenCascadeの形状オブジェクトを作成する．
Wolfram Language code: shapes = OpenCascadeShape /@ {c1, c2, c3};
弧のセグメントから単一のワイヤを作る．
Wolfram Language code: ocHalfTooth = OpenCascadeShapeWire[shapes]
結果のタイプを調べる．
Wolfram Language code: OpenCascadeShapeType[ocHalfTooth]

次に，半分の歯をZ軸に沿って鏡映させる．

Z軸の方向に回転変換を設定する．
Wolfram Language code: rot1 = RotationTransform[Pi, {0, 0, 1}]
半分の歯と鏡映された半分の歯を組み合せて，完全な歯車の歯を作成する．
Wolfram Language code: ocTooth = OpenCascadeShapeWire[{ocHalfTooth, OpenCascadeShape[ocHalfTooth, rot1]}]
2π/8のステップでX軸方向に回転変換を設定する．
Wolfram Language code: rott = Table[RotationTransform[k * 2π / 8, {1, 0, 0}], {k, 0, 7}];
X軸の周りで単一の歯を数回回転させて，YZ軸で歯車の輪郭のワイヤを作成する．
Wolfram Language code: ocGearProfile1 = OpenCascadeShapeWire[OpenCascadeShapeTransformation[ocTooth, #]& /@ rott]

3Dで作成した歯車の輪郭を可視化するために， X軸方向に平坦な輪郭を拡張させる．この作業は可視化のために行うことであり，歯車の構築には必要ない．

3Dの歯車の輪郭を軸と一緒に可視化する．
Wolfram Language code: temp = OpenCascadeShapeLinearSweep[ocGearProfile1, {{0, 0, 0}, {1, 0, 0}}]; Show[OpenCascadeShapeSurfaceMeshToBoundaryMesh[temp]["Wireframe"], shaftGR, OpenCascadeAxis3D[{-10, 0, 0}, {200, 75, 75}]]

平面を作成する

歯車の輪郭を作った後は，その輪郭をスケール，回転，平行移動させて，互いに平行な歯車の輪郭をYZ平面に作成する．

2つ目の歯車の輪郭を作成する．
Wolfram Language code: ocGearProfile2 = OpenCascadeShapeTransformation[ocGearProfile1, ScalingTransform[0.75 * {1, 1, 1}, {0, 0, 0}]]; ocGearProfile2 = OpenCascadeShapeTransformation[ocGearProfile2, RotationTransform[-15 Degree, {1, 0, 0}]]; ocGearProfile2 = OpenCascadeShapeTransformation[ocGearProfile2, TranslationTransform[{-45, 0, 0}]];
3つ目の歯車の輪郭を作成する．
Wolfram Language code: ocGearProfile3 = OpenCascadeShapeTransformation[ocGearProfile1, ScalingTransform[0.5 * {1, 1, 1}, {0, 0, 0}]]; ocGearProfile3 = OpenCascadeShapeTransformation[ocGearProfile3, RotationTransform[-30 Degree, {1, 0, 0}]]; ocGearProfile3 = OpenCascadeShapeTransformation[ocGearProfile3, TranslationTransform[{-95, 0, 0}]];
歯車の輪郭を可視化する．
Wolfram Language code: temp = OpenCascadeShapeLinearSweep[#, {{0, 0, 0}, {2, 0, 0}}]& /@ {ocGearProfile1, ocGearProfile2, ocGearProfile3}; Show[OpenCascadeShapeSurfaceMeshToBoundaryMesh[#]["Wireframe"["MeshElementStyle" -> FaceForm[Red]]]& /@ temp]
YZ平面で歯車の輪郭を通る曲面を作成して，完全な3Dの歯車を作成する．
Wolfram Language code: gear = OpenCascadeShapeLoft[{ocGearProfile1, ocGearProfile2, ocGearProfile3}, "BuildSolid" -> True]
境界要素メッシュを抽出する．
Wolfram Language code: bmesh = OpenCascadeShapeSurfaceMeshToBoundaryMesh[gear];
歯車の境界要素メッシュを可視化する．
Wolfram Language code: Show[ gearGR = bmesh["Wireframe"["MeshElementStyle" -> Directive[FaceForm[LightGray]]]], OpenCascadeAxis3D[{-100, 0, 0}, {120, 75, 75}]]

意図した通りに境界メッシュが構築されたことを確かめるために，完全な要素メッシュを生成する．

完全な要素メッシュを作成する．
Wolfram Language code: ToElementMesh[bmesh, "MeshOrder" -> 1]

組み合せる

これで軸と歯車を組み合せることができる．

軸と歯車の和を作成する．
Wolfram Language code: bevelGear = OpenCascadeShapeUnion[shaft, gear]
境界要素メッシュを抽出する．
Wolfram Language code: bmesh = OpenCascadeShapeSurfaceMeshToBoundaryMesh[bevelGear];
軸と歯車の和の境界要素メッシュを可視化する．
Wolfram Language code: Show[ bevelGearGR = bmesh["Wireframe"["MeshElementStyle" -> Directive[FaceForm[LightGray]]]], OpenCascadeAxis3D[{-100, 0, 0}, {300, 75, 75}]]

意図した通りに境界メッシュが構築されたことを確かめるために，完全な要素メッシュを生成する．

完全な要素メッシュを作成する．
Wolfram Language code: ToElementMesh[bmesh, "MeshOrder" -> 1]

ボス

ボスを作るために使われるCuboidを作成する．
Wolfram Language code: boss = Cuboid[{length - 80, -5, 36 - 2}, {length - 32, 5, 36 + 5}]
かさ歯車（ベベルギア）と単一のボスを可視化する．
Wolfram Language code: Show[bevelGearGR, Graphics3D[boss]]
ボスが軸の曲面と正しく交差することを確かめる．
Wolfram Language code: Show[bevelGearGR, Graphics3D[boss], PlotRange -> ((# + {-10, 10})& /@ Transpose[List@@boss])]
13個のボスを作成する．
Wolfram Language code: s = OpenCascadeShape[boss]; num = 13; s = OpenCascadeShapeTransformation[s, #]& /@ Table[RotationTransform[k * 2π / num, {1, 0, 0}], {k, 1, num}];
かさ歯車とボスの和を形成する．
Wolfram Language code: bevelGearBoss = OpenCascadeShapeUnion[Flatten[{bevelGear, s}]]
境界要素メッシュを抽出する．
Wolfram Language code: bmesh = OpenCascadeShapeSurfaceMeshToBoundaryMesh[bevelGearBoss];
軸と歯車の和の境界要素メッシュを可視化する．
Wolfram Language code: Show[ bevelGearGR = bmesh["Wireframe"["MeshElementStyle" -> Directive[FaceForm[LightGray]]]], OpenCascadeAxis3D[{-100, 0, 0}, {300, 75, 75}]]

意図した通りに境界メッシュが構築されたことを確かめるために，完全な要素メッシュを生成する．

完全な要素メッシュを作成する．
Wolfram Language code: ToElementMesh[bmesh, "MeshOrder" -> 1]

中空軸

オブジェクトに穴を開けるために使うCylinderを作成する．
Wolfram Language code: cyl = Cylinder[{{-120, 0, 0}, {200, 0, 0}}, 35 / 2]
かさ歯車と，せん孔のための円柱を可視化する．
Wolfram Language code: Show[bevelGearGR, Graphics3D[cyl]]
かさ歯車と円柱の差を作成する．
Wolfram Language code: bevelGearBoss = OpenCascadeShapeDifference[bevelGearBoss, OpenCascadeShape[cyl]]
境界要素メッシュを抽出する．
Wolfram Language code: bmesh = OpenCascadeShapeSurfaceMeshToBoundaryMesh[bevelGearBoss];
軸と歯車の和の境界要素メッシュを可視化する．
Wolfram Language code: Show[ bevelGearGR = bmesh["Wireframe"["MeshElementStyle" -> Directive[FaceForm[LightGray]]]], OpenCascadeAxis3D[{-100, 0, 0}, {300, 75, 75}]]

意図した通りに境界メッシュが構築されたことを確かめるために，完全な要素メッシュを生成する．

完全な要素メッシュを作成する．
Wolfram Language code: ToElementMesh[bmesh, "MeshOrder" -> 1]
細分化された曲面近似の境界要素メッシュを抽出する．
Wolfram Language code: bmesh = OpenCascadeShapeSurfaceMeshToBoundaryMesh[bevelGearBoss, "ShapeSurfaceMeshOptions" -> {"LinearDeflection" -> 0.001}];
Wolfram Language code: Show[ bevelGearGR = bmesh["Wireframe"["MeshElementStyle" -> Directive[FaceForm[LightGray]]]], OpenCascadeAxis3D[{-100, 0, 0}, {300, 75, 75}]]
完全なメッシュを作成し，かさ歯車を可視化する．
Wolfram Language code: mesh = ToElementMesh[bmesh, "MeshOrder" -> 1, "MaxCellMeasure" -> Infinity]; Show[mesh["Wireframe"["MeshElementStyle" -> Directive[FaceForm[LightGray], EdgeForm[]]]], mesh["Edgeframe"]]

初期化

以下のヘルパ関数は，3D空間で円を可視化するためのものである．

Wolfram Language code: Circle3D[{centre_, normal_}, radius_ : 1, angle_ : {0, 2 Pi}] := Module[{r, mp, mp3D}, r = DiscretizeGraphics[Circle[centre[[{1, 2}]], radius, angle]]; mp = MeshPrimitives[r, 1, Multicells -> True]; mp3D = mp /. {x_Real, y_Real} :> {x, y, centre[[3]]}; RotationTransform[{{0, 0, 1}, normal}, centre] /@ mp3D ]

参考文献

[1] https://www.youtube.com/watch?v=VihInzgm0QA