WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CarlsonRM[x,y,ρ]

Carlsonの楕円積分 TemplateBox[{x, y, rho}, CarlsonRM]を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
特定の値  
微分と積分  
関数表現  
関数の恒等式と簡約  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

CarlsonRM

CarlsonRM[x,y,ρ]

Carlsonの楕円積分 TemplateBox[{x, y, rho}, CarlsonRM]を与える．

詳細

  • 記号操作・数値操作の両方に適した数学関数である．
  • 非負の引数について TemplateBox[{x, y, rho}, CarlsonRM]=2/piint_0^inftyt^(-1/2) (t+x)^(-1/2)(t+y)^(-1/2)(t+rho)^(-1)dt である．
  • CarlsonRM[x,y,ρ]は に不連続な分枝切断線を持つ．
  • CarlsonRM[x,y,ρ]は ρ<0のコーシー(Cauchy)主値積分として理解される．
  • 特別な引数の場合，CarlsonRMは自動的に厳密値を計算する．
  • CarlsonRMは任意の数値精度で評価できる．
  • CarlsonRMは自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (3)

数値的に評価する：

Wolfram Language code: CarlsonRM[3., 5., 1.]

関数をプロットする：

Wolfram Language code: Plot[{CarlsonRM[t, 5, 7], CarlsonRM[3, t, 7], CarlsonRM[3, 5, t]}, {t, -10, 10}, PlotLegends -> "Expressions"]

CarlsonRMはルジャンドル(Legendre)の第3種完全楕円積分に関連している：

Wolfram Language code: n Pi / 4 CarlsonRM[1 - m, 1, 1 - n] /. {m -> 0.4, n -> -4}
Wolfram Language code: EllipticPi[n, m] - EllipticK[m] /. {m -> 0.4, n -> -4}

スコープ  (11)

数値評価  (5)

数値的に評価する：

Wolfram Language code: N[CarlsonRM[Sqrt[3], 4, 2]]

高精度で数値的に評価する：

Wolfram Language code: N[CarlsonRM[5, 1, 2], 50]

出力精度は入力精度に従う：

Wolfram Language code: CarlsonRM[5, 1, 2.34567890123456789012345]
Wolfram Language code: CarlsonRM[5, 1, 2.345678901234567890123456789012345]

複素引数について評価する：

Wolfram Language code: N[CarlsonRM[-3 + I, -2, 7 + I]]

高精度で効率的に評価する：

Wolfram Language code: Timing[CarlsonRM[3, 5, 11`500]]
Wolfram Language code: Timing[Precision[CarlsonRM[3, 5, 11`100000]]]

CarlsonRMは要素単位でリストに縫い込まれる：

