WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

AudioSpectralMap[f,audio]

関数 f を短時間フーリエ(Fourier)変換に適用することで音声信号を変換する．

AudioSpectralMap[f,{audio1,…}]

関数 f をすべての audioiの短時間フーリエ変換のリストに適用する．

AudioSpectralMap[f,video]

video の最初の音声トラックを変換する．

詳細とオプション
Details and Options Details and Options
例題  
例  
スコープ  
オプション  
PartitionGranularity  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

AudioSpectralMap

AudioSpectralMap[f,audio]

関数 f を短時間フーリエ(Fourier)変換に適用することで音声信号を変換する．

AudioSpectralMap[f,{audio1,…}]

関数 f をすべての audioiの短時間フーリエ変換のリストに適用する．

AudioSpectralMap[f,video]

video の最初の音声トラックを変換する．

詳細とオプション

  • AudioSpectralMapを使って，時間領域と周波数領域の両方で任意に信号を変更することができる．分光フィルタを使って特定の時間の特定の周波数を，弱めたり，ハイライトしたり，変更したりすることができる（例：ノイズを除去する）．
  • AudioSpectralMapは関数 f を短時間フーリエ変換に適用し，重畳加算法を使って逆関数を計算する．
  • 関数 f は短時間フーリエ変換の値を第1引数として取る．周波数と時間も第2および第3引数として f に任意で与えることができる．
  • #Value または #1短時間フーリエ変換の値
    #Frequency または #2周波数（単位：Hz）
    #Time または #3時間（単位：秒）
  • 多チャンネル音声オブジェクトについては，変換は各チャンネル別々に行われる．
  • 複数の音声信号がある場合は，#Valueは値のリストになる．audioiに#Value〚i〛を使う．
  • AudioSpectralMapは，各分割の長さとオフセット，および平滑化窓が指定できるPartitionGranularityオプションを取る．

例題

すべて開く すべて閉じる

例  (1)

音声信号の分光フィルタリング：

