WOLFRAM

Wolfram 语言与系统参考资料中心

AudioSpectralMap[f,audio]

通过对音频的短时傅立叶变换应用函数 f 对音频进行转换.

AudioSpectralMap[f,{audio1,…}]

对所有 audioi 的短时傅立叶变换应用函数 f.

AudioSpectralMap[f,video]

转换 video 中的第一个音轨.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
PartitionGranularity  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

AudioSpectralMap

AudioSpectralMap[f,audio]

通过对音频的短时傅立叶变换应用函数 f 对音频进行转换.

AudioSpectralMap[f,{audio1,…}]

对所有 audioi 的短时傅立叶变换应用函数 f.

AudioSpectralMap[f,video]

转换 video 中的第一个音轨.

更多信息和选项

  • AudioSpectralMap 可对时域和频域音频信号随意进行修改. 可以使用频谱滤波器减弱、突出或修改特定时间的特定频率，如移除噪声.
  • AudioSpectralMap 对短时傅立叶变换应用函数 f，并用重叠相加法计算逆变换.
  • 函数 f 接受短时傅立叶变换的值作为第一个参数. 根据需要，频率和时间可作为 f 的第二个和第三个参数：
  • #Value 或 #1短时傅立叶变换的值
    #Frequency 或 #2频率，单位为 Hz
    #Time 或 #3时间，单位为秒
  • 对于多通道音频对象，分别对每个通道进行变换.
  • 如果有多个音频信号，#Value 是数值的列表. 用 #Value〚i〛 表示 audioi.
  • AudioSpectralMap 接受 PartitionGranularity 选项，可用来指定每个分区的长度和偏移，以及平滑窗口.

范例

打开所有单元 关闭所有单元

基本范例  (1)

音频信号的频谱滤波：

