WOLFRAM

Wolfram 语言与系统参考资料中心

BartlettWindow[x]

表示 x 的一个 Bartlett 窗函数.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

BartlettWindow

BartlettWindow[x]

表示 x 的一个 Bartlett 窗函数.

更多信息

  • BartlettWindow 亦称为三角窗，通常用于抗混叠和重新采样.
  • 窗函数被用在以较短的片段来处理数据的应用中，并且通过在每个片段的末尾将数据值逐渐减小为零来产生平滑效果.
  • BartlettWindow[x] 等价于 1-2 x 0<=x<=1/2; 1+2 x -1/2<=x<0; 0 TemplateBox[{x}, Abs]>1/2; .
  • BartlettWindow 自动线性作用于列表.

范例

打开所有单元 关闭所有单元

基本范例  (3)

一维 Bartlett 窗的形状：

Wolfram Language code: Plot[BartlettWindow[x], {x, -1, 1}]

二维 Bartlett 窗的形状：

Wolfram Language code: Plot3D[BartlettWindow[x]BartlettWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

提取表示 Bartlett 窗的连续函数：

Wolfram Language code: FunctionExpand[BartlettWindow[x]]

范围  (4)

数值运算：

Wolfram Language code: BartlettWindow[0.1]

平移并放大 Bartlett 窗：

Wolfram Language code: Plot[BartlettWindow[(x - 1) / 2], {x, -1, 3}]

具有圆形支持的二维 Bartlett 窗：

Wolfram Language code: Plot3D[BartlettWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

长度为15的离散 Bartlett 窗：

Wolfram Language code: ListPlot[Array[BartlettWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

离散 15×10 二维 Bartlett 窗：

Wolfram Language code: ListPointPlot3D[Array[BartlettWindow[#1] BartlettWindow[#2]&, {15, 10}, {{-1 / 2, 1 / 2}}], Filling -> Axis]

应用  (4)

创建长度为11的移动平均滤波器：

Wolfram Language code: h = ConstantArray[1 / 11, 11]

使用 Bartlett 窗逐渐减小滤波器：

Wolfram Language code: w = Array[BartlettWindow, Length[h], {-1 / 2, 1 / 2}]; fir = w h;

归一化：

Wolfram Language code: fir / Total[fir]

两个滤波器功率谱的对数幅图：

Wolfram Language code: Plot[Evaluate[20Log10[Abs@ListFourierSequenceTransform[#, ω]]& /@ {h, %}], {ω, 0, Pi}, GridLines -> Automatic]

使用 Bartlett 窗方法对白噪音信号进行滤波：

Wolfram Language code: a = AudioGenerator["White", 1, SampleRate -> 8000]; Periodogram[{a, LowpassFilter[a, 8000 π / 3, 21, BartlettWindow]}]

使用窗指定，计算样本 PowerSpectralDensity：

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

计算谱：

Wolfram Language code: spec = PowerSpectralDensity[data, w, BartlettWindow];

与不用窗函数计算得到的谱密度比较：

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

下图显示窗使谱密度平滑：

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotRange -> All, PlotLegends -> {"no window", "with window"}]

与过程的理论谱密度比较：

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

将窗指定用于时间序列估计：

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

指定谱估计的窗：

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> BartlettWindow}]

属性和关系  (6)

BartlettWindow 相当于被压缩的 UnitTriangle：

Wolfram Language code: PiecewiseExpand[BartlettWindow[x]] === PiecewiseExpand[UnitTriangle[2x]]

Bartlett 窗下方的面积：

Wolfram Language code: area = Integrate[BartlettWindow[x], {x, -∞, ∞}]

标准化，创建一个单位面积的窗：

Wolfram Language code: Plot[{BartlettWindow[x], BartlettWindow[x] / area}, {x, -1, 1}]

Bartlett 窗的傅立叶变换：

Wolfram Language code: f = FourierTransform[BartlettWindow[x], x, w]

Bartlett 窗的能谱：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 100}]

离散长度为 15 的 Barrlett 窗：

Wolfram Language code: Array[BartlettWindow, 15, {-0.5, 0.5}]

归一化使得系数总和为 1：

Wolfram Language code: % / Total[%]

长度为 15 的归一化离散 Bartlett 窗的离散时间傅立叶变换：

Wolfram Language code: (win = Array[BartlettWindow, 15, {-0.5, 0.5}]; f = ListFourierSequenceTransform[win / Total[win], ω])

幅值谱：

Wolfram Language code: Plot[Abs@f, {ω, 0, π}, PlotRange -> All]

Bartlett 的功率谱和矩形窗序列：

Wolfram Language code: tab = Table[(h = Array[win, 15, {-0.5, 0.5}]; 20Log10[Abs@ListFourierSequenceTransform[h / Total[h], ω]]), {win, {BartlettWindow, DirichletWindow}}];
Wolfram Language code: Plot[tab, {ω, 0, π}, PlotRange -> {5, -80}, PlotLegends -> {BartlettWindow, DirichletWindow}]
Wolfram Research (2012)，BartlettWindow，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BartlettWindow.html.

文本

Wolfram Research (2012)，BartlettWindow，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BartlettWindow.html.

CMS

Wolfram 语言. 2012. "BartlettWindow." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BartlettWindow.html.

APA

Wolfram 语言. (2012). BartlettWindow. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BartlettWindow.html 年

BibTeX

@misc{reference.wolfram_2026_bartlettwindow, author="Wolfram Research", title="{BartlettWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BartlettWindow.html}", note=[Accessed: 09-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_bartlettwindow, organization={Wolfram Research}, title={BartlettWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/BartlettWindow.html}, note=[Accessed: 09-August-2026]}