WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BlackmanHarrisWindow[x]

x のBlackman–Harris窓関数を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

BlackmanHarrisWindow

BlackmanHarrisWindow[x]

x のBlackman–Harris窓関数を表す．

詳細

  • BlackmanHarrisWindowは，一般に，データを短いセグメントで処理する必要がある信号処理アプリケーションで使われる窓関数である．
  • 窓関数には，データ値を漸減して各セグメントの終りで0に近付ける平滑化効果がある．
  • BlackmanHarrisWindow[x]は (48829 cos(2 pi x)+14128 cos(4 pi x)+1168 cos(6 pi x)+35875)/(100000) -1/2<=x<=1/2; 0 TemplateBox[{x}, Abs]>1/2; に等しい．
  • BlackmanHarrisWindowは自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (3)

1DのBlackman–Harris窓の形：

Wolfram Language code: Plot[BlackmanHarrisWindow[x], {x, -1, 1}]

2DのBlackman–Harris窓の形：

Wolfram Language code: Plot3D[BlackmanHarrisWindow[x]BlackmanHarrisWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

Blackman–Harris窓を表す連続関数を抽出する：

Wolfram Language code: FunctionExpand[BlackmanHarrisWindow[x]]

スコープ  (4)

数値的に評価する：

Wolfram Language code: BlackmanHarrisWindow[0.1]

平行移動され広げられたBlackman–Harris窓：

Wolfram Language code: Plot[BlackmanHarrisWindow[(x - 1) / 2], {x, -1, 3}]

円形の台を持つ2DのBlackman–Harris窓：

Wolfram Language code: Plot3D[BlackmanHarrisWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

長さ15の離散Blackman–Harris窓：

Wolfram Language code: ListPlot[Array[BlackmanHarrisWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

15×10の2D離散Blackman–Harris窓：

Wolfram Language code: ListPointPlot3D[Array[BlackmanHarrisWindow[#1] BlackmanHarrisWindow[#2]&, {15, 10}, {{-1 / 2, 1 / 2}}], Filling -> Axis, PlotRange -> All]

アプリケーション  (3)

長さ11の移動平均フィルタを作る：

Wolfram Language code: h = ConstantArray[1 / 11., 11]

Blackman–Harris窓を使ってフィルタを漸減させる：

Wolfram Language code: fir = # / Total[#]&[h Array[BlackmanHarrisWindow, Length[h], {-1 / 2, 1 / 2}]];

2つのフィルタのパワースペクトルの対数振幅プロット：

Wolfram Language code: LogLinearPlot[Evaluate[20Log[10, Abs@ListFourierSequenceTransform[#, ω]]& /@ {h, fir}], {ω, 0.01, Pi}, PlotRange -> All, GridLines -> Automatic, ImageSize -> 300]

窓指定を使ってサンプルPowerSpectralDensityを計算する：

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

スペクトルを計算する：

Wolfram Language code: spec = PowerSpectralDensity[data, w, BlackmanHarrisWindow];

窓関数を使わずに計算されたスペクトル密度と比較する：

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

プロットは，窓がスペクトル密度を平坦化したことを示している：

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotRange -> All, PlotLegends -> {"no window", "with window"}]

この過程の理論的なスペクトル密度と比較する：

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

時系列推定に窓指定を使う：

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

スペクトル推定器に窓を指定する：

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> BlackmanHarrisWindow}]

特性と関係  (2)

Blackman–Harris窓の下の面積：

Wolfram Language code: area = Integrate[BlackmanHarrisWindow[x], {x, -∞, ∞}]

正規化することで単位面積の窓を作る：

Wolfram Language code: Plot[{BlackmanHarrisWindow[x], BlackmanHarrisWindow[x] / area}, {x, -1, 1}, PlotRange -> All]

Blackman–Harris窓のフーリエ変換：

Wolfram Language code: f = FourierTransform[BlackmanHarrisWindow[x], x, w]

Blackman–Harris窓のパワースペクトル：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 100}]
Wolfram Research (2012), BlackmanHarrisWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/BlackmanHarrisWindow.html.

テキスト

Wolfram Research (2012), BlackmanHarrisWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/BlackmanHarrisWindow.html.

CMS

Wolfram Language. 2012. "BlackmanHarrisWindow." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BlackmanHarrisWindow.html.

APA

Wolfram Language. (2012). BlackmanHarrisWindow. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BlackmanHarrisWindow.html

BibTeX

@misc{reference.wolfram_2026_blackmanharriswindow, author="Wolfram Research", title="{BlackmanHarrisWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BlackmanHarrisWindow.html}", note=[Accessed: 12-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_blackmanharriswindow, organization={Wolfram Research}, title={BlackmanHarrisWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/BlackmanHarrisWindow.html}, note=[Accessed: 12-August-2026]}