WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BartlettHannWindow[x]

x のBartlett–Hann窓関数を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

BartlettHannWindow

BartlettHannWindow[x]

x のBartlett–Hann窓関数を表す．

詳細

  • BartlettHannWindowは，一般に，データを短いセグメントで処理する必要がある信号処理アプリケーションで使われる窓関数である．
  • 窓関数には，データ値を漸減して各セグメントの終りで0に近付ける平滑化効果がある．
  • BartlettHannWindow[x]は (31)/(50)-(12 x)/(25)+(19)/(50) cos(2 pi x) 0<=x<=1/2; (31)/(50)+(12 x)/(25)+(19)/(50) cos(2 pi x) -1/2<=x<0; 0 TemplateBox[{x}, Abs]>1/2; に等しい．
  • BartlettHannWindowは自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (3)

1DのBartlett–Hann窓の形：

Wolfram Language code: Plot[BartlettHannWindow[x], {x, -1, 1}]

2DのBartlett–Hann窓の形：

Wolfram Language code: Plot3D[BartlettHannWindow[x]BartlettHannWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

Bartlett–Hann窓を表す連続関数を抽出する：

Wolfram Language code: FunctionExpand[BartlettHannWindow[x]]

スコープ  (4)

数値的に評価する：

Wolfram Language code: BartlettHannWindow[0.1]

平行移動され広げられたBartlett–Hann窓：

Wolfram Language code: Plot[BartlettHannWindow[(x - 1) / 2], {x, -1, 3}]

円形の台を持つ2DのBartlett–Hann窓：

Wolfram Language code: Plot3D[BartlettHannWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

長さ15の離散Bartlett–Hann窓：

Wolfram Language code: ListPlot[Array[BartlettHannWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

15×10の2D離散Bartlett–Hann窓：

Wolfram Language code: ListPointPlot3D[Array[BartlettHannWindow[#1] BartlettHannWindow[#2]&, {15, 10}, {{-1 / 2, 1 / 2}}], Filling -> Axis]

アプリケーション  (3)

長さ11の移動平均フィルタを作る：

Wolfram Language code: a = ConstantArray[1 / 11, 11]

Bartlett–Hann窓を使ってフィルタを平滑化する：

Wolfram Language code: a2 = # / Total[#]&[a Array[BartlettHannWindow, 11, {-1 / 2, 1 / 2}]];

フィルタの周波数スペクトルの対数振幅プロット：

Wolfram Language code: LogLinearPlot[Evaluate[20Log[10, Abs@ListFourierSequenceTransform[#, ω]]& /@ {a, a2}], {ω, 0.0314, Pi}, PlotRange -> All, GridLines -> Automatic, ImageSize -> 300]

窓指定を使ってサンプルPowerSpectralDensityを計算する：

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

スペクトルを計算する：

Wolfram Language code: spec = PowerSpectralDensity[data, w, BartlettHannWindow];

窓関数を使わずに計算されたスペクトル密度と比較する：

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

プロットは，窓がスペクトル密度を平坦化したことを示している：

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotRange -> All, PlotLegends -> {"no window", "with window"}]

この過程の理論的なスペクトル密度と比較する：

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

時系列推定に窓指定を使う：

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

スペクトル推定器に窓を指定する：

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> BartlettHannWindow}]

特性と関係  (2)

Bartlett–Hann窓の下の面積：

Wolfram Language code: area = Integrate[BartlettHannWindow[x], {x, -∞, ∞}]

正規化することで単位面積の窓を作る：

Wolfram Language code: Plot[{BartlettHannWindow[x], BartlettHannWindow[x] / area}, {x, -1, 1}]

Bartlett–Hann窓のフーリエ変換：

Wolfram Language code: f = FourierTransform[BartlettHannWindow[x], x, w]

Bartlett–Hann窓のパワースペクトル：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 80}]
Wolfram Research (2012), BartlettHannWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/BartlettHannWindow.html.

テキスト

Wolfram Research (2012), BartlettHannWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/BartlettHannWindow.html.

CMS

Wolfram Language. 2012. "BartlettHannWindow." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BartlettHannWindow.html.

APA

Wolfram Language. (2012). BartlettHannWindow. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BartlettHannWindow.html

BibTeX

@misc{reference.wolfram_2026_bartletthannwindow, author="Wolfram Research", title="{BartlettHannWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BartlettHannWindow.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_bartletthannwindow, organization={Wolfram Research}, title={BartlettHannWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/BartlettHannWindow.html}, note=[Accessed: 15-September-2026]}