WOLFRAM

Wolfram 语言与系统参考资料中心

BarcodeImage["string"]

生成一个 "QR" 格式的 "string" 的条形码图像.

BarcodeImage["string",format]

以指定 format 生成 "string" 的条形码图像.

BarcodeImage["string",format,size]

尝试生成指定 size 的条形码图像.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
相关指南
相关链接
历史
按以下格式引用：

BarcodeImage

BarcodeImage["string"]

生成一个 "QR" 格式的 "string" 的条形码图像.

BarcodeImage["string",format]

以指定 format 生成 "string" 的条形码图像.

BarcodeImage["string",format,size]

尝试生成指定 size 的条形码图像.

更多信息

  • BarcodeImage 总是返回二值图像.
  • size 的可能值包括：
  • width近似宽度，高度自动计算
    {width,height}近似的宽度和高度
  • 如果指定的尺寸不能提供产生条形码所需的足够分辨率，则生成较大尺寸的图像. »
  • 以下一维条形码格式可用于 format：
  • "UPC"UPC-A12 位数字
    "UPCE"UPC-E8 位数字
    "EAN8"EAN-88 位数字
    "EAN13"EAN-1313 位数字
    "Code39"代码 39至多 80 个字符，包括大写字母、数字、特殊字符（-, ., $, /, +, %）和空格
    "Code93"代码 93大写字母，数字，特殊字符 -、.、$、/、+、%，和空格 space
    "Code128"代码 128至多 80 个 ASCII 字符
    "ITF"ITF至多 80 位等长度数字
    "Codabar"Codabar数字和特殊字符（:, /, +, .）
  • 以下二维条形码格式可用于 format：
  • "Aztec"Aztec（纠错 2）3000个 ASCII 或 3748 位数
    {"Aztec", lev}Aztec（纠错 lev）ASCII 字符（水平越高存储越少）
    "DataMatrix"数据矩阵代码2335个 ASCII 或 3116 位数
    "QR"QR（纠错 2）2953个 ASCII、7089 位数或 4296 个字母数字
    {"QR",lev}QR（纠错 lev）ASCII 字符（水平越高存储越少）
    "PDF417"PDF417（纠错 2）多达 1781个 ASCII 字符
    {"PDF417",lev}PDF417（纠错 lev）ASCII 字符（水平越高存储越少）
  • 纠错水平 lev 可为 0 到 8 之间的一个整数.

范例

打开所有单元 关闭所有单元

基本范例  (4)

根据 URL 生成一个二维码：

Wolfram Language code: BarcodeImage["www.wolfram.com"]

明确指定条形码类型：

Wolfram Language code: BarcodeImage["www.wolfram.com", "QR"]

生成一个指定大小的二维码：

Wolfram Language code: BarcodeImage["www.wolfram.com", "QR", 100]

产生 UPC 条码：

Wolfram Language code: BarcodeImage["123456789999", "UPC"]

范围  (16)

从12位数字的代码生成 UPC 条码：

Wolfram Language code: BarcodeImage["123456789999", "UPC"]

在11位代码时，自动计算校验和：

Wolfram Language code: BarcodeImage["12345678999", "UPC"]
Wolfram Language code: BarcodeRecognize[%]

根据 8 位数的数字代码生成 UPC 条形码：

Wolfram Language code: BarcodeImage["12345670", "UPCE"]

有了 7 位数的代码，就可以自动计算出校验和：

Wolfram Language code: BarcodeImage["1234567", "UPCE"]
Wolfram Language code: BarcodeRecognize[%]

生成 EAN-8 条码：

Wolfram Language code: BarcodeImage["12345670", "EAN8"]

在7位代码时，自动计算校验和：

Wolfram Language code: BarcodeImage["1234567", "EAN8"]
Wolfram Language code: BarcodeRecognize[%]

从 13 位数字的代码生成 EAN-13 条码：

Wolfram Language code: BarcodeImage["1234567890128", "EAN13"]

在 12 位代码中，自动计算校验和：

Wolfram Language code: BarcodeImage["123456789012", "EAN13"]
Wolfram Language code: BarcodeRecognize[%]

从数字生成 Code 39 条码：

Wolfram Language code: BarcodeImage["123456789", "Code39"]

从字母数字串生成 Code 39 条码：

Wolfram Language code: BarcodeImage["CODE 39", "Code39"]

根据数字生成 Code 93 条形码：

Wolfram Language code: BarcodeImage["123456789", "Code93"]

根据字母数字字符串生成 Code 93 条形码：

Wolfram Language code: BarcodeImage["CODE 93", "Code93"]

生成 Code 128 条码：

Wolfram Language code: BarcodeImage["abc 123 ABC!", "Code128"]

生成 ITF 条码：

Wolfram Language code: BarcodeImage["1234567890", "ITF"]

生成库德巴（Codabar）条码：

Wolfram Language code: BarcodeImage["1234", "Codabar"]

生成 Aztec 条码：

Wolfram Language code: BarcodeImage["Wolfram Research, Inc.", "Aztec"]

生成一个纠错等级为 7 的 Aztec 码：

Wolfram Language code: BarcodeImage["Wolfram Research, Inc.", {"Aztec", 7}]

生成数据矩阵码：

Wolfram Language code: BarcodeImage["1234", "DataMatrix"]

生成 QR 码：

Wolfram Language code: BarcodeImage["1234", "QR"]

生成一个纠错水平为 4 的二维码：

Wolfram Language code: BarcodeImage["1234", {"QR", 4}]

生成 PDF 417 条码：

Wolfram Language code: BarcodeImage["1234", "PDF417"]

生成一个纠错等级为 6 的 PDF 417 代码：

Wolfram Language code: BarcodeImage["1234", {"PDF417", 6}]

应用  (3)

