WOLFRAM

Wolfram 语言与系统参考资料中心

How to| 进行线性回归

线性回归模型是最常见的统计模型之一. 线性模型通过预测变量或预测变量函数的线性组合预测反应变量的值. 在 Wolfram 语言中，LinearModelFit 将返回一个对象，包含线性回归模型的拟合信息，可以很容易提取结果和诊断信息.

模拟一个数据集：

Wolfram Language code: data = Table[{3 + i + RandomReal[{-3, 7}], i + RandomReal[{-2, 5}]}, {i, 1, 20}];

用 LinearModelFit 创建数据的线性模型：

Wolfram Language code: model = LinearModelFit[data, x, x]

提取模型的函数形式：

Wolfram Language code: model["BestFit"]

绘制模型的函数形式：

Wolfram Language code: Plot[model["BestFit"], {x, 0, 20}]

显示数据和最佳拟合直线：

Wolfram Language code: Show[ListPlot[data], Plot[model["BestFit"], {x, 0, 30}]]

获取有关参数估计的信息：

Wolfram Language code: model["ParameterTable"]

提取和绘制标准化的残差与拟合残值：

Wolfram Language code: {sr, fr} = model[{"StandardizedResiduals", "FitResiduals"}]; {{ListPlot[sr], ListPlot[fr]}}//GraphicsGrid

按照观察数绘制库克距离：

Wolfram Language code: ListPlot[model["CookDistances"], Filling -> Axis, FillingStyle -> Thick, PlotStyle -> Thick]

另外，绘制库克距离与预测值：

Wolfram Language code: ListPlot[Transpose[{data[[All, 1]], model["CookDistances"]}], Filling -> Axis, FillingStyle -> Thick, PlotStyle -> Thick]

前面的示例选择性地演示了 LinearModelFit 所支持的一些属性；还有更多属性可供使用：

Wolfram Language code: model["Properties"]