WOLFRAM

Wolfram 语言与系统参考资料中心

BlackmanHarrisWindow[x]

表示 x 的 Blackman–Harris 窗函数.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

BlackmanHarrisWindow

BlackmanHarrisWindow[x]

表示 x 的 Blackman–Harris 窗函数.

更多信息

  • BlackmanHarrisWindow 是一个窗函数，通常用在信号处理中需要以短的片段对数据进行处理的应用中.
  • 窗函数通过在每个片段末尾将数据值逐渐减小到零的方式产生平滑效果.
  • BlackmanHarrisWindow[x] 等于  (48829 cos(2 pi x)+14128 cos(4 pi x)+1168 cos(6 pi x)+35875)/(100000) -1/2<=x<=1/2; 0 TemplateBox[{x}, Abs]>1/2; .
  • BlackmanHarrisWindow 自动线性作用于列表.

范例

打开所有单元 关闭所有单元

基本范例  (3)

一维 Blackman–Harris 窗的形状：

Wolfram Language code: Plot[BlackmanHarrisWindow[x], {x, -1, 1}]

二维 Blackman–Harris 窗的形状：

Wolfram Language code: Plot3D[BlackmanHarrisWindow[x]BlackmanHarrisWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

提取表示 Blackman–Harris 窗的连续函数：

Wolfram Language code: FunctionExpand[BlackmanHarrisWindow[x]]

范围  (4)

数值计算：

Wolfram Language code: BlackmanHarrisWindow[0.1]

Blackman–Harris 窗的变换和伸缩：

Wolfram Language code: Plot[BlackmanHarrisWindow[(x - 1) / 2], {x, -1, 3}]

在圆形支持（support）下的二维 Blackman–Harris 窗：

Wolfram Language code: Plot3D[BlackmanHarrisWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

长度为15的离散 Blackman–Harris 窗：

Wolfram Language code: ListPlot[Array[BlackmanHarrisWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

离散15×10 二维 Blackman–Harris 窗：

Wolfram Language code: ListPointPlot3D[Array[BlackmanHarrisWindow[#1] BlackmanHarrisWindow[#2]&, {15, 10}, {{-1 / 2, 1 / 2}}], Filling -> Axis, PlotRange -> All]

应用  (3)

创建长度为 11 的移动平均滤波器：

Wolfram Language code: h = ConstantArray[1 / 11., 11]

用 Blackman–Harris 窗窄化滤波器：

Wolfram Language code: fir = # / Total[#]&[h Array[BlackmanHarrisWindow, Length[h], {-1 / 2, 1 / 2}]];

两个滤波器的功率谱的对数幅度图：

Wolfram Language code: LogLinearPlot[Evaluate[20Log[10, Abs@ListFourierSequenceTransform[#, ω]]& /@ {h, fir}], {ω, 0.01, Pi}, PlotRange -> All, GridLines -> Automatic, ImageSize -> 300]

使用窗指定，计算样本 PowerSpectralDensity：

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

计算谱：

Wolfram Language code: spec = PowerSpectralDensity[data, w, BlackmanHarrisWindow];

与不用窗函数计算得到的谱密度比较：

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

下图显示窗使谱密度平滑：

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotRange -> All, PlotLegends -> {"no window", "with window"}]

与过程的理论谱密度比较：

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

将窗指定用于时间序列估计：

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

指定谱估计的窗：

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> BlackmanHarrisWindow}]

属性和关系  (2)

Blackman–Harris 窗下的面积：

Wolfram Language code: area = Integrate[BlackmanHarrisWindow[x], {x, -∞, ∞}]

规范化以创建单位面积的窗：

Wolfram Language code: Plot[{BlackmanHarrisWindow[x], BlackmanHarrisWindow[x] / area}, {x, -1, 1}, PlotRange -> All]

Blackman–Harris 窗的傅里叶变换：

Wolfram Language code: f = FourierTransform[BlackmanHarrisWindow[x], x, w]

Blackman–Harris 窗的功率谱：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 100}]
Wolfram Research (2012)，BlackmanHarrisWindow，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BlackmanHarrisWindow.html.

文本

Wolfram Research (2012)，BlackmanHarrisWindow，Wolfram 语言函数，https://reference.wolfram.com/language/ref/BlackmanHarrisWindow.html.

CMS

Wolfram 语言. 2012. "BlackmanHarrisWindow." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/BlackmanHarrisWindow.html.

APA

Wolfram 语言. (2012). BlackmanHarrisWindow. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/BlackmanHarrisWindow.html 年

BibTeX

@misc{reference.wolfram_2026_blackmanharriswindow, author="Wolfram Research", title="{BlackmanHarrisWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BlackmanHarrisWindow.html}", note=[Accessed: 17-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_blackmanharriswindow, organization={Wolfram Research}, title={BlackmanHarrisWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/BlackmanHarrisWindow.html}, note=[Accessed: 17-August-2026]}