WOLFRAM

Wolfram 语言与系统参考资料中心

CarmichaelLambda[n]

给出卡迈克尔函数 .

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
数值运算  
符号运算  
应用  
基本应用  
素性测试  
密码学  
数论  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

CarmichaelLambda

CarmichaelLambda[n]

给出卡迈克尔函数 .

更多信息

  • CarmichaelLambda 也被称为简化欧拉函数或最小通用指数函数.
  • CarmichaelLambda 通常在质数测试中使用，以查找无法通过某些质数测试证明为合数的合数.
  • 整型数学函数，适合于符号和数值计算.
  • CarmichaelLambda[n] 是最小的正整数 ，使得对于所有 而言， 与 互质.
  • 对于数字 ，其中， 为单位值， 为素数，CarmichaelLambda[n] 返回 LCM[(p1-1),…,(pm-1)].

范例

打开所有单元 关闭所有单元

基本范例  (2)

计算 的 CarmichaelLambda：

Wolfram Language code: CarmichaelLambda[10]

绘制序列：

Wolfram Language code: DiscretePlot[CarmichaelLambda[n], {n, 0, 50}]

范围  (7)

数值运算  (4)

使用整数进行计算：

Wolfram Language code: CarmichaelLambda[10]
Wolfram Language code: CarmichaelLambda[-10]

计算大型整数：

Wolfram Language code: CarmichaelLambda[10 ^ 90 + 1]

CarmichaelLambda 遍历列表：

Wolfram Language code: CarmichaelLambda[{2, 4, 7}]

TraditionalForm 格式化：

Wolfram Language code: CarmichaelLambda[n]//TraditionalForm

符号运算  (3)

查找一个整数解的实例：

Wolfram Language code: FindInstance[CarmichaelLambda[n] == EulerPhi[n] && n > 0, n, Integers]

化简表达式：

Wolfram Language code: FullSimplify[Mod[a ^ CarmichaelLambda[n], n], Element[a | n, Integers] && GCD[a, n] == 1 && n > 1]

识别 CarmichaelLambda 数列：

Wolfram Language code: FindSequenceFunction[{1, 1, 2, 2, 4, 2, 6, 2, 6, 4}, n]

应用  (7)

基本应用  (3)

CarmichaelLambda 的前 20 个值：

Wolfram Language code: Grid[{Prepend[Range[20], "n"], Prepend[Table[CarmichaelLambda[n], {n, 20}], "TraditionalFormλ(n)"]}, Background -> {None, {Orange, StandardGray}}, Dividers -> Lighter[Gray, .5], Spacings -> {Automatic, .8}]

离散图形：

Wolfram Language code: DiscretePlot[CarmichaelLambda[n], {n, 0, 100}]

数轴图：

Wolfram Language code: NumberLinePlot[Table[CarmichaelLambda[n], {n, 100}]]

绘制生成函数：

Wolfram Language code: CarmichaelGF[z_] := Sum[CarmichaelLambda[n] * z ^ n, {n, 500}]
Wolfram Language code: GraphicsRow[{Plot[CarmichaelGF[x], {x, 0, 1}], ContourPlot[Re[CarmichaelGF[x + I * y]], {x, -1, 1}, {y, -1, 1}, ContourStyle -> None]}]

指数生成函数：

Wolfram Language code: CarmichaelEGF[z_] := Sum[CarmichaelLambda[n] * z ^ n / n!, {n, 500}]
Wolfram Language code: GraphicsRow[{Plot[CarmichaelEGF[x], {x, 0, 5}], ContourPlot[Re[CarmichaelEGF[x + I * y]], {x, -3, 3}, {y, -3, 3}, ContourStyle -> None]}]

狄里克雷序列：

Wolfram Language code: CarmichaelDirichlet[s_] := Sum[CarmichaelLambda[n] / n ^ s, {n, 500}]
Wolfram Language code: GraphicsRow[{Plot[CarmichaelDirichlet[x], {x, 0, 1}], ContourPlot[Re[CarmichaelDirichlet[x + I * y]], {x, -1, 1}, {y, -1, 1}, ContourStyle -> None]}]

素性测试  (2)

给定质数，所有正数 a 的 小于 p：

Wolfram Language code: Table[Mod[a ^ (11 - 1), 11] == 1, {a, 1, 10}]

素性的自然测试：

Wolfram Language code: primeQ[n_, a_ : 2] := Mod[a ^ (n - 1), n] == 1
Wolfram Language code: {primeQ[3], primeQ[9], primeQ[23]}
Wolfram Language code: {primeQ[341, 2], primeQ[341, 3]}

对于满足 的复合整数 n，此测试可能没有结论：

Wolfram Language code: Mod[561, CarmichaelLambda[561]]
Wolfram Language code: primeQ[561, 2]

对于所有 a，验证 与 561 互质：

