WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

BlackmanWindow[x]

x のBlackman窓関数を表す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

BlackmanWindow

BlackmanWindow[x]

x のBlackman窓関数を表す．

詳細

  • BlackmanWindowは，一般に，有限インパルス応答(FIR)フィルタ設計とスペクトル分析で使われる窓関数である．
  • 窓関数は，データが短いセグメントで処理されるアプリケーションに使われ，データ値を漸減して各セグメントの終りで0に近付ける平滑化効果がある．
  • Blackman窓はExactBlackmanWindowの近似である．切取り係数の結果として高周波数ロールオフが改善されるが，スペクトルのサイドローブは大きくなる．
  • BlackmanWindow[x]は 1/(50) (25 cos(2 pi x)+4 cos(4 pi x)+21) -1/2<=x<=1/2; 0 TemplateBox[{x}, Abs]>1/2; に等しい．
  • BlackmanWindowは自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (3)

1DのBlackman窓の形：

Wolfram Language code: Plot[BlackmanWindow[x], {x, -1, 1}]

2DのBlackman窓の形：

Wolfram Language code: Plot3D[BlackmanWindow[x]BlackmanWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

Blackman窓を表す連続関数を抽出する：

Wolfram Language code: FunctionExpand[BlackmanWindow[x]]

スコープ  (4)

数値的に評価する：

Wolfram Language code: BlackmanWindow[0.1]

平行移動され広げられたBlackman窓：

Wolfram Language code: Plot[BlackmanWindow[(x - 1) / 2], {x, -1, 3}]

円形の台を持つ2DのBlackman窓：

Wolfram Language code: Plot3D[BlackmanWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

長さ15の離散Blackman窓：

Wolfram Language code: ListPlot[Array[BlackmanWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

15×10の2D離散Blackman窓：

Wolfram Language code: ListPointPlot3D[Array[BlackmanWindow[#1] BlackmanWindow[#2]&, {15, 10}, {{-1 / 2, 1 / 2}}], Filling -> Axis]

アプリケーション  (4)

カットオフ周波数 ，長さ21のローパス有限インパルス応答フィルタを作る：

Wolfram Language code: h = LeastSquaresFilterKernel[{"Lowpass", π / 5}, 21]

Blackman窓を使ってフィルタを漸減させることでストップバンド減衰を向上させる：

Wolfram Language code: w = Array[BlackmanWindow, Length[h], {-1 / 2, 1 / 2}]; fir = h w;

正規化する：

Wolfram Language code: fir / Total[fir]

2つのフィルタのパワースペクトルの対数振幅プロット：

Wolfram Language code: Plot[Evaluate[20Log10[Abs@ListFourierSequenceTransform[#, ω]]& /@ {h, %}], {ω, 0, π}, GridLines -> Automatic]

Blackman窓メソッドを使ってホワイトノイズ信号にフィルタをかける：

Wolfram Language code: a = AudioGenerator["White", 1, SampleRate -> 8000]; Periodogram[{a, LowpassFilter[a, 8000 π / 3, 21, BlackmanWindow]}]

窓指定を使ってサンプルPowerSpectralDensityを計算する：

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

スペクトルを計算する：

Wolfram Language code: spec = PowerSpectralDensity[data, w, BlackmanWindow];

窓関数を使わずに計算されたスペクトル密度と比較する：

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

プロットは，窓がスペクトル密度を平坦化したことを示している：

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotRange -> All, PlotLegends -> {"no window", "with window"}]

この過程の理論的なスペクトル密度と比較する：

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

時系列推定に窓指定を使う：

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

スペクトル推定器に窓を指定する：

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> BlackmanWindow}]

特性と関係  (5)

Blackman窓の下の面積：

Wolfram Language code: area = Integrate[BlackmanWindow[x], {x, -∞, ∞}]

正規化することで単位面積の窓を作る：

Wolfram Language code: Plot[{BlackmanWindow[x], BlackmanWindow[x] / area}, {x, -1, 1}, PlotRange -> All]

Blackman窓のフーリエ変換：

Wolfram Language code: f = FourierTransform[BlackmanWindow[x], x, w]

Blackman窓のパワースペクトル：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 100}, PlotRange -> {0, -120}]

長さ15の離散Blackman窓：

Wolfram Language code: Array[BlackmanWindow, 15, {-0.5, 0.5}]

係数の合計が1になるように正規化する：

Wolfram Language code: % / Total[%]

正規化された長さ15の離散Blackman窓の離散時間フーリエ変換：

Wolfram Language code: (win = Array[HammingWindow, 15, {-0.5, 0.5}]; f = ListFourierSequenceTransform[win / Total[win], ω])

振幅スペクトル：

Wolfram Language code: Plot[Abs@f, {ω, 0, π}, PlotRange -> All]

Blackman窓と矩形窓のパワースペクトル：

Wolfram Language code: tab = Table[(h = Array[win, 15, {-0.5, 0.5}]; 20Log10[Abs@ListFourierSequenceTransform[h / Total[h], ω]]), {win, {BlackmanWindow, DirichletWindow}}];
Wolfram Language code: Plot[tab, {ω, 0, π}, PlotRange -> {5, -80}, PlotLegends -> {BlackmanWindow, DirichletWindow}]
Wolfram Research (2012), BlackmanWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/BlackmanWindow.html.

テキスト

Wolfram Research (2012), BlackmanWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/BlackmanWindow.html.

CMS

Wolfram Language. 2012. "BlackmanWindow." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/BlackmanWindow.html.

APA

Wolfram Language. (2012). BlackmanWindow. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/BlackmanWindow.html

BibTeX

@misc{reference.wolfram_2026_blackmanwindow, author="Wolfram Research", title="{BlackmanWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/BlackmanWindow.html}", note=[Accessed: 13-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_blackmanwindow, organization={Wolfram Research}, title={BlackmanWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/BlackmanWindow.html}, note=[Accessed: 13-August-2026]}