Wolfram Language code: CarlsonRM[{Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, {Subscript[y, 1], Subscript[y, 2], Subscript[y, 3]}, {Subscript[ρ, 1], Subscript[ρ, 2], Subscript[ρ, 3]}]

特定の値  (1)

単純な厳密値は自動的に生成される：

Wolfram Language code: CarlsonRM[x, x, x]
Wolfram Language code: CarlsonRM[x, x, ρ]
Wolfram Language code: CarlsonRM[x, y, 0]
Wolfram Language code: CarlsonRM[x, 0, ρ]

微分と積分  (2)

についての TemplateBox[{x, y, rho}, CarlsonRM]の導関数：

Wolfram Language code: D[CarlsonRM[x, y, ρ], x]

についての TemplateBox[{x, y, rho}, CarlsonRM]の導関数：

Wolfram Language code: D[CarlsonRM[x, y, ρ], ρ]

についての TemplateBox[{x, y, rho}, CarlsonRM]の不定積分：

Wolfram Language code: Integrate[CarlsonRM[x, y, ρ], x]

関数表現  (1)

TraditionalFormによる表示：

Wolfram Language code: CarlsonRM[x, y, z]//TraditionalForm

関数の恒等式と簡約  (2)

CarlsonRMは，オイラー・ポアソン(Euler–Poisson)の偏微分方程式を満足する：

Wolfram Language code: (x - y)Subscript[∂, x, y]CarlsonRM[x, y, ρ] + (1/2)(Subscript[∂, y]CarlsonRM[x, y, ρ] - Subscript[∂, x]CarlsonRM[x, y, ρ]) == 0//FunctionExpand//FullSimplify
Wolfram Language code: (x - ρ)Subscript[∂, x, ρ]CarlsonRM[x, y, ρ] + (1/2)Subscript[∂, ρ]CarlsonRM[x, y, ρ] - Subscript[∂, x]CarlsonRM[x, y, ρ] == 0//FunctionExpand//FullSimplify

CarlsonRMは，オイラーの同次関係を満足する：

Wolfram Language code: xSubscript[∂, x]CarlsonRM[x, y, ρ] + ySubscript[∂, y]CarlsonRM[x, y, ρ] + ρSubscript[∂, ρ]CarlsonRM[x, y, ρ] == -(3/2)CarlsonRM[x, y, ρ]//FunctionExpand//FullSimplify

アプリケーション  (2)

Circular Disk（円板）に対する立体角を可視化する：

Wolfram Language code: With[{L = 2, r0 = 2 / 5, rm = 1}, Graphics3D[{EdgeForm[], Polygon[PadRight[N@CirclePoints[rm, 24], {Automatic, 3}]], {Dashed, Line[{{r0, 0, 0}, {r0, 0, L}}]}, Sphere[{r0, 0, L}, rm / 20]}, Boxed -> False, ViewPoint -> {-2.4, -1.3, 2.}]]

立体角を評価する：

Wolfram Language code: With[{L = 2, r0 = 2 / 5, rm = 1}, N[2π Boole[r0 < rm] - (2π L rm/rm - r0)(CarlsonRK[L^2 + (rm - r0)^2, L^2 + (rm + r0)^2] - (r0(L^2 + (rm - r0)^2)/(rm^2 - r0^2)^2) CarlsonRM[(L^2 + (rm + r0)^2/(rm + r0)^2), (L^2 + (rm - r0)^2/(rm + r0)^2), (L^2 + (rm - r0)^2/(rm - r0)^2)]), 20]]

NIntegrate の結果と比較する：

Wolfram Language code: With[{L = 2, r0 = 2 / 5, rm = 1}, L NIntegrate[(r/(r^2 - 2r0 r Cos[θ] + r0^2 + L^2)^3 / 2), {r, 0, rm}, {θ, 0, 2π}]]

円筒と球の交点を可視化する：

Wolfram Language code: R = 1 / 6;r = 5 / 9;b = 5 / 11; cyl = Cylinder[{{0, 0, 0}, {0, 0, 2r}}, R]; ball = Ball[{b, 0, r}, r];
Wolfram Language code: Show@{ Graphics3D[{Opacity[1 / 2], cyl, ball}], Region[RegionIntersection[cyl, ball], PlotTheme -> "Web"]}

Carlson積分によって表現されたCylinder-Ball Intersection（円筒と球の交点）の体積：

Wolfram Language code: N[(2π/9 )(2R(3 R (2 r^2 - R^2) - b (b^2 - 4 r^2 + 5 b R + 7 R^2) + (3 r^4/b - R))CarlsonRK[(b - r + R) (b + r + R), 4b R] + (b^2 - 4 r^2 + 7 R^2)CarlsonRE[(b - r + R) (b + r + R), 4b R] + 6b R r^4(b + r - R) (b + R) (b - r - R)CarlsonRM[(b - R)^2 (b - r + R) (b + r + R), 4 b R(b - R)^2, 4 b R r^2]), 20]

Volumeの結果と比較する：

Wolfram Language code: Volume[RegionIntersection[cyl, ball], WorkingPrecision -> 20]

特性と関係  (1)

CarlsonRMはその最初の2つの引数について対称である：

Wolfram Language code: CarlsonRM[x, y, ρ] == CarlsonRM[y, x, ρ]
Wolfram Research (2021), CarlsonRM, Wolfram言語関数， https://reference.wolfram.com/language/ref/CarlsonRM.html.

テキスト

Wolfram Research (2021), CarlsonRM, Wolfram言語関数， https://reference.wolfram.com/language/ref/CarlsonRM.html.

CMS

Wolfram Language. 2021. "CarlsonRM." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CarlsonRM.html.

APA

Wolfram Language. (2021). CarlsonRM. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CarlsonRM.html

BibTeX

@misc{reference.wolfram_2026_carlsonrm, author="Wolfram Research", title="{CarlsonRM}", year="2021", howpublished="\url{https://reference.wolfram.com/language/ref/CarlsonRM.html}", note=[Accessed: 16-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_carlsonrm, organization={Wolfram Research}, title={CarlsonRM}, year={2021}, url={https://reference.wolfram.com/language/ref/CarlsonRM.html}, note=[Accessed: 16-August-2026]}