Wolfram Language code: AllTrue[Select[Range[561], CoprimeQ[#, 561]&], primeQ[561, #]&]

识别卡迈克尔数，使得对于所有与 n 互质的 a，有 an≡1 mod n 成立的合数：

Wolfram Language code: CarmichaelNumberQ[n_] := CompositeQ[n] && Mod[n, CarmichaelLambda[n]] == 1

数 是卡迈克尔数，而 不是：

Wolfram Language code: CarmichaelNumberQ[561]
Wolfram Language code: CarmichaelNumberQ[1310]

密码学  (1)

建立类似 RSA 的加密方案. 从模数开始:

Wolfram Language code: {p, q} = Prime[RandomInteger[{10 ^ 4, 10 ^ 5}, {2}]]; n = p q

求出乘法组通用指数模除 n：

Wolfram Language code: λ = CarmichaelLambda[n]

专用键：

Wolfram Language code: d = NestWhile[#1 + 1&, Round[n / 3], GCD[λ, #1] =!= 1&]

公用键：

Wolfram Language code: e = ModularInverse[d, λ]

加密一条信息：

Wolfram Language code: PowerMod[ToCharacterCode["RSA in Mathematica"], e, n]

解密信息：

Wolfram Language code: FromCharacterCode[PowerMod[%, d, n]]

数论  (1)

求 Z_n^* 的最大子群中的元素数：

Wolfram Language code: FindCycles[n_] := Cases[GroupElements[CyclicGroup[EulerPhi[n]]], Cycles[{x_}] -> x]
Wolfram Language code: EulerPhi[12]
Wolfram Language code: subgroups = FindCycles[14]
Wolfram Language code: Dimensions[subgroups][[2]]
Wolfram Language code: CarmichaelLambda[12]

属性和关系  (7)

结果是非负的：

Wolfram Language code: CarmichaelLambda[{-2, -1, 0, 1, 2}]

保留整除性：

Wolfram Language code: {Divisible[24, 8], Divisible[CarmichaelLambda[24], CarmichaelLambda[8]]}

CarmichaelLambda 的 LCM 等于 LCM 的 CarmichaelLambda：

Wolfram Language code: {LCM@@CarmichaelLambda[{3, 8}], CarmichaelLambda[LCM[3, 8]]}

如果 无平方因子，则 a≡aλ(n)+1mod n：

Wolfram Language code: SquareFreeQ[17]
Wolfram Language code: Mod[3 ^ (CarmichaelLambda[17] + 1), 17]

元素模除 的乘法阶数整除 CarmichaelLambda[n]：

Wolfram Language code: Divisible[CarmichaelLambda[9], MultiplicativeOrder[4, 9]]

CarmichaelLambda 整除 EulerPhi：

Wolfram Language code: Divisible[EulerPhi[8], CarmichaelLambda[8]]

如果 具有原根，则 CarmichaelLambda 和 EulerPhi 相同：

Wolfram Language code: Cases[Range[2, 20], n_ /; IntegerQ[PrimitiveRoot[n]]]
Wolfram Language code: CarmichaelLambda[%]
Wolfram Language code: EulerPhi[%%]

巧妙范例  (2)

不同的 CarmichaelLambda 值的图形：

Wolfram Language code: ArrayPlot[Table[CarmichaelLambda[j + 5k], {j, 1, 100}, {k, 1, 100}], ColorFunction -> "AvocadoColors"]

乌岚螺旋，根据 CarmichaelLambda 的值对数字进行着色：

Wolfram Language code: ulam[n_] := Partition[Permute[Range[n ^ 2], Accumulate[Take[Flatten[{{n ^ 2 + 1} / 2, Table [(-1) ^ j i, {j, n}, {i, {-1, n}}, {j}]}], n ^ 2]]], n]
Wolfram Language code: ArrayPlot[CarmichaelLambda[ulam[101]], ColorFunction -> "Rainbow"]
Wolfram Research (1999)，CarmichaelLambda，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CarmichaelLambda.html （更新于 2018 年）.

文本

Wolfram Research (1999)，CarmichaelLambda，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CarmichaelLambda.html （更新于 2018 年）.

CMS

Wolfram 语言. 1999. "CarmichaelLambda." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2018. https://reference.wolfram.com/language/ref/CarmichaelLambda.html.

APA

Wolfram 语言. (1999). CarmichaelLambda. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CarmichaelLambda.html 年

BibTeX

@misc{reference.wolfram_2026_carmichaellambda, author="Wolfram Research", title="{CarmichaelLambda}", year="2018", howpublished="\url{https://reference.wolfram.com/language/ref/CarmichaelLambda.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_carmichaellambda, organization={Wolfram Research}, title={CarmichaelLambda}, year={2018}, url={https://reference.wolfram.com/language/ref/CarmichaelLambda.html}, note=[Accessed: 10-September-2026]}