WOLFRAM

Wolfram 语言与系统参考资料中心

BartlettHannWindow[x]

表示 x 的一个 Bartlett–Hann 窗函数.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

BartlettHannWindow

BartlettHannWindow[x]

表示 x 的一个 Bartlett–Hann 窗函数.

更多信息

  • BartlettHannWindow 是一个窗函数，通常用在信号处理中需要以短的片段对数据进行处理的应用中.
  • 窗函数通过在每个片段的末端将数据值逐渐减小为零来产生平滑效果.
  • BartlettHannWindow[x] 等价于 (31)/(50)-(12 x)/(25)+(19)/(50) cos(2 pi x) 0<=x<=1/2; (31)/(50)+(12 x)/(25)+(19)/(50) cos(2 pi x) -1/2<=x<0; 0 TemplateBox[{x}, Abs]>1/2; .
  • BartlettHannWindow 自动线性作用于列表.

范例

打开所有单元 关闭所有单元

基本范例  (3)

一维 Bartlett–Hann 窗的形状：

Wolfram Language code: Plot[BartlettHannWindow[x], {x, -1, 1}]

二维 Bartlett–Hann 窗的形状：

Wolfram Language code: Plot3D[BartlettHannWindow[x]BartlettHannWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

提取表示 Bartlett–Hann 窗的连续函数：

Wolfram Language code: FunctionExpand[BartlettHannWindow[x]]

范围  (4)

数值运算：

Wolfram Language code: BartlettHannWindow[0.1]

平移并放大 Bartlett–Hann 窗：

Wolfram Language code: Plot[BartlettHannWindow[(x - 1) / 2], {x, -1, 3}]

具有圆形支持的二维 Bartlett–Hann窗：

Wolfram Language code: Plot3D[BartlettHannWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

长度为15的离散 Bartlett–Hann 窗：

Wolfram Language code: ListPlot[Array[BartlettHannWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

离散 15×10 二维 Bartlett–Hann 窗：

Wolfram Language code: ListPointPlot3D[Array[BartlettHannWindow[#1] BartlettHannWindow[#2]&, {15, 10}, {{-1 / 2, 1 / 2}}], Filling -> Axis]

应用  (3)

创建长度为11的移动平均滤波器：

Wolfram Language code: a = ConstantArray[1 / 11, 11]

利用 Bartlett–Hann 窗使滤波器平滑：

Wolfram Language code: a2 = # / Total[#]&[a Array[BartlettHannWindow, 11, {-1 / 2, 1 / 2}]];

滤波器频谱的对数幅度图形：

Wolfram Language code: LogLinearPlot[Evaluate[20Log[10, Abs@ListFourierSequenceTransform[#, ω]]& /@ {a, a2}], {ω, 0.0314, Pi}, PlotRange -> All, GridLines -> Automatic, ImageSize -> 300]

使用窗指定，计算样本 PowerSpectralDensity：

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

计算谱：

Wolfram Language code: spec = PowerSpectralDensity[data, w, BartlettHannWindow];

与不用窗函数计算得到的谱密度比较：

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

下图显示窗使谱密度平滑：

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotRange -> All, PlotLegends -> {"no window", "with window"}]

与过程的理论谱密度比较：

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

对时间序列估计使用窗规范：

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

指定谱估计的窗：

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> BartlettHannWindow}]

属性和关系  (2)

Bartlett–Hann 窗下方的面积：

Wolfram Language code: area = Integrate[BartlettHannWindow[x], {x, -∞, ∞}]

标准化，创建一个单位面积的窗：

Wolfram Language code: Plot[{BartlettHannWindow[x], BartlettHannWindow[x] / area}, {x, -1, 1}]

Bartlett–Hann 窗的傅立叶变换：

Wolfram Language code: f = FourierTransform[BartlettHannWindow[x], x, w]

Bartlett–Hann 窗的能谱：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 80}]
Wolfram Research (2012)，BartlettHannWindow，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BartlettHannWindow.html.

文本

Wolfram Research (2012)，BartlettHannWindow，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BartlettHannWindow.html.

CMS

Wolfram 语言. 2012. "BartlettHannWindow." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BartlettHannWindow.html.

APA

Wolfram 语言. (2012). BartlettHannWindow. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BartlettHannWindow.html 年

BibTeX

@misc{reference.wolfram_2026_bartletthannwindow, author="Wolfram Research", title="{BartlettHannWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BartlettHannWindow.html}", note=[Accessed: 07-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_bartletthannwindow, organization={Wolfram Research}, title={BartlettHannWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/BartlettHannWindow.html}, note=[Accessed: 07-August-2026]}