WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CarmichaelLambda[n]

カーマイケル(Carmichael)関数 を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
数値評価  
記号演算  
アプリケーション  
基本的なアプリケーション  
素数判定  
暗号学  
整数論  
特性と関係  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

CarmichaelLambda

CarmichaelLambda[n]

カーマイケル(Carmichael)関数 を与える．

詳細

  • CarmichaelLambdaは，簡約トーシェント関数あるいは最小普遍指数関数としても知られている．
  • CarmichaelLambdaは，素数判定で，ある種の素数判定では合成数であると証明できない合成数を求めるためによく使われる．
  • 記号操作・数値操作の両方に適した数学的整数関数である．
  • CarmichaelLambda[n]は， と互いに素であるすべての について となるような最小の正の整数 である．
  • （ は単数で は素数）について，CarmichaelLambda[n]はLCM[(p1-1),…,(pm-1)]を返す．

例題

すべて開く すべて閉じる

例  (2)

のCarmichaelLambdaを計算する：

Wolfram Language code: CarmichaelLambda[10]

数列をプロットする：

Wolfram Language code: DiscretePlot[CarmichaelLambda[n], {n, 0, 50}]

スコープ  (7)

数値評価  (4)

整数を使って計算する：

Wolfram Language code: CarmichaelLambda[10]
Wolfram Language code: CarmichaelLambda[-10]

大きい整数について計算する：

Wolfram Language code: CarmichaelLambda[10 ^ 90 + 1]

CarmichaelLambdaはリストに縫い込まれる：

Wolfram Language code: CarmichaelLambda[{2, 4, 7}]

TraditionalFormによる表示：

Wolfram Language code: CarmichaelLambda[n]//TraditionalForm

記号演算  (3)

整数の解の例を求める：

Wolfram Language code: FindInstance[CarmichaelLambda[n] == EulerPhi[n] && n > 0, n, Integers]

式を簡約する：

Wolfram Language code: FullSimplify[Mod[a ^ CarmichaelLambda[n], n], Element[a | n, Integers] && GCD[a, n] == 1 && n > 1]

CarmichaelLambda数列を識別する：

Wolfram Language code: FindSequenceFunction[{1, 1, 2, 2, 4, 2, 6, 2, 6, 4}, n]

アプリケーション  (7)

基本的なアプリケーション  (3)

CarmichaelLambdaの最初の20の値：

Wolfram Language code: Grid[{Prepend[Range[20], "n"], Prepend[Table[CarmichaelLambda[n], {n, 20}], "TraditionalFormλ(n)"]}, Background -> {None, {Orange, StandardGray}}, Dividers -> Lighter[Gray, .5], Spacings -> {Automatic, .8}]

離散プロット：

Wolfram Language code: DiscretePlot[CarmichaelLambda[n], {n, 0, 100}]

数直線プロット：

Wolfram Language code: NumberLinePlot[Table[CarmichaelLambda[n], {n, 100}]]

母関数をプロットする：

Wolfram Language code: CarmichaelGF[z_] := Sum[CarmichaelLambda[n] * z ^ n, {n, 500}]
Wolfram Language code: GraphicsRow[{Plot[CarmichaelGF[x], {x, 0, 1}], ContourPlot[Re[CarmichaelGF[x + I * y]], {x, -1, 1}, {y, -1, 1}, ContourStyle -> None]}]

指数母関数：

Wolfram Language code: CarmichaelEGF[z_] := Sum[CarmichaelLambda[n] * z ^ n / n!, {n, 500}]
Wolfram Language code: GraphicsRow[{Plot[CarmichaelEGF[x], {x, 0, 5}], ContourPlot[Re[CarmichaelEGF[x + I * y]], {x, -3, 3}, {y, -3, 3}, ContourStyle -> None]}]

ディリクレ(Dirichlet)級数：

Wolfram Language code: CarmichaelDirichlet[s_] := Sum[CarmichaelLambda[n] / n ^ s, {n, 500}]
Wolfram Language code: GraphicsRow[{Plot[CarmichaelDirichlet[x], {x, 0, 1}], ContourPlot[Re[CarmichaelDirichlet[x + I * y]], {x, -1, 1}, {y, -1, 1}, ContourStyle -> None]}]

素数判定  (2)

素数が与えられた場合，p より小さいすべての正の数 a について である：

Wolfram Language code: Table[Mod[a ^ (11 - 1), 11] == 1, {a, 1, 10}]

素数性についての自然なテスト：

Wolfram Language code: primeQ[n_, a_ : 2] := Mod[a ^ (n - 1), n] == 1
Wolfram Language code: {primeQ[3], primeQ[9], primeQ[23]}
Wolfram Language code: {primeQ[341, 2], primeQ[341, 3]}

このテストは を満足する合成整数 n に対しては結論が出せないかもしれない：

