WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Blurring[r]

グラフィックスオブジェクトを半径 r のぼかし効果で描画するように指定する二次元指示子である．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
基本的な用法  
指定  
アプリケーション  
基本的なアプリケーション  
ぼかし効果  
可視化  
特性と関係  
インタラクティブな例題  
関連項目
関連するガイド
履歴
引用書式

Blurring

Blurring[r]

グラフィックスオブジェクトを半径 r のぼかし効果で描画するように指定する二次元指示子である．

詳細

  • Blurringは，ぼかしあるいはガウスぼかしとしても知られている．
  • Blurringは，通常，グラフィックスオブジェクトの画像をやわらげ，オブジェクトの特徴を隠すために使われる．
  • Blurring[r]は r 印刷用ポイント数を互いに混ぜ合せるように指定する．
  • 半径 r は印刷用ポイント数を単位として計測され，拡大前はインチに等しい．
  • Blurring[{r1,r2}]は幅に半径 r1，高さに半径 r2を使う．
  • Blurring[r]は，事実上，Blurring[{r,r}]に等しい．
  • Blurring[]は，事実上，Blurring[3]に等しい．
  • ImageScaledを使って半径を指定することができる．半径はデフォルトの画像サイズとの比であるとみなされる．

例題

すべて開く すべて閉じる

例  (3)

テキストをぼかす：

Wolfram Language code: Graphics[{Blurring[], Text[Style["Wolfram", 32]]}]

いくつかの関数をプロットする：

Wolfram Language code: Plot[{Sin[Sqrt[2] x] + Sin[x], Style[Sin[x], Blurring[3]]}, {x, 0, 10}]

パリの周りの領域をハイライトする：

Wolfram Language code: GeoGraphics[{Gray, Blurring[5], GeoDisk[Entity["City", {"Paris", "IleDeFrance", "France"}]]}]

スコープ  (12)

基本的な用法  (8)

グラフィックス指示子をぼかす：

