WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AllowedCloudParameterExtensions

APIFunctionおよび関連関数のオプションで，APIあるいは他の入力パラメータにどのような拡張子を許可するかを指定する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
考えられる問題  
関連項目
関連するガイド
関連するワークフロー
履歴
引用書式

AllowedCloudParameterExtensions

AllowedCloudParameterExtensions

APIFunctionおよび関連関数のオプションで，APIあるいは他の入力パラメータにどのような拡張子を許可するかを指定する．

詳細

  • 拡張子は，URL等で入力パラメータを key__extension=val として指定することを許可する．拡張子はAPIあるいは他のクラウド実行コードに渡される実際の値を val からどのように派生させるかを定義する．
  • 次の拡張子がサポートされている．
  • "url"指定したURLからデータを取り出す
    "json"与えられた文字列をJSONとして解釈する
    "wl"与えられた文字列をWolfram言語のデータとして解釈する
    "csv"与えられた文字列をCSVとして解釈する
    "tsv"与えられた文字列をTSVとして解釈する
    "cloudobject"指定されたクラウドオブジェクトからデータを取り出す
  • AllowedCloudParameterExtensionsには次の設定が可能である．
  • None拡張子は許可しない
    Allサポートされる任意の拡張子を許可する
    Automatic安全な拡張子（現在は"json"）を許可する
    {ext1,ext2,…}任意の拡張子 extiを許可する
  • "wl"拡張子は，Wolfram言語のデータのみのサブセットに相当する．

例題

すべて開く すべて閉じる

例  (2)

JSON符号化された行列を取るAPIFunctionを配備する：

Wolfram Language code: api = CloudDeploy @ APIFunction[ "data" -> SquareRepeatingElement["Integer"], Det[#data]&, AllowedCloudParameterExtensions -> {"json"} ]
Wolfram Language code: URLExecute[api, {"data__json" -> "[[1, 2], [3, 4]]"}]

Wolfram言語データとして与えられたパラメータを取るAPIFunctionを配備する：

Wolfram Language code: api = CloudDeploy @ APIFunction[ "positions" -> CompoundElement[<|"city" -> "City", "country" -> "Country"|>], GeoGraphics[{GeoMarker[#positions["city"]], Polygon[#positions["country"]]}]&, "PNG", AllowedCloudParameterExtensions -> {"wl"} ]
Wolfram Language code: URLExecute[api, {"positions__wl" -> ToString[<|"city" -> "marseille", "country" -> "italy"|>, InputForm]}]

スコープ  (1)

URLまたはCloudObjectがフェッチできるAPIFunctionを配備する：

Wolfram Language code: api = CloudDeploy @ APIFunction[ "image" -> "Image", ColorNegate[ImageResize[#image, 150]] &, "PNG", AllowedCloudParameterExtensions -> {"url", "cloudobject"} ]
Wolfram Language code: URLExecute[api, {"image__cloudobject" -> "39794024-abcc-4ac2-8d9c-a0fe635f840f"}]
Wolfram Language code: URLExecute[api, {"image__url" -> "https://upload.wikimedia.org/wikipedia/commons/5/53/%27Willy%27_smiling._Mary_Dillwyn_Col._1853.jpg"}]

考えられる問題  (2)

"url"あるいは"cloudobject"を許可すると，悪意のあるユーザが配備元のクラウドクレジットを多量に使う方法でデータを送ることを許可することになるかもしれない：

Wolfram Language code: obj = CloudDeploy[Delayed[Pause[10];1, "WL"]]
Wolfram Language code: api = CloudDeploy[APIFunction["x" -> "Integer", #x&, AllowedCloudParameterExtensions -> {"cloudobject"}]]
Wolfram Language code: URLExecute[api, {"x__cloudobject" -> "https://www.wolframcloud.com/objects/60e09d7b-15f8-45cb-a7c3-ef4fb39733d8"}]

AllowedCloudParameterExtensionsを設定して"wl"を許可することは，任意のWolfram言語の式を許すことにはならない：

Wolfram Language code: api = CloudDeploy @ APIFunction[ "col" -> "Color", Plot[Sin[x], {x, 0, 10}, PlotStyle -> #col]&, "PNG", AllowedCloudParameterExtensions -> {"wl"} ]
Wolfram Language code: URLExecute[api, {"col__wl" -> "Quit[]"}]
Wolfram Language code: URLExecute[api, {"col__wl" -> "RGBColor[1,0,0]"}]
Wolfram Research (2017), AllowedCloudParameterExtensions, Wolfram言語関数， https://reference.wolfram.com/language/ref/AllowedCloudParameterExtensions.html.

テキスト

Wolfram Research (2017), AllowedCloudParameterExtensions, Wolfram言語関数， https://reference.wolfram.com/language/ref/AllowedCloudParameterExtensions.html.

CMS

Wolfram Language. 2017. "AllowedCloudParameterExtensions." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/AllowedCloudParameterExtensions.html.

APA

Wolfram Language. (2017). AllowedCloudParameterExtensions. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AllowedCloudParameterExtensions.html

BibTeX

@misc{reference.wolfram_2026_allowedcloudparameterextensions, author="Wolfram Research", title="{AllowedCloudParameterExtensions}", year="2017", howpublished="\url{https://reference.wolfram.com/language/ref/AllowedCloudParameterExtensions.html}", note=[Accessed: 14-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_allowedcloudparameterextensions, organization={Wolfram Research}, title={AllowedCloudParameterExtensions}, year={2017}, url={https://reference.wolfram.com/language/ref/AllowedCloudParameterExtensions.html}, note=[Accessed: 14-September-2026]}