WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BarcodeImage["string"]

"string"のバーコード画像を"QR"形式で生成する．

BarcodeImage["string",format]

指定された format で"string"のバーコード画像を生成する．

BarcodeImage["string",format,size]

指定された size のバーコード画像を生成しようと試みる．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
関連するガイド
関連リンク
履歴
引用書式

BarcodeImage

BarcodeImage["string"]

"string"のバーコード画像を"QR"形式で生成する．

BarcodeImage["string",format]

指定された format で"string"のバーコード画像を生成する．

BarcodeImage["string",format,size]

指定された size のバーコード画像を生成しようと試みる．

詳細

  • BarcodeImageは，常にバイナリ画像を返す．
  • size の可能な値
  • widthだいたいの幅．高さは自動的に計算される
    {width,height}だいたいの幅と高さ
  • 指定された大きさではバーコードの生成に十分な解像度が得られない場合は，より大きいサイズの画像が生成される． »
  • format には次の1Dバーコード形式を使うことができる．
  • "UPC"UPC-A12桁の数字
    "UPCE"UPC-E8桁の数字
    "EAN8"EAN-88桁の数字
    "EAN13"EAN-1313桁の数字
    "Code39"コード39大文字，数字，特殊文字（-，.，$，/，+，%等），スペース（最大80個）
    "Code93"Code 93大文字，数字，特殊文字，-，.，$，/，+，%，スペース
    "Code128"コード128ASCII文字（最大80個）
    "ITF"ITF80桁までの偶数桁の数字
    "Codabar"Codabar数字と特殊文字（ :，/，+，.）
  • format には次の2Dバーコード形式を使うことができる．
  • "Aztec"Aztec（誤り訂正2）3000個のASCII文字，あるいは3748個の数字
    {"Aztec", lev}Aztec（誤り訂正 lev）ASCII文字（高レベルについてはより小さい記憶域）
    "DataMatrix"Data Matrixコード2335個のASCII文字，あるいは3116個の数字
    "QR"QR（誤り訂正22953個までのASCII文字，7089個の数字，あるいは4296個の英数字
    {"QR",lev}QR（誤り訂正 lev）ASCII文字（高レベルについてはより小さい記憶域）
    "PDF417"PDF417 （誤り訂正2）1781個までのASCII文字
    {"PDF417",lev}PDF417 （誤り訂正 lev）ASCII文字（高レベルについてはより小さい記憶域）
  • 謝り訂正レベル lev は0から8までの整数でよい．

例題

すべて開く すべて閉じる

例  (4)

URLからQRコードを生成する：

Wolfram Language code: BarcodeImage["www.wolfram.com"]

バーコードのタイプを明示的に指定する：

Wolfram Language code: BarcodeImage["www.wolfram.com", "QR"]

指定サイズのQRバーコードを生成する：

Wolfram Language code: BarcodeImage["www.wolfram.com", "QR", 100]

UPCバーコードを生成する：

Wolfram Language code: BarcodeImage["123456789999", "UPC"]

スコープ  (16)

12桁の数字コードからUPCバーコードを生成する：

Wolfram Language code: BarcodeImage["123456789999", "UPC"]

11桁コードの場合は，自動的にチェックサムが計算される：

Wolfram Language code: BarcodeImage["12345678999", "UPC"]
Wolfram Language code: BarcodeRecognize[%]

8桁の数字コードからUPCバーコードを生成する：

Wolfram Language code: BarcodeImage["12345670", "UPCE"]

7桁コードの場合はチェックサムが自動的に計算される：

Wolfram Language code: BarcodeImage["1234567", "UPCE"]
Wolfram Language code: BarcodeRecognize[%]

EAN-8バーコードを生成する：

Wolfram Language code: BarcodeImage["12345670", "EAN8"]

7桁コードの場合は，チェックサムが自動的に計算される：

Wolfram Language code: BarcodeImage["1234567", "EAN8"]
Wolfram Language code: BarcodeRecognize[%]

13桁の数字コードからEAN-13バーコードを生成する：