Wolfram Language code: Mod[561, CarmichaelLambda[561]]
Wolfram Language code: primeQ[561, 2]

561と互いに素なすべての a について を検証する：

Wolfram Language code: AllTrue[Select[Range[561], CoprimeQ[#, 561]&], primeQ[561, #]&]

カーマイケル数，すなわち n と互いに素であるすべての a について an≡1 mod n である合成数を認識する：

Wolfram Language code: CarmichaelNumberQ[n_] := CompositeQ[n] && Mod[n, CarmichaelLambda[n]] == 1

はカーマイケル数だがは違う：

Wolfram Language code: CarmichaelNumberQ[561]
Wolfram Language code: CarmichaelNumberQ[1310]

暗号学  (1)

RSAのような暗号スキームを構築する．まず，モジュラスから始める：

Wolfram Language code: {p, q} = Prime[RandomInteger[{10 ^ 4, 10 ^ 5}, {2}]]; n = p q

n を法とする乗法群の普遍指数を求める：

Wolfram Language code: λ = CarmichaelLambda[n]

秘密鍵：

Wolfram Language code: d = NestWhile[#1 + 1&, Round[n / 3], GCD[λ, #1] =!= 1&]

公開鍵：

Wolfram Language code: e = ModularInverse[d, λ]

メッセージを暗号化する：

Wolfram Language code: PowerMod[ToCharacterCode["RSA in Mathematica"], e, n]

これを解読する：

Wolfram Language code: FromCharacterCode[PowerMod[%, d, n]]

整数論  (1)

Z_n^*の最大部分群の元の数を求める：

Wolfram Language code: FindCycles[n_] := Cases[GroupElements[CyclicGroup[EulerPhi[n]]], Cycles[{x_}] -> x]
Wolfram Language code: EulerPhi[12]
Wolfram Language code: subgroups = FindCycles[14]
Wolfram Language code: Dimensions[subgroups][[2]]
Wolfram Language code: CarmichaelLambda[12]

特性と関係  (7)

結果は非負である：

Wolfram Language code: CarmichaelLambda[{-2, -1, 0, 1, 2}]

被整除性は保持される：

Wolfram Language code: {Divisible[24, 8], Divisible[CarmichaelLambda[24], CarmichaelLambda[8]]}

CarmichaelLambdaのLCMはLCMのCarmichaelLambdaに等しい：

Wolfram Language code: {LCM@@CarmichaelLambda[{3, 8}], CarmichaelLambda[LCM[3, 8]]}

が無平方なら a≡aλ(n)+1mod n である：

Wolfram Language code: SquareFreeQ[17]
Wolfram Language code: Mod[3 ^ (CarmichaelLambda[17] + 1), 17]

を法とした元の乗法的位数はCarmichaelLambda[n]を割る：

Wolfram Language code: Divisible[CarmichaelLambda[9], MultiplicativeOrder[4, 9]]

CarmichaelLambdaはEulerPhiを割る：

Wolfram Language code: Divisible[EulerPhi[8], CarmichaelLambda[8]]

が原始根を持つなら，CarmichaelLambdaとEulerPhiは等しい：

Wolfram Language code: Cases[Range[2, 20], n_ /; IntegerQ[PrimitiveRoot[n]]]
Wolfram Language code: CarmichaelLambda[%]
Wolfram Language code: EulerPhi[%%]

おもしろい例題  (2)

CarmichaelLambdaの値を変化させるプロット：

Wolfram Language code: ArrayPlot[Table[CarmichaelLambda[j + 5k], {j, 1, 100}, {k, 1, 100}], ColorFunction -> "AvocadoColors"]

CarmichaelLambdaの値に基づいて数が彩色されたウラム(Ulam)螺線：

Wolfram Language code: ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table [(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n]
Wolfram Language code: ArrayPlot[CarmichaelLambda[ulam[101]], ColorFunction -> "Rainbow"]
Wolfram Research (1999), CarmichaelLambda, Wolfram言語関数， https://reference.wolfram.com/language/ref/CarmichaelLambda.html （2018年に更新）.

テキスト

Wolfram Research (1999), CarmichaelLambda, Wolfram言語関数， https://reference.wolfram.com/language/ref/CarmichaelLambda.html （2018年に更新）.

CMS

Wolfram Language. 1999. "CarmichaelLambda." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2018. https://reference.wolfram.com/language/ref/CarmichaelLambda.html.

APA

Wolfram Language. (1999). CarmichaelLambda. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CarmichaelLambda.html

BibTeX

@misc{reference.wolfram_2026_carmichaellambda, author="Wolfram Research", title="{CarmichaelLambda}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/CarmichaelLambda.html}", note=[Accessed: 14-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_carmichaellambda, organization={Wolfram Research}, title={CarmichaelLambda}, year={2018}, url={https://reference.wolfram.com/language/ref/CarmichaelLambda.html}, note=[Accessed: 14-August-2026]}