将一个网址放在 Code 39 条码中：

Wolfram Language code: BarcodeImage["WWW.WOLFRAM.COM", "Code39"]

在 QR 代码中编码图形：

Wolfram Language code: str = ToString[HoldForm[Plot[Sin[x], {x, 0, 10}]]]
Wolfram Language code: i = BarcodeImage[str, "QR"]

解码并计算表达式：

Wolfram Language code: ToExpression[BarcodeRecognize[i]]

添加一个 QR 码绘制成可视化水印：

Wolfram Language code: Plot[Sin[x], {x, 0, 2Pi}, Epilog -> Inset[BarcodeImage["Wolfram Research, Inc.", "QR"], {Right, Top}, {Right, Top}, 1.5]]

解码一个 QR 代码：

Wolfram Language code: BarcodeRecognize[%]

属性和关系  (4)

使用 BarcodeRecognize 把条形码图像转换为字符串：

Wolfram Language code: BarcodeImage["123456789", "QR"]
Wolfram Language code: BarcodeRecognize[%]

从11位代码计算 UPC-A 校验和：

Wolfram Language code: UPCAchecksum[code_String] := With[{digits = ToExpression /@ Characters[code]}, 10 - Mod[3Total[digits[[1 ;; -1 ;; 2]]] + Total[digits[[2 ;; -1 ;; 2]]], 10]]
Wolfram Language code: code = "12345678901"; UPCAchecksum[code]

校验和在不被提供的情况下自动计算，并用作第 12 位数字：

Wolfram Language code: BarcodeImage[code, "UPC"]
Wolfram Language code: {code, BarcodeRecognize[%]}

计算 7 位代码的 EAN-8 校验和：

Wolfram Language code: EAN8checksum[str_ ? StringQ] := Module[{digits, odds = 0, evens = 0}, digits = Map[ToExpression, Characters[str]]; odds = Total[digits[[Range[7, 1, -2]]]]; evens = Total[digits[[Range[6, 1, -2]]]]; Return[Mod[10 - Mod[3 * odds + evens, 10], 10]]; ]
Wolfram Language code: code = "1234567"; EAN8checksum[code]

BarcodeImage 自动计算校验和：

Wolfram Language code: BarcodeImage[code, "EAN8"]
Wolfram Language code: BarcodeRecognize[%]

计算 12 位代码的 EAN-13 校验和：

Wolfram Language code: EAN13checksum[code_String] := Module[{digits, weightedsum}, digits = ToExpression /@ Characters[code]; weightedsum = Total[digits[[1 ;; 12 ;; 2]]] + 3Total[digits[[2 ;; 12 ;; 2]]]; Abs[weightedsum - 10Ceiling[weightedsum / 10]] ]
Wolfram Language code: code = "123456789012"; EAN13checksum[code]

BarcodeImage 自动计算校验和：

Wolfram Language code: BarcodeImage[code, "EAN13"]
Wolfram Language code: BarcodeRecognize[%]

可能存在的问题  (4)

在生成一维条码图像时，宽度指定可能会被忽略：

Wolfram Language code: BarcodeImage["123456789101112131415", "Code39", {100, 30}]

由此产生的宽度是表示条码图像所需的最小值：

Wolfram Language code: ImageDimensions[%]

在生成二维条码图像时，尺寸指定可能会被忽略：

Wolfram Language code: text = ExampleData[{"Text", "BeowulfModern"}];
Wolfram Language code: BarcodeImage[StringTake[text, 2500], "QR", {100, 100}]
Wolfram Language code: ImageDimensions[%]

不同的格式对输入字符串有要求，包括长度和支持的字符：

Wolfram Language code: BarcodeImage["1234", "EAN8"]
Wolfram Language code: BarcodeImage["123456789", "EAN13"]
Wolfram Language code: BarcodeImage["12345", "ITF"]
Wolfram Language code: BarcodeImage["ABCD", "UPC"]

对于具有校验字符的格式，不正确的校验和被替换为正确的值：

Wolfram Language code: BarcodeImage["1234567890123", "EAN13"]

巧妙范例  (1)

创建两个条形码图像，并根据美国国旗的主要颜色对其着色：

Wolfram Language code: {blue, red} = Flatten[Nearest[DominantColors[CountryData["USA", "Flag"], 3], #, DistanceFunction -> ColorDistance]& /@ {Blue, Red}]
Wolfram Language code: i1 = ImagePad[ColorReplace[BarcodeImage["Flag of the ", "QR", {120, 120}], Black -> blue], 3, White]
Wolfram Language code: i2 = ImageRotate[ColorReplace[BarcodeImage["US", "Code39", {200, 250}], Black -> red]]

用条码图像来创建一个“条形码”美国国旗：

Wolfram Language code: ImageCompose[i2, i1, {Left, Top}, {Left, Top}]

识别图像中的条形码：

Wolfram Language code: StringJoin[BarcodeRecognize[%]]
Wolfram Research (2014)，BarcodeImage，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BarcodeImage.html （更新于 2023 年）.

文本

Wolfram Research (2014)，BarcodeImage，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BarcodeImage.html （更新于 2023 年）.

CMS

Wolfram 语言. 2014. "BarcodeImage." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2023. https://reference.wolfram.com/language/ref/BarcodeImage.html.

APA

Wolfram 语言. (2014). BarcodeImage. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BarcodeImage.html 年

BibTeX

@misc{reference.wolfram_2026_barcodeimage, author="Wolfram Research", title="{BarcodeImage}", year="2023", howpublished="\url{https://reference.wolfram.com/language/ref/BarcodeImage.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_barcodeimage, organization={Wolfram Research}, title={BarcodeImage}, year={2023}, url={https://reference.wolfram.com/language/ref/BarcodeImage.html}, note=[Accessed: 09-August-2026]}