Wolfram Language code: BarcodeImage["1234567890128", "EAN13"]

12桁コードの場合は，自動的にチェックサムが計算される：

Wolfram Language code: BarcodeImage["123456789012", "EAN13"]
Wolfram Language code: BarcodeRecognize[%]

数字からコード39のバーコードを生成する：

Wolfram Language code: BarcodeImage["123456789", "Code39"]

英数字からコード39のバーコードを生成する：

Wolfram Language code: BarcodeImage["CODE 39", "Code39"]

数字からコード93のバーコードを生成する：

Wolfram Language code: BarcodeImage["123456789", "Code93"]

英数字の文字列からコード93のバーコードを生成する：

Wolfram Language code: BarcodeImage["CODE 93", "Code93"]

コード128のバーコードを生成する：

Wolfram Language code: BarcodeImage["abc 123 ABC!", "Code128"]

ITFバーコードを生成する：

Wolfram Language code: BarcodeImage["1234567890", "ITF"]

コーダバーバーコードを生成する：

Wolfram Language code: BarcodeImage["1234", "Codabar"]

アステカコードを生成する：

Wolfram Language code: BarcodeImage["Wolfram Research, Inc.", "Aztec"]

誤り訂正レベル7でアステカコードを生成する：

Wolfram Language code: BarcodeImage["Wolfram Research, Inc.", {"Aztec", 7}]

データ行列コードを生成する：

Wolfram Language code: BarcodeImage["1234", "DataMatrix"]

QRコードを生成する：

Wolfram Language code: BarcodeImage["1234", "QR"]

誤り訂正レベル4のQRコードを生成する：

Wolfram Language code: BarcodeImage["1234", {"QR", 4}]

PDF417コードを生成する：

Wolfram Language code: BarcodeImage["1234", "PDF417"]

誤り訂正レベル6でPDF417コードを生成する：

Wolfram Language code: BarcodeImage["1234", {"PDF417", 6}]

アプリケーション  (3)

コード39バーコードでURLをコード化する：

Wolfram Language code: BarcodeImage["WWW.WOLFRAM.COM", "Code39"]

QRコードのグラフィックスを符号化する：

Wolfram Language code: str = ToString[HoldForm[Plot[Sin[x], {x, 0, 10}]]]
Wolfram Language code: i = BarcodeImage[str, "QR"]

式を復号化して評価する：

Wolfram Language code: ToExpression[BarcodeRecognize[i]]

QRコードを視覚的透かし模様としてプロットに加える：

Wolfram Language code: Plot[Sin[x], {x, 0, 2Pi}, Epilog -> Inset[BarcodeImage["Wolfram Research, Inc.", "QR"], {Right, Top}, {Right, Top}, 1.5]]

QRコードを復号化する：

Wolfram Language code: BarcodeRecognize[%]

特性と関係  (4)

BarcodeRecognizeを使ってバーコード画像を数列に変換する：

Wolfram Language code: BarcodeImage["123456789", "QR"]
Wolfram Language code: BarcodeRecognize[%]

11桁コードからUPC-Aチェックサムを計算する：

Wolfram Language code: UPCAchecksum[code_String] := With[{digits = ToExpression /@ Characters[code]}, 10 - Mod[3Total[digits[[1 ;; -1 ;; 2]]] + Total[digits[[2 ;; -1 ;; 2]]], 10]]
Wolfram Language code: code = "12345678901"; UPCAchecksum[code]

12桁目として提供・使用されていない場合，チェックサムは自動的に計算される：

Wolfram Language code: BarcodeImage[code, "UPC"]
Wolfram Language code: {code, BarcodeRecognize[%]}

7桁コードのEAN-8チェックサムを計算する：

Wolfram Language code: EAN8checksum[str_ ? StringQ] := Module[{digits, odds = 0, evens = 0}, digits = Map[ToExpression, Characters[str]]; odds = Total[digits[[Range[7, 1, -2]]]]; evens = Total[digits[[Range[6, 1, -2]]]]; Return[Mod[10 - Mod[3 * odds + evens, 10], 10]]; ]
Wolfram Language code: code = "1234567"; EAN8checksum[code]

