WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BitAnd[n1,n2,…]

整数 niのビットごとのANDを与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

BitAnd

BitAnd[n1,n2,…]

整数 niのビットごとのANDを与える．

詳細

  • 記号操作・数値操作の両方に適した数学的整数関数である．
  • BitAnd[n1,n2,…]はバイナリビット表現で niのすべてに1がある場所に，バイナリ表現で1があるような整数を与える． »
  • 負の整数の場合は，BitAndは2の補数表現が仮定される．
  • BitAndは自動的にリストに縫い込まれる． »

例題

すべて開く すべて閉じる

例  (1)

2つの数のビットごとのANDを計算する：

Wolfram Language code: BitAnd[61, 15]

13のバイナリ表現では，61と15のバイナリ表現の両方で1になる位置に1が存在する：

Wolfram Language code: IntegerDigits[{61, 15, 13}, 2, 6]//Column

スコープ  (4)

任意のサイズの数を使う：

Wolfram Language code: BitAnd[3 ^ 100, 5 ^ 100]

BitAndは任意の数の引数を取ることができる：

Wolfram Language code: BitAnd[3333, 5555, 7777, 9999]

負の数を使う：

Wolfram Language code: BitAnd[-2, -3]

基本的な記号の簡約は自動的に行われる：

Wolfram Language code: BitAnd[x, y, y, x]
Wolfram Language code: BitAnd[3, 5, x]
Wolfram Language code: BitAnd[1, 2, x]

アプリケーション  (7)

数の中で2番目に低い次数のビットを抽出する：

Wolfram Language code: Table[BitAnd[i, 2], {i, 10}]

Andの真理値表：

Wolfram Language code: Grid[Outer[BitAnd, {1, 0}, {1, 0}]]

ビット3か4が1かどうか「マスク」してテストする：

Wolfram Language code: Table[Sign[BitAnd[i, 2 ^ 2 + 2 ^ 3]], {i, 16}]

2のベキ乗についてテストする：

Wolfram Language code: TableForm[Table[{i, BitAnd[i, i - 1] == 0}, {i, 20}]]

ネストしたパターンを作る：

Wolfram Language code: ArrayPlot[Table[Boole[BitAnd[i, j] == 0], {i, 0, 63}, {j, 0, 63}]]

以下の構造はシェルピンスキーのガスケットに相当する：

Wolfram Language code: SierpinskiMesh[5]

のBitAndを でプロットする：

Wolfram Language code: ListLinePlot[Table[BitAnd[i, i - 1], {i, 100}]]

のBitAndを でプロットする：

Wolfram Language code: ListLinePlot[Table[BitAnd[i, 2i], {i, 64}]]

のBitAndを と でプロットする：

Wolfram Language code: ListLinePlot[Table[BitAnd[i, 2i, 3i], {i, 64}]]

特性と関係  (4)

-1はすべてのビットをオンにすることに相当する：

Wolfram Language code: BitAnd[-1, 2, x]

任意の数とそれ自身とのペアのBitAndはその数である：

Wolfram Language code: BitAnd[x, x]
Wolfram Language code: BitAnd[x, x, x]

BitAndは自動的にリストに縫い込まれる：

Wolfram Language code: BitAnd[5, Range[10]]

BitAndはOrderlessである：

Wolfram Language code: BitAnd[y, x]

おもしろい例題  (1)

平面でBitAnd[x,y]をプロットすると，正方形のネストしたパターンが現れる：

Wolfram Language code: ArrayPlot[Array[BitAnd, {63, 63}]]

三次元でプロットするとフラクタル構造が現れる：

Wolfram Language code: Graphics3D[Table[Cuboid[{i, j, BitAnd[i, j]}], {i, 31}, {j, 31}]]

この構造はシェルピンスキーのスポンジに対応する：

Wolfram Language code: SierpinskiMesh[5, 3]
Wolfram Research (1999), BitAnd, Wolfram言語関数， https://reference.wolfram.com/language/ref/BitAnd.html.

テキスト

Wolfram Research (1999), BitAnd, Wolfram言語関数， https://reference.wolfram.com/language/ref/BitAnd.html.

CMS

Wolfram Language. 1999. "BitAnd." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BitAnd.html.

APA

Wolfram Language. (1999). BitAnd. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BitAnd.html

BibTeX

@misc{reference.wolfram_2026_bitand, author="Wolfram Research", title="{BitAnd}", year="1999", howpublished="\url{https://reference.wolfram.com/language/ref/BitAnd.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_bitand, organization={Wolfram Research}, title={BitAnd}, year={1999}, url={https://reference.wolfram.com/language/ref/BitAnd.html}, note=[Accessed: 18-August-2026]}