WOLFRAM

Wolfram 语言与系统参考资料中心

Blurring[r]

是一个二维指令，指定绘制图形对象时应用半径 r 的模糊效果.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
基本用法  
规范  
应用  
基本应用  
模糊效果  
可视化  
属性和关系  
互动范例  
参见
相关指南
历史
按以下格式引用：

Blurring

Blurring[r]

是一个二维指令，指定绘制图形对象时应用半径 r 的模糊效果.

更多信息

  • Blurring 亦称为模糊和高斯模糊.
  • Blurring 模糊通常用于柔化图形对象的图像并隐藏对象的特征.
  • Blurring[r] 指定应该混合 r 个打印机的点.
  • 半径 r 的单位是打印机点，放大前等于 英寸.
  • Blurring[{r1,r2}] 在宽度上使用半径 r1，在高度上使用半径 r2.
  • Blurring[r] 实际上等价于 Blurring[{r,r}].
  • Blurring[] 实际上等价于 Blurring[3].
  • ImageScaled 可用于指定半径，并被视为取的是默认图像大小的比例.

范例

打开所有单元 关闭所有单元

基本范例  (3)

对文本应用模糊指令：

Wolfram Language code: Graphics[{Blurring[], Text[Style["Wolfram", 32]]}]

绘制几个函数：

Wolfram Language code: Plot[{Sin[Sqrt[2] x] + Sin[x], Style[Sin[x], Blurring[3]]}, {x, 0, 10}]

突出显示巴黎附近的一个地区：

Wolfram Language code: GeoGraphics[{Gray, Blurring[5], GeoDisk[Entity["City", {"Paris", "IleDeFrance", "France"}]]}]

范围  (12)

基本用法  (8)

对图形基元应用模糊指令：