Wolfram Language code: Graphics[{Blurring[], #}]& /@ {Point[{{6, 3}, {0, 4}, {2, 0}, {3, 2}, {9, 5}}], BSplineCurve[{{3, 3}, {3, 4}, {2, 3}, {3, 2}, {4, 3}}], Polygon[{{3, 1}, {9, 8}, {0, 5}, {9, 3}, {4, 9}}]}

Textをぼかす：

Wolfram Language code: Graphics[{Blurring[], Text[Style["Blurring", 24]]}]

プロットをぼかす：

Wolfram Language code: Plot[{3Sin[x] + x, 3Cos[x] + x}, {x, 0, 15}, PlotStyle -> Blurring /@ {3, 0}]

グラフをぼかす：

Wolfram Language code: BarChart[{1, 2, 3, 4}, ChartStyle -> Blurring /@ {6, 6, 0, 6}]

地理領域にスタイル付けする：

Wolfram Language code: Region[Style[ImplicitRegion[y ^ 2 < x (-1 + x ^ 3), {x, y}], Blurring[]]]

Imageをぼかす：

Wolfram Language code: Graphics[{Blurring[], [image]}]

ぼかしたアウトライン地図を表示する：

Wolfram Language code: GeoGraphics[{GeoStyling["OutlineMap", Directive[Opacity[0.5, Red], Blurring[20]]], Polygon[["austria"]]}]

要約ボックス：

Wolfram Language code: Blurring[]

指定  (4)

Blurring[]は，ほぼ均一的なぼかしを適用する：

Wolfram Language code: Graphics[{Blurring[], Annulus[]}]

ぼかし半径を指定する：

Wolfram Language code: Graphics[{Blurring[#], Annulus[]}, PlotRangePadding -> 1 / 2]& /@ {0, 5, 20}

水平方向と垂直方向に異なるぼかし半径を指定する：

Wolfram Language code: Graphics[{Blurring[#], Annulus[]}, PlotRangePadding -> 1 / 2]& /@ {{20, 20}, {0, 20}, {20, 0}}

デフォルトで，ぼかし半径は印刷用ポイント数で指定される：

Wolfram Language code: Graphics[{Blurring[5], Annulus[]}, PlotRangePadding -> Scaled[.2], ImageSize -> #]& /@ {50, 100, 150}

ImageScaled半径を使う：

Wolfram Language code: Graphics[{Blurring[ImageScaled[0.05]], Annulus[]}, PlotRangePadding -> Scaled[.2], ImageSize -> #]& /@ {50, 100, 150}

アプリケーション  (9)

基本的なアプリケーション  (3)

ぼかしの程度を示す：

Wolfram Language code: blur[{x_, y_}] := Graphics[{{Blurring[{x, y}], RGBColor[1., 3/4, 0.], Disk[{0, 0}, Offset[30]]}, {Thick, Dashed, RGBColor[0., 2/3, 1.], Circle[{0, 0}, Offset[30 + {x, y}]]}}]

均一のぼかしを適用する：

Wolfram Language code: Table[blur[{r, r}], {r, {0, 10, 16}}]

水平方向と垂直方向に別々のぼかし半径を使う：

Wolfram Language code: GraphicsGrid[Table[blur[{rx, ry}], {rx, {0, 16, 24}}, {ry, {0, 16, 24}}]]

EdgeFormでオブジェクトをぼかす：

Wolfram Language code: Graphics[{Blurring[6], EdgeForm[{RGBColor[0., 2/3, 1.], Thickness[0.05]}], RGBColor[1., 3/4, 0.], RegularPolygon[6]}, PlotRangePadding -> 0.2]

Opacityでオブジェクトをぼかす：

Wolfram Language code: Graphics[{Blurring[6], Opacity[1 / 2], RGBColor[1., 3/4, 0.], RegularPolygon[6]}, PlotRangePadding -> 0.2]

ぼかし効果  (4)

画像を使って被写界深度効果のシミュレーションを行う：

Wolfram Language code: {a, b, c} = {[image], [image], [image]};
Wolfram Language code: Graphics[{Blurring[10], a, Blurring[4], b, Blurring[None], c}]

グラフィックスプリミティブを使って被写界深度効果のシミュレーションを行う：

Wolfram Language code: tree = Polygon[{{-0.037585066407075374, -0.027697338275686434}, {-0.006255347454498406, -0.027847216854752332}, {-0.0061146007618049225, -0.04742416119182735}, {-0.0056195913354599725, -0.04841418004446041}, {-0.005015991050584034, -0.04898745733328 ... 03842425336586075, -0.02735820075878337}}, {1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36, 37, 38, 39, 40, 41, 42, 43, 44, 45, 46, 47, 48, 49, 50, 51}]; positions = Join@@Table[{(x + y / 2)3, y}, {y, 1, 0, -1 / 5}, {x, 0, 1, 1 / 5}];
Wolfram Language code: Graphics[{RGBColor[0., 2/3, 0], EdgeForm[Black], Table[{Blurring[6 * p[[2]]], Translate[Scale[tree, 3 * (1 - p[[2]]) + 5], p]}, {p, positions}]}]

ドロップシャドウを作成する：

Wolfram Language code: shape = Annulus[]; Graphics[{{Blurring[10], GrayLevel[0, 1/3], Translate[shape, {-0.2, -0.2}]}, shape}]

DropShadowingを使って同じ効果を得る：

Wolfram Language code: Graphics[{DropShadowing[{-12, -12}, 10], shape}]

可視化の一部を強調する：

Wolfram Language code: cloud = WordCloud[EntityValue[CountryData["Europe"], {"Name", "LandArea"}]]

「Sweden」以外のすべての国名をぼかす：

Wolfram Language code: cloud /. x : Inset[Style[Except["Sweden"], __], __] :> {Blurring[5], x}

可視化  (2)

曲線をぼかしてプロットする：

Wolfram Language code: Plot[{Sin[Sqrt[2] x] + Sin[x], Style[Sin[x], Blurring[3]]}, {x, 0, 10}]

棒グラフにスタイル付する：

Wolfram Language code: BarChart[{1, Style[2, Blurring[6]], 3, 4, 5}]

特性と関係  (2)

BlurはImageをぼかしたものを与える：

Wolfram Language code: img = [image];
Wolfram Language code: Blur[img, 6]

Blurringを使った同等の効果：

Wolfram Language code: Graphics[{Blurring[6], ImageMesh[ColorNegate[img]]}, PlotRangePadding -> Scaled[.06]]

Blurring はガウスぼかしを適用する：

Wolfram Language code: text = Text[Style["G", 80, FontFamily -> "Times"]]
Wolfram Language code: Graphics[{Blurring[8], text}]

同等のガウスフィルタ：

Wolfram Language code: GaussianFilter[Rasterize[Graphics[{text}], RasterSize -> 100, ImageSize -> 100], 8]

インタラクティブな例題  (2)

被写界深度効果のシミュレーションを行う：

Wolfram Language code: Manipulate[ DynamicModule[{ts = Range[0, 1, 1 / 20], disks, blurs, opt = PlotRange -> 4}, disks = Table[Disk[{3t Sin[4Pi Sqrt[ t]], 2 - 4t}, t * 0.8 + 0.2], {t, ts}]; blurs = Table[Blurring[10 * Abs[1 - t - focus]], {t, ts}]; Graphics[{EdgeForm[Black], LightGray, Transpose[{blurs, disks}]}, opt] ], {focus, 0, 1} ]

マウスオーバーされている国を強調表示する：

Wolfram Language code: EntityValue[CountryData[], {"Name", "LandArea"}]//Short
Wolfram Language code: WordCloud[%, MaxItems -> 50] /. x_Inset :> Mouseover[{Blurring[5], x}, x]
Wolfram Research (2022), Blurring, Wolfram言語関数， https://reference.wolfram.com/language/ref/Blurring.html.

テキスト

Wolfram Research (2022), Blurring, Wolfram言語関数， https://reference.wolfram.com/language/ref/Blurring.html.

CMS

Wolfram Language. 2022. "Blurring." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Blurring.html.

APA

Wolfram Language. (2022). Blurring. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Blurring.html

BibTeX

@misc{reference.wolfram_2026_blurring, author="Wolfram Research", title="{Blurring}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/Blurring.html}", note=[Accessed: 14-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_blurring, organization={Wolfram Research}, title={Blurring}, year={2022}, url={https://reference.wolfram.com/language/ref/Blurring.html}, note=[Accessed: 14-August-2026]}