WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CastColumns[tab,{col1type1,…}]

Tabularオブジェクト tab 内の coliの型を typeiに変える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
売上げデータ  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

CastColumns

CastColumns[tab,{col1type1,…}]

Tabularオブジェクト tab 内の coliの型を typeiに変える．

詳細

  • CastColumnsは，通常，Tabularオブジェクトの列の型を変換する（例：文字列を数や日付に変換する）ために使われる．
  • 型 typeiは，TabularColumnとして表された coliの要素の型を参照する．要素型には以下がある．
  • "MachineInteger"機械サイズ整数
    "MachineReal"機械サイズ実数
    "Around"::[…]不確かさがある数
    "Boolean"ブール値（TrueまたはFalse）
    "ByteArray"::[…]バイナリデータを表すByteArray要素
    "Date"::[…]任意粒度（日，月，μs 等）の暦の日付
    "Entity"::[…]指定領域の実体
    "GeoPosition"::[…]任意の測地系あるいは地理モデルにおける地理位置
    "InertExpression"使われるまで評価されない一般的な式
    "ListVector"::[type]指定の type の要素のリスト
    "ListVector"::[type,n]指定の type の要素の長さ n のリスト
    "ListTuple"::[type1,type2,…]型 type1, type2, …の要素のリスト
    "Null"Missing式
    "Quantity"::[type,unit]type の大きさで共通 unit を持つ数量
    "String"文字列
    "Time"::[…]TimeObjectにおけるような一日の時点
  • 数値要素は，以下のようにより具体的に与えることができる．
  • "Integer8"符号付き8ビット整数（から127まで）
    "UnsignedInteger8"整数（0から255まで）
    "Integer16"符号付き16ビット整数（からまで）
    "UnsignedInteger16"整数（0から65535まで）
    "Integer32"符号付き32ビット整数（からまで）
    "UnsignedInteger32"整数（0からまで）
    "Integer64"符号付き64ビット整数（からまで）
    "UnsignedInteger64"整数（0からまで）
    "Real32"単精度実数（32ビット）
    "Real64"倍精度実数(64ビット）
    "ComplexReal32"単精度複素数
    "ComplexReal64"倍精度複素数

例題

すべて開く すべて閉じる

例  (1)

数値型の列を別の数値型の列に変える：

Wolfram Language code: tab = ToTabular[<|"a" -> {1, 2, 3}, "b" -> {1., 4., 8.}|>, "Columns"]
Wolfram Language code: ColumnTypes[tab]

"Integer64"の列を"Real64"に変更する：

Wolfram Language code: CastColumns[tab, "a" -> "Real64"]
Wolfram Language code: ColumnTypes[%]

スコープ  (4)

指定された日に血糖値を測定する：

Wolfram Language code: tab = Tabular[{{"2024Nov12", 100}, {"2024Nov13", 102}, {"2024Nov14", 99}}, {"date", "blood sugar"}]
Wolfram Language code: ColumnTypes[tab]

"date"列を"Date"型に変える：

Wolfram Language code: CastColumns[tab, "date" -> "Date"]
Wolfram Language code: ColumnTypes[%]

数値データが文字列として記録されているTabularオブジェクトを取得する：

Wolfram Language code: tab = Tabular[Association["RawSchema" -> Association["ColumnProperties" -> Association["date" -> Association["ElementType" -> TypeSpecifier["Date"]["Integer64", "Day", "Gregorian", -6.]], "val" -> Association["ElementType" -> "String"]], "KeyColumns" -> None, "Backend" -> "WolframKernel"], "Options" -> {}, "BackendData" -> Association["ColumnData" -> DataStructure["ColumnTable", {{TabularColumn[Association["Data" -> {6, {{{1230789600000, 1230876000000, 1230962400000, 1231048800000, 1231135200000, 1231221600000}, {}, None}}, None}, "ElementType" -> "Date"["Integer64", "Day", "Gregorian", -6.], "CachedOriginalExpression" -> {DateObject[{2009, 1, 1}, "Day", "Gregorian", -6.], DateObject[{2009, 1, 2}, "Day", "Gregorian", -6.], DateObject[{2009, 1, 3}, "Day", "Gregorian", -6.], DateObject[{2009, 1, 4}, "Day", "Gregorian", -6.], DateObject[{2009, 1, 5}, "Day", "Gregorian", -6.], DateObject[{2009, 1, 6}, "Day", "Gregorian", -6.]}]], TabularColumn[Association[ "Data" -> {{3, {0, 5, 10, 15, 19, 24, 29}, "-6.06-2.83-4.221.28-7.17-4.83"}, {}, None}, "ElementType" -> "String"]]}}]]]];
Wolfram Language code: ColumnTypes[tab]

"val"列を数値型に変更する：

Wolfram Language code: CastColumns[tab, "val" -> "Real64"]
Wolfram Language code: ColumnTypes[%]

Tabularオブジェクトの列のベクトル型を変える：

Wolfram Language code: tab = ToTabular[<|"a" -> {1, 2, 3}, "b" -> {{4, 5}, Missing[], {6, 7}}, "c" -> {1., 4., 8.}|>, "Columns"]
Wolfram Language code: ColumnTypes[tab]
Wolfram Language code: CastColumns[tab, "b" -> "ListVector"::["Real64", 2]]
Wolfram Language code: ColumnTypes[%]

いくつかの列を同時に同じ型に変更する：

Wolfram Language code: Tabular[{{1, 2, 3}, {4, 5, 6}}, {"a", "b", "c"}]
Wolfram Language code: CastColumns[%, {"a", "c"} -> "Real64"]

アプリケーション  (2)

売上げデータ  (2)

"tsv"形式の小売りデータをTabularオブジェクトに取得する：

Wolfram Language code: data = Import["ExampleData/RetailSales.tsv", "Tabular", "HeaderLines" -> 1]

日付はすべて文字列である：

Wolfram Language code: ColumnTypes[data]

"Date"を"Date"形式に変換する：

Wolfram Language code: CastColumns[data, "Date" -> "Date"]

指定された都市のデータを選択する：

Wolfram Language code: Select[%, SameQ[#City, "Paris"]&]

"TimeColumn"として使われている"Date"でTimeSeriesオブジェクトを作成する：

Wolfram Language code: FromTabular[%, "TimeSeries", <|"TimeColumn" -> "Date"|>]

小売りの時系列を可視化する：

Wolfram Language code: DateListPlot[% -> "Sales"]

米国のコロナウイルス感染症データの大きなデータ集合を取得する：

Wolfram Language code: data = ResourceData["Sample Tabular Data: US Covid"];
Wolfram Language code: Dimensions[data]

最初の5行だけを表示する：

Wolfram Language code: data[[ ;; 5]]

FIPSコードは米国の郡を一意的に識別する数であるが，"fips"列は文字列型である：

Wolfram Language code: ColumnTypes[data]["fips"]

"fips"列を整数に変換する：

Wolfram Language code: RepeatedTiming[newdata = CastColumns[data, "fips" -> "Integer"];]
Wolfram Language code: Take[newdata, 5]
Wolfram Language code: ColumnTypes[newdata]["fips"]

特性と関係  (4)

CastColumns[tab,typerules]を使ってTabularオブジェクト tab の列の型を変える：

Wolfram Language code: tab = Tabular[Association["RawSchema" -> Association["ColumnProperties" -> Association["date" -> Association["ElementType" -> "String"], "blood sugar" -> Association["ElementType" -> "Integer64"]], "KeyColumns" -> None, "Backend" -> "WolframKernel"], "BackendData" -> Association["ColumnData" -> DataStructure["ColumnTable", {{TabularColumn[Association["Data" -> {{3, {0, 9, 18}, "2024Nov122024Nov13"}, {}, None}, "ElementType" -> "String"]], TabularColumn[Association["Data" -> {{100, 102}, {}, None}, "ElementType" -> "Integer64"]]}}]]]];
Wolfram Language code: CastColumns[tab, {"date" -> "Date", "blood sugar" -> "Real"}]

Tabular[tab,<|"ElementType"typerules|>]を使っても同じ結果が得られる：

Wolfram Language code: Tabular[tab, <|"ElementType" -> {"date" -> "Date", "blood sugar" -> "Real"}|>]

ToTabular[tab,"Rows",<|"ElementType"typerules|>]を使ってもそうである：

Wolfram Language code: ToTabular[tab, "Rows", <|"ElementType" -> {"date" -> "Date", "blood sugar" -> "Real"}|>]

文字列の列があるTabularオブジェクトを取得する：

Wolfram Language code: tab = Tabular[Association["RawSchema" -> Association["ColumnProperties" -> Association["date" -> Association["ElementType" -> "String"], "blood sugar" -> Association["ElementType" -> "String"]], "KeyColumns" -> None, "Backend" -> "WolframKernel"], "BackendData" -> Association["ColumnData" -> DataStructure["ColumnTable", {{TabularColumn[Association["Data" -> {{3, {0, 9, 18}, "2024Nov122024Nov13"}, {}, None}, "ElementType" -> "String"]], TabularColumn[Association[ "Data" -> {{3, {0, 3, 6}, "100102"}, {}, None}, "ElementType" -> "String"]]}}]]]];

CastColumnsを使う代りに，新たな列型で新たな概要が構築できる：

Wolfram Language code: schema = TabularSchema[<|"ColumnProperties" -> <|"date" -> <|"ElementType" -> "Date"|>, "blood sugar" -> <|"ElementType" -> "Real64"|>|>|>]

Tabularオブジェクトにスキーマを適用する：

Wolfram Language code: Tabular[tab, schema]

CastColumnsの動作は，TransformColumnsに適切な関数を使うことで再現できる：

Wolfram Language code: tab = Tabular[Association["RawSchema" -> Association["ColumnProperties" -> Association["date" -> Association["ElementType" -> "String"], "blood sugar" -> Association["ElementType" -> "Integer64"]], "KeyColumns" -> None, "Backend" -> "WolframKernel"], "Options" -> {}, "BackendData" -> Association["ColumnData" -> DataStructure["ColumnTable", {{TabularColumn[Association["Data" -> {{3, {0, 9, 18}, "2024Nov122024Nov13"}, {}, None}, "ElementType" -> "String"]], TabularColumn[Association["Data" -> {{100, 102}, {}, None}, "ElementType" -> "Integer64"]]}}]]]];

スペースを含む文字列の列キーには明示的な引用符を使用しなければならない：

Wolfram Language code: TransformColumns[tab, {"date" -> (Cast[#date, "Date"]&), "blood sugar" -> (N[#"blood sugar"]&)}]

血糖値の実数値の列を含むTabularオブジェクトを取得する：

Wolfram Language code: tab = Tabular[Association["RawSchema" -> Association["ColumnProperties" -> Association["date" -> Association["ElementType" -> "String"], "blood sugar" -> Association["ElementType" -> "Real64"]], "KeyColumns" -> None, "Backend" -> "WolframKernel"], "BackendData" -> Association["ColumnData" -> DataStructure["ColumnTable", {{TabularColumn[Association["Data" -> {{3, {0, 9, 18}, "2024Nov122024Nov13"}, {}, None}, "ElementType" -> "String"]], TabularColumn[Association[ "Data" -> {{100., 102.3}, {}, None}, "ElementType" -> "Real64"]]}}]]]];
Wolfram Language code: bsugar = tab[All, "blood sugar"]

CastColumnsは，事実上，各列にAutomatic変換法を使う：

Wolfram Language code: CastColumns[tab, "blood sugar" -> "Integer32"]

実数が常に忠実に整数に投影される訳ではないので，このような変換はこの場合は失敗する：

Wolfram Language code: TabularColumn[bsugar, "Integer32"]

整数に変換するときは，実数の丸めを含む明示的な変換法でTabularColumnを使う：

Wolfram Language code: ibsugar = TabularColumn[bsugar, "Integer32", <|"ConversionMethod" -> "Round"|>]
Wolfram Language code: ibsugar//Normal

InsertColumnsを使って新規列を再度挿入する：

Wolfram Language code: InsertColumns[tab, "blood sugar" -> ibsugar]
Wolfram Research (2025), CastColumns, Wolfram言語関数， https://reference.wolfram.com/language/ref/CastColumns.html （2026年に更新）.

テキスト

Wolfram Research (2025), CastColumns, Wolfram言語関数， https://reference.wolfram.com/language/ref/CastColumns.html （2026年に更新）.

CMS

Wolfram Language. 2025. "CastColumns." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2026. https://reference.wolfram.com/language/ref/CastColumns.html.

APA

Wolfram Language. (2025). CastColumns. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CastColumns.html

BibTeX

@misc{reference.wolfram_2026_castcolumns, author="Wolfram Research", title="{CastColumns}", year="2026", howpublished="\url{https://reference.wolfram.com/language/ref/CastColumns.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_castcolumns, organization={Wolfram Research}, title={CastColumns}, year={2026}, url={https://reference.wolfram.com/language/ref/CastColumns.html}, note=[Accessed: 18-August-2026]}