Wolfram Language code: AudioSpectralMap[#Value ^ 1.5&, \!\(\*AudioBox["![Embedded Audio Player](audio://content-9xyt6)"]\)]//AudioNormalize

スコープ  (3)

各スペクトル成分にその周波数を掛ける：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-cnp9u)"]\);
Wolfram Language code: AudioSpectralMap[#Value * #Frequency&, a]//AudioNormalize

各スペクトル成分に時間を掛ける：

Wolfram Language code: AudioSpectralMap[#Value * #Time&, a]//AudioNormalize

2つのサウンド間で変化させる：

Wolfram Language code: a1 = \!\(\*AudioBox["![Embedded Audio Player](audio://content-tmu5d)"]\);a2 = \!\(\*AudioBox["![Embedded Audio Player](audio://content-1il6e)"]\);

2つの短時間フーリエ変換に掛け算を行う：

Wolfram Language code: AudioSpectralMap[Times@@#Value&, {a1, a2}]

最初の音声の大きさと2番目の音声の位相を使う：

Wolfram Language code: AudioSpectralMap[Abs@#Value[[1]] * Exp[-I Arg@#Value[[2]]]&, {a1, a2}]

動画の音声トラックを処理する：

Wolfram Language code: AudioSpectralMap[#Value ^ 1.5&, \!\(\*VideoBox["![Video Player: ExampleData/fish.mp4](video://content-2sfji)"]\)]

オプション  (1)

PartitionGranularity  (1)

デフォルトで，分光フィルタリングに適した自動分割が使われる：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-72ua6)"]\);
Wolfram Language code: AudioSpectralMap[#Value ^ 1.5&, a]//AudioNormalize

分割サイズを指定する：

Wolfram Language code: AudioSpectralMap[#Value ^ 1.5&, a, PartitionGranularity -> Quantity[80, "Milliseconds"]]//AudioNormalize

分割サイズ，オフセット，平滑化窓を指定する：

Wolfram Language code: AudioSpectralMap[#Value ^ 1.5&, a, PartitionGranularity -> {.08, .005, HannWindow}]//AudioNormalize

アプリケーション  (8)

振幅が小さいすべての成分を除去することで，音声信号のノイズを除去する：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-cnp9u)"]\); Spectrogram[a]
Wolfram Language code: AudioSpectralMap[If[Abs@#Value < 4, 0., #Value]&, a]
Wolfram Language code: Spectrogram[%]

1000Hzより小さい成分を除去することでローパスフィルタを作る：

Wolfram Language code: a = AudioGenerator["White", 1, SampleRate -> 8000];
Wolfram Language code: Spectrogram[a]
Wolfram Language code: AudioSpectralMap[#Value (1 - UnitStep[#Frequency - 1000])&, a]
Wolfram Language code: Spectrogram[%]

ハイパスフィルタを作る：

Wolfram Language code: AudioSpectralMap[#Value UnitStep[#Frequency - 1000]&, a]
Wolfram Language code: Spectrogram[%]

0.5秒より小さい時間の全成分をゼロにする：

Wolfram Language code: a = AudioGenerator["White", 1, SampleRate -> 8000];
Wolfram Language code: Spectrogram[a]
Wolfram Language code: AudioSpectralMap[#Value (UnitStep[#Time - .5])&, a]
Wolfram Language code: Spectrogram[%]

すべての成分にランダムな位相を割り当ててささやき効果を出す：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"]; AudioSpectralMap[#Value Exp[I RandomReal[2Pi]]&, a]

ゼロに等しい位相をすべての成分に割り当ててロボットのような効果を出す：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"]; AudioSpectralMap[Abs[#Value]&, a, PartitionGranularity -> Quantity[30, "Milliseconds"]]

静かな成分の振幅を低くすると，事実上，単純なノイズ除去が行われる：

Wolfram Language code: apollo = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[value_] := (value Abs[value]/Abs[value] + 10)
Wolfram Language code: Plot[f[value], {value, 0, 10}]
Wolfram Language code: AudioSpectralMap[f, apollo]

静かな成分を完全にゼロで埋める：

Wolfram Language code: g[value_] := If[Abs[(value Abs[value]/Abs[value] + 10)] < 2, 0, value]
Wolfram Language code: Plot[g[value], {value, 0, 10}]
Wolfram Language code: AudioSpectralMap[g, apollo]

時間依存ハイパスフィルタを作る：

Wolfram Language code: a = AudioGenerator["White", SampleRate -> 8000];
Wolfram Language code: f[value_, freq_, time_] := value(Tanh[(freq - 2000 * (1 - time))] / 2 + .5)
Wolfram Language code: AudioSpectralMap[f, a]//AudioNormalize
Wolfram Language code: Spectrogram[%]

ノイズのプロファイルを引くことで信号のノイズを除去する：

Wolfram Language code: apollo = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"]
Wolfram Language code: Spectrogram[apollo]

ノイズだけを含む信号の部分を切り取る：

Wolfram Language code: noise = AudioTrim[apollo, {4, 5}]

ノイズの振幅スペクトルを計算する：

Wolfram Language code: noiseSpectrum = Abs[Fourier[First@AudioData[noise], FourierParameters -> {1, -1}]];

結果を平滑化する：

Wolfram Language code: smoothedNoiseSpectrum = MeanFilter[noiseSpectrum, 20];

平滑化されたノイズスペクトルを使って周波数領域上に補間関数を作る：

Wolfram Language code: len = Floor[Length[noiseSpectrum] / 2];f = Interpolation[Thread[{Array[#&, len, {0., 11025}], smoothedNoiseSpectrum[[ ;; len]]}]]
Wolfram Language code: Plot[f[x], {x, 0, 10000}]

各成分から対応するノイズ振幅スペクトルを引く：

Wolfram Language code: AudioSpectralMap[Clip[(Abs[#Value] - f[#Frequency]), {0, Infinity}] * Exp[-I Arg@#Value]&, apollo]
Wolfram Language code: Spectrogram[%]

特性と関係  (1)

恒等写像を各スペクトル成分に適用する：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: AudioSpectralMap[Identity, a]

この操作は，逆変換の際の重畳加算のために恒等操作ではない：

Wolfram Language code: % == a

しかし，結果はもとの信号とほんの少ししか違わない：

Wolfram Language code: {Mean[#], StandardDeviation[#]}&[AudioSpectralMap[Identity, a] - a]
Wolfram Research (2017), AudioSpectralMap, Wolfram言語関数， https://reference.wolfram.com/language/ref/AudioSpectralMap.html （2024年に更新）.

テキスト

Wolfram Research (2017), AudioSpectralMap, Wolfram言語関数， https://reference.wolfram.com/language/ref/AudioSpectralMap.html （2024年に更新）.

CMS

Wolfram Language. 2017. "AudioSpectralMap." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2024. https://reference.wolfram.com/language/ref/AudioSpectralMap.html.

APA

Wolfram Language. (2017). AudioSpectralMap. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/AudioSpectralMap.html

BibTeX

@misc{reference.wolfram_2026_audiospectralmap, author="Wolfram Research", title="{AudioSpectralMap}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/AudioSpectralMap.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_audiospectralmap, organization={Wolfram Research}, title={AudioSpectralMap}, year={2024}, url={https://reference.wolfram.com/language/ref/AudioSpectralMap.html}, note=[Accessed: 17-August-2026]}