Wolfram Language code: Graphics[{Blurring[], #}]& /@ {Point[{{6, 3}, {0, 4}, {2, 0}, {3, 2}, {9, 5}}], BSplineCurve[{{3, 3}, {3, 4}, {2, 3}, {3, 2}, {4, 3}}], Polygon[{{3, 1}, {9, 8}, {0, 5}, {9, 3}, {4, 9}}]}

对 Text 应用模糊指令：

Wolfram Language code: Graphics[{Blurring[], Text[Style["Blurring", 24]]}]

对绘图应用模糊指令：

Wolfram Language code: Plot[{3Sin[x] + x, 3Cos[x] + x}, {x, 0, 15}, PlotStyle -> Blurring /@ {3, 0}]

对图表应用模糊指令：

Wolfram Language code: BarChart[{1, 2, 3, 4}, ChartStyle -> Blurring /@ {6, 6, 0, 6}]

设置几何区域的样式：

Wolfram Language code: Region[Style[ImplicitRegion[y ^ 2 < x (-1 + x ^ 3), {x, y}], Blurring[]]]

对 Image 应用模糊指令：

Wolfram Language code: Graphics[{Blurring[], [image]}]

显示一个模糊的示意性轮廓图：

Wolfram Language code: GeoGraphics[{GeoStyling["OutlineMap", Directive[Opacity[0.5, Red], Blurring[20]]], Polygon[["austria"]]}]

摘要框：

Wolfram Language code: Blurring[]

规范  (4)

Blurring[] 产生的是轻微的均匀模糊效果：

Wolfram Language code: Graphics[{Blurring[], Annulus[]}]

指定模糊半径：

Wolfram Language code: Graphics[{Blurring[#], Annulus[]}, PlotRangePadding -> 1 / 2]& /@ {0, 5, 20}

在水平和垂直方向上分别指定模糊半径：

Wolfram Language code: Graphics[{Blurring[#], Annulus[]}, PlotRangePadding -> 1 / 2]& /@ {{20, 20}, {0, 20}, {20, 0}}

默认情况下，以打印机点数为单位指定模糊半径：

Wolfram Language code: Graphics[{Blurring[5], Annulus[]}, PlotRangePadding -> Scaled[.2], ImageSize -> #]& /@ {50, 100, 150}

使用 ImageScaled 半径：

Wolfram Language code: Graphics[{Blurring[ImageScaled[0.05]], Annulus[]}, PlotRangePadding -> Scaled[.2], ImageSize -> #]& /@ {50, 100, 150}

应用  (9)

基本应用  (3)

显示模糊范围：

Wolfram Language code: blur[{x_, y_}] := Graphics[{{Blurring[{x, y}], RGBColor[1., 3/4, 0.], Disk[{0, 0}, Offset[30]]}, {Thick, Dashed, RGBColor[0., 2/3, 1.], Circle[{0, 0}, Offset[30 + {x, y}]]}}]

应用均匀模糊：

Wolfram Language code: Table[blur[{r, r}], {r, {0, 10, 16}}]

在水平和垂直方向上使用不同的模糊半径：

Wolfram Language code: GraphicsGrid[Table[blur[{rx, ry}], {rx, {0, 16, 24}}, {ry, {0, 16, 24}}]]

模糊带有 EdgeForm 的对象：

Wolfram Language code: Graphics[{Blurring[6], EdgeForm[{RGBColor[0., 2/3, 1.], Thickness[0.05]}], RGBColor[1., 3/4, 0.], RegularPolygon[6]}, PlotRangePadding -> 0.2]

模糊具有 Opacity 的对象：

Wolfram Language code: Graphics[{Blurring[6], Opacity[1 / 2], RGBColor[1., 3/4, 0.], RegularPolygon[6]}, PlotRangePadding -> 0.2]

模糊效果  (4)

模拟图像的景深效果：

Wolfram Language code: {a, b, c} = {[image], [image], [image]};
Wolfram Language code: Graphics[{Blurring[10], a, Blurring[4], b, Blurring[None], c}]

模拟图形基元的景深效果：

Wolfram Language code: tree = Polygon[{{-0.037585066407075374, -0.027697338275686434}, {-0.006255347454498406, -0.027847216854752332}, {-0.0061146007618049225, -0.04742416119182735}, {-0.0056195913354599725, -0.04841418004446041}, {-0.005015991050584034, -0.04898745733328 ... 03842425336586075, -0.02735820075878337}}, {1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 13, 14, 15, 16, 17, 18, 19, 20, 21, 22, 23, 24, 25, 26, 27, 28, 29, 30, 31, 32, 33, 34, 35, 36, 37, 38, 39, 40, 41, 42, 43, 44, 45, 46, 47, 48, 49, 50, 51}]; positions = Join@@Table[{(x + y / 2)3, y}, {y, 1, 0, -1 / 5}, {x, 0, 1, 1 / 5}];
Wolfram Language code: Graphics[{RGBColor[0., 2/3, 0], EdgeForm[Black], Table[{Blurring[6 * p[[2]]], Translate[Scale[tree, 3 * (1 - p[[2]]) + 5], p]}, {p, positions}]}]

生成投影：

Wolfram Language code: shape = Annulus[]; Graphics[{{Blurring[10], GrayLevel[0, 1/3], Translate[shape, {-0.2, -0.2}]}, shape}]

与 DropShadowing 获取相同的效果：

Wolfram Language code: Graphics[{DropShadowing[{-12, -12}, 10], shape}]

突出可视化图形的一部分：

Wolfram Language code: cloud = WordCloud[EntityValue[CountryData["Europe"], {"Name", "LandArea"}]]

模糊除 "Sweden" 以外的所有国家名称：

Wolfram Language code: cloud /. x : Inset[Style[Except["Sweden"], __], __] :> {Blurring[5], x}

可视化  (2)

绘制有模糊效果的曲线：

Wolfram Language code: Plot[{Sin[Sqrt[2] x] + Sin[x], Style[Sin[x], Blurring[3]]}, {x, 0, 10}]

设置条形图的样式：

Wolfram Language code: BarChart[{1, Style[2, Blurring[6]], 3, 4, 5}]

属性和关系  (2)

Blur 给出 Image 的模糊化后的版本：

Wolfram Language code: img = [image];
Wolfram Language code: Blur[img, 6]

用 Blurring 给出同样的效果：

Wolfram Language code: Graphics[{Blurring[6], ImageMesh[ColorNegate[img]]}, PlotRangePadding -> Scaled[.06]]

Blurring 应用的是高斯模糊：

Wolfram Language code: text = Text[Style["G", 80, FontFamily -> "Times"]]
Wolfram Language code: Graphics[{Blurring[8], text}]

等效的高斯滤波器：

Wolfram Language code: GaussianFilter[Rasterize[Graphics[{text}], RasterSize -> 100, ImageSize -> 100], 8]

互动范例  (2)

模拟景深效果：

Wolfram Language code: Manipulate[ DynamicModule[{ts = Range[0, 1, 1 / 20], disks, blurs, opt = PlotRange -> 4}, disks = Table[Disk[{3t Sin[4Pi Sqrt[ t]], 2 - 4t}, t * 0.8 + 0.2], {t, ts}]; blurs = Table[Blurring[10 * Abs[1 - t - focus]], {t, ts}]; Graphics[{EdgeForm[Black], LightGray, Transpose[{blurs, disks}]}, opt] ], {focus, 0, 1} ]

突出鼠标悬停处的国家：

Wolfram Language code: EntityValue[CountryData[], {"Name", "LandArea"}]//Short
Wolfram Language code: WordCloud[%, MaxItems -> 50] /. x_Inset :> Mouseover[{Blurring[5], x}, x]
Wolfram Research (2022)，Blurring，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Blurring.html.

文本

Wolfram Research (2022)，Blurring，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Blurring.html.

CMS

Wolfram 语言. 2022. "Blurring." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Blurring.html.

APA

Wolfram 语言. (2022). Blurring. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Blurring.html 年

BibTeX

@misc{reference.wolfram_2026_blurring, author="Wolfram Research", title="{Blurring}", year="2022", howpublished="\url{https://reference.wolfram.com/language/ref/Blurring.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_blurring, organization={Wolfram Research}, title={Blurring}, year={2022}, url={https://reference.wolfram.com/language/ref/Blurring.html}, note=[Accessed: 04-September-2026]}