BarcodeImageは自動的にチェックサムを計算する：

Wolfram Language code: BarcodeImage[code, "EAN8"]
Wolfram Language code: BarcodeRecognize[%]

12桁コードについてのEAN-13チェックサムを計算する：

Wolfram Language code: EAN13checksum[code_String] := Module[{digits, weightedsum}, digits = ToExpression /@ Characters[code]; weightedsum = Total[digits[[1 ;; 12 ;; 2]]] + 3Total[digits[[2 ;; 12 ;; 2]]]; Abs[weightedsum - 10Ceiling[weightedsum / 10]] ]
Wolfram Language code: code = "123456789012"; EAN13checksum[code]

BarcodeImageは，自動的にチェックサムを計算する：

Wolfram Language code: BarcodeImage[code, "EAN13"]
Wolfram Language code: BarcodeRecognize[%]

考えられる問題  (4)

1Dのバーコード画像を生成する際は，幅指定が無視されることがある：

Wolfram Language code: BarcodeImage["123456789101112131415", "Code39", {100, 30}]

結果の幅は，バーコード画像を表すために必要最低限の幅になる：

Wolfram Language code: ImageDimensions[%]

2Dバーコード画像を生成する際にサイズ指定が無視されることがある：

Wolfram Language code: text = ExampleData[{"Text", "BeowulfModern"}];
Wolfram Language code: BarcodeImage[StringTake[text, 2500], "QR", {100, 100}]
Wolfram Language code: ImageDimensions[%]

長さおよびサポートされている文字を含む入力数列の必要条件は，形式によって異なる：

Wolfram Language code: BarcodeImage["1234", "EAN8"]
Wolfram Language code: BarcodeImage["123456789", "EAN13"]
Wolfram Language code: BarcodeImage["12345", "ITF"]
Wolfram Language code: BarcodeImage["ABCD", "UPC"]

チェックサム文字列を含む形式では，不正確なチェックサムが正しい値で置換される：

Wolfram Language code: BarcodeImage["1234567890123", "EAN13"]

おもしろい例題  (1)

2つのバーコード画像を作成し，アメリカ合衆国旗の主調色に基づいて色付けする：

Wolfram Language code: {blue, red} = FindMatchingColor[CountryData["USA", "Flag"], {Blue, Red}, MaxColorDistance -> .2]
Wolfram Language code: i1 = ColorReplace[BarcodeImage["Flag of the ", "QR", {120, 120}], Black -> blue]
Wolfram Language code: i2 = ImageRotate[ColorReplace[BarcodeImage["US", "Code39", {200, 250}], Black -> red]]

「バーコード」合衆国旗を作成するためにバーコード画像を作成する：

Wolfram Language code: ImageCompose[i2, ImagePad[i1, 3, White], {Left, Top}, {Left, Top}]

画像中のバーコードを認識する：

Wolfram Language code: StringJoin[BarcodeRecognize[%]]
Wolfram Research (2014), BarcodeImage, Wolfram言語関数， https://reference.wolfram.com/language/ref/BarcodeImage.html （2023年に更新）.

テキスト

Wolfram Research (2014), BarcodeImage, Wolfram言語関数， https://reference.wolfram.com/language/ref/BarcodeImage.html （2023年に更新）.

CMS

Wolfram Language. 2014. "BarcodeImage." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2023. https://reference.wolfram.com/language/ref/BarcodeImage.html.

APA

Wolfram Language. (2014). BarcodeImage. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BarcodeImage.html

BibTeX

@misc{reference.wolfram_2026_barcodeimage, author="Wolfram Research", title="{BarcodeImage}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/BarcodeImage.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_barcodeimage, organization={Wolfram Research}, title={BarcodeImage}, year={2023}, url={https://reference.wolfram.com/language/ref/BarcodeImage.html}, note=[Accessed: 17-August-2026]}