WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BartlettWindow[x]

x のBartlett窓関数を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

BartlettWindow

BartlettWindow[x]

x のBartlett窓関数を表す．

詳細

  • BartlettWindowは，三角窓としても知られている，アンチエイリアス処理およびリサンプリングによく使われる窓関数である．
  • 窓関数は，データが短いセグメントで処理されるアプリケーションに使われ，データ値を漸減して各セグメントの終りで0に近付ける平滑化効果がある．
  • BartlettWindow[x]は 1-2 x 0<=x<=1/2; 1+2 x -1/2<=x<0; 0 TemplateBox[{x}, Abs]>1/2; に等しい．
  • BartlettWindowは自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (3)

1DのBartlett窓の形：

Wolfram Language code: Plot[BartlettWindow[x], {x, -1, 1}]

2DのBartlett窓の形：

Wolfram Language code: Plot3D[BartlettWindow[x]BartlettWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

Bartlett窓を表す連続関数を抽出する：

Wolfram Language code: FunctionExpand[BartlettWindow[x]]

スコープ  (4)

数値的に評価する：

Wolfram Language code: BartlettWindow[0.1]

平行移動され広げられたBartlett窓：

Wolfram Language code: Plot[BartlettWindow[(x - 1) / 2], {x, -1, 3}]

円形の台を持つ2DのBartlett窓：

Wolfram Language code: Plot3D[BartlettWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

長さ15の離散Bartlett窓：

Wolfram Language code: ListPlot[Array[BartlettWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

15×10の2D離散Bartlett窓：

Wolfram Language code: ListPointPlot3D[Array[BartlettWindow[#1] BartlettWindow[#2]&, {15, 10}, {{-1 / 2, 1 / 2}}], Filling -> Axis]

アプリケーション  (4)

長さ11の移動平均フィルタを作る：

Wolfram Language code: h = ConstantArray[1 / 11, 11]

Bartlett窓を使ってフィルタを漸減させる：

Wolfram Language code: w = Array[BartlettWindow, Length[h], {-1 / 2, 1 / 2}]; fir = w h;

正規化する：

Wolfram Language code: fir / Total[fir]

2つのフィルタのパワースペクトルの対数振幅プロット：

Wolfram Language code: Plot[Evaluate[20Log10[Abs@ListFourierSequenceTransform[#, ω]]& /@ {h, %}], {ω, 0, Pi}, GridLines -> Automatic]

Bartlett窓メソッドを使ってホワイトノイズ信号にフィルタをかける：

Wolfram Language code: a = AudioGenerator["White", 1, SampleRate -> 8000]; Periodogram[{a, LowpassFilter[a, 8000 π / 3, 21, BartlettWindow]}]

窓指定を使ってサンプルPowerSpectralDensityを計算する：

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

スペクトルを計算する：

Wolfram Language code: spec = PowerSpectralDensity[data, w, BartlettWindow];

窓関数を使わずに計算されたスペクトル密度と比較する：

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

プロットは，窓がスペクトル密度を平坦化したことを示している：

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotRange -> All, PlotLegends -> {"no window", "with window"}]

この過程の理論的なスペクトル密度と比較する：

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

時系列推定に窓指定を使う：

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

スペクトル推定器に窓を指定する：

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> BartlettWindow}]

特性と関係  (6)

BartlettWindowは，圧縮されたUnitTriangleに等しい：

Wolfram Language code: PiecewiseExpand[BartlettWindow[x]] === PiecewiseExpand[UnitTriangle[2x]]

Bartlett窓の下の面積：

Wolfram Language code: area = Integrate[BartlettWindow[x], {x, -∞, ∞}]

正規化することで単位面積の窓を作る：

Wolfram Language code: Plot[{BartlettWindow[x], BartlettWindow[x] / area}, {x, -1, 1}]

Bartlett窓のフーリエ変換：

Wolfram Language code: f = FourierTransform[BartlettWindow[x], x, w]

Bartlett窓のパワースペクトル：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 100}]

長さ15の離散Bartlett窓：

Wolfram Language code: Array[BartlettWindow, 15, {-0.5, 0.5}]

係数の合計が1になるように正規化する：

Wolfram Language code: % / Total[%]

正規化された長さ15の離散Bartlett窓の離散時間フーリエ変換：

Wolfram Language code: (win = Array[BartlettWindow, 15, {-0.5, 0.5}]; f = ListFourierSequenceTransform[win / Total[win], ω])

振幅スペクトル：

Wolfram Language code: Plot[Abs@f, {ω, 0, π}, PlotRange -> All]

Bartlettm窓と矩形窓のパワースペクトル：

Wolfram Language code: tab = Table[(h = Array[win, 15, {-0.5, 0.5}]; 20Log10[Abs@ListFourierSequenceTransform[h / Total[h], ω]]), {win, {BartlettWindow, DirichletWindow}}];
Wolfram Language code: Plot[tab, {ω, 0, π}, PlotRange -> {5, -80}, PlotLegends -> {BartlettWindow, DirichletWindow}]
Wolfram Research (2012), BartlettWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/BartlettWindow.html.

テキスト

Wolfram Research (2012), BartlettWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/BartlettWindow.html.

CMS

Wolfram Language. 2012. "BartlettWindow." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BartlettWindow.html.

APA

Wolfram Language. (2012). BartlettWindow. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BartlettWindow.html

BibTeX

@misc{reference.wolfram_2026_bartlettwindow, author="Wolfram Research", title="{BartlettWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BartlettWindow.html}", note=[Accessed: 14-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_bartlettwindow, organization={Wolfram Research}, title={BartlettWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/BartlettWindow.html}, note=[Accessed: 14-August-2026]}