Wolfram Language code: AudioSpectralMap[#Value ^ 1.5&, \!\(\*AudioBox["![Embedded Audio Player](audio://content-9xyt6)"]\)]//AudioNormalize

范围  (3)

每个频谱分量乘以自己的频率：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-cnp9u)"]\);
Wolfram Language code: AudioSpectralMap[#Value * #Frequency&, a]//AudioNormalize

每个频谱分量乘以时间：

Wolfram Language code: AudioSpectralMap[#Value * #Time&, a]//AudioNormalize

在两个声音之间进行变换：

Wolfram Language code: a1 = \!\(\*AudioBox["![Embedded Audio Player](audio://content-tmu5d)"]\);a2 = \!\(\*AudioBox["![Embedded Audio Player](audio://content-1il6e)"]\);

两个短时傅立叶变换相乘：

Wolfram Language code: AudioSpectralMap[Times@@#Value&, {a1, a2}]

用第一个信号的幅值和第二个信号的相位：

Wolfram Language code: AudioSpectralMap[Abs@#Value[[1]] * Exp[-I Arg@#Value[[2]]]&, {a1, a2}]

处理视频的音轨：

Wolfram Language code: AudioSpectralMap[#Value ^ 1.5&, \!\(\*VideoBox["![Video Player: ExampleData/fish.mp4](video://content-2sfji)"]\)]

选项  (1)

PartitionGranularity  (1)

缺省情况下，使用适合于频谱滤波的自动分区：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-72ua6)"]\);
Wolfram Language code: AudioSpectralMap[#Value ^ 1.5&, a]//AudioNormalize

指定分区的大小：

Wolfram Language code: AudioSpectralMap[#Value ^ 1.5&, a, PartitionGranularity -> Quantity[80, "Milliseconds"]]//AudioNormalize

指定分区的大小、偏移和平滑窗口：

Wolfram Language code: AudioSpectralMap[#Value ^ 1.5&, a, PartitionGranularity -> {.08, .005, HannWindow}]//AudioNormalize

应用  (8)

通过移除所有幅值较小的分量消除音频信号中的噪声：

Wolfram Language code: a = \!\(\*AudioBox["![Embedded Audio Player](audio://content-cnp9u)"]\); Spectrogram[a]
Wolfram Language code: AudioSpectralMap[If[Abs@#Value < 4, 0., #Value]&, a]
Wolfram Language code: Spectrogram[%]

通过移除小于 1000Hz 的分量创建低通滤波器：

Wolfram Language code: a = AudioGenerator["White", 1, SampleRate -> 8000];
Wolfram Language code: Spectrogram[a]
Wolfram Language code: AudioSpectralMap[#Value (1 - UnitStep[#Frequency - 1000])&, a]
Wolfram Language code: Spectrogram[%]

创建高通滤波器：

Wolfram Language code: AudioSpectralMap[#Value UnitStep[#Frequency - 1000]&, a]
Wolfram Language code: Spectrogram[%]

将所有小于 0.5 秒的分量置零：

Wolfram Language code: a = AudioGenerator["White", 1, SampleRate -> 8000];
Wolfram Language code: Spectrogram[a]
Wolfram Language code: AudioSpectralMap[#Value (UnitStep[#Time - .5])&, a]
Wolfram Language code: Spectrogram[%]

为所有分量分配一个随机相位以实现耳语特效：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"]; AudioSpectralMap[#Value Exp[I RandomReal[2Pi]]&, a]

为所有分量分配零相位以实现类似机器人的效果：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"]; AudioSpectralMap[Abs[#Value]&, a, PartitionGranularity -> Quantity[30, "Milliseconds"]]

降低静音分量的幅值实际上进行了一次简单的降噪处理：

Wolfram Language code: apollo = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: f[value_] := (value Abs[value]/Abs[value] + 10)
Wolfram Language code: Plot[f[value], {value, 0, 10}]
Wolfram Language code: AudioSpectralMap[f, apollo]

完全清除静音分量：

Wolfram Language code: g[value_] := If[Abs[(value Abs[value]/Abs[value] + 10)] < 2, 0, value]
Wolfram Language code: Plot[g[value], {value, 0, 10}]
Wolfram Language code: AudioSpectralMap[g, apollo]

创建一个与时间相关的高通滤波器：

Wolfram Language code: a = AudioGenerator["White", SampleRate -> 8000];
Wolfram Language code: f[value_, freq_, time_] := value(Tanh[(freq - 2000 * (1 - time))] / 2 + .5)
Wolfram Language code: AudioSpectralMap[f, a]//AudioNormalize
Wolfram Language code: Spectrogram[%]

通过减去噪音范本消除信号噪声：

Wolfram Language code: apollo = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"]
Wolfram Language code: Spectrogram[apollo]

剪掉信号中只含有噪声的部分：

Wolfram Language code: noise = AudioTrim[apollo, {4, 5}]

计算噪声的幅值谱：

Wolfram Language code: noiseSpectrum = Abs[Fourier[First@AudioData[noise], FourierParameters -> {1, -1}]];

对结果进行平滑处理：

Wolfram Language code: smoothedNoiseSpectrum = MeanFilter[noiseSpectrum, 20];

用经过平滑处理的噪声谱产生频域的插值函数：

Wolfram Language code: len = Floor[Length[noiseSpectrum] / 2];f = Interpolation[Thread[{Array[#&, len, {0., 11025}], smoothedNoiseSpectrum[[ ;; len]]}]]
Wolfram Language code: Plot[f[x], {x, 0, 10000}]

从每个分量中减去相应的噪声谱幅值：

Wolfram Language code: AudioSpectralMap[Clip[(Abs[#Value] - f[#Frequency]), {0, Infinity}] * Exp[-I Arg@#Value]&, apollo]
Wolfram Language code: Spectrogram[%]

属性和关系  (1)

对每个频谱分量应用恒等运算：

Wolfram Language code: a = ExampleData[{"Audio", "Apollo11SmallStep"}, "Audio"];
Wolfram Language code: AudioSpectralMap[Identity, a]

由于逆变换中的重叠和相加，该操作不是恒等运算：

Wolfram Language code: % == a

然而结果与原来的信号只有很小的差别：

Wolfram Language code: {Mean[#], StandardDeviation[#]}&[AudioSpectralMap[Identity, a] - a]
Wolfram Research (2017)，AudioSpectralMap，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AudioSpectralMap.html （更新于 2024 年）.

文本

Wolfram Research (2017)，AudioSpectralMap，Wolfram 语言函数，https://reference.wolfram.com/language/ref/AudioSpectralMap.html （更新于 2024 年）.

CMS

Wolfram 语言. 2017. "AudioSpectralMap." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2024. https://reference.wolfram.com/language/ref/AudioSpectralMap.html.

APA

Wolfram 语言. (2017). AudioSpectralMap. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/AudioSpectralMap.html 年

BibTeX

@misc{reference.wolfram_2026_audiospectralmap, author="Wolfram Research", title="{AudioSpectralMap}", year="2024", howpublished="\url{https://reference.wolfram.com/language/ref/AudioSpectralMap.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_audiospectralmap, organization={Wolfram Research}, title={AudioSpectralMap}, year={2024}, url={https://reference.wolfram.com/language/ref/AudioSpectralMap.html}, note=[Accessed: 18-August-2026]}