WOLFRAM

Wolfram 语言与系统参考资料中心

CatalanNumber[n]

给出了第 n 个 卡塔兰数 .

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
历史
按以下格式引用：

CatalanNumber

CatalanNumber[n]

给出了第 n 个 卡塔兰数 .

更多信息

范例

打开所有单元 关闭所有单元

基本范例  (1)

前 10 个卡塔兰数：

Wolfram Language code: Table[CatalanNumber[n], {n, 10}]

范围  (9)

计算较大的参数：

Wolfram Language code: CatalanNumber[100000]//Short

计算半整数参数：

Wolfram Language code: CatalanNumber[5 / 2]

数值式计算：

Wolfram Language code: CatalanNumber[2.3]

计算复数参数：

Wolfram Language code: CatalanNumber[1.2 + I]

绘制卡塔兰数作为其指标函数的图线：

Wolfram Language code: Plot[CatalanNumber[n], {n, -3, 3}]

计算涉及 CatalanNumber 的和：

Wolfram Language code: Sum[1 / CatalanNumber[n], {n, 1, Infinity}]
Wolfram Language code: Sum[(1/4^n) CatalanNumber[n], {n, m - 1}]

CatalanNumber 按元素线性作用于列表：

Wolfram Language code: CatalanNumber[{1, 2, 3, 4}]

CatalanNumber 可与 Interval 和 CenteredInterval 对象一起使用：

Wolfram Language code: CatalanNumber[Interval[{0.5, 0.6}]]
Wolfram Language code: CatalanNumber[CenteredInterval[1, 1 / 100]]

TraditionalForm 格式：

Wolfram Language code: CatalanNumber[n]//TraditionalForm

应用  (3)

计算给表达式加括号的不同方法数：

Wolfram Language code: SetAttributes[f, {Flat, OneIdentity}]

分配到 CirclePlus 中的列表上：

Wolfram Language code: e : CirclePlus[___, _List, ___] := Distribute[Unevaluated[e], List]

用模式匹配器按各种方法反复将列表分为两部分：

Wolfram Language code: parenthesizedlist = f[a, b, c, d] //. {f[x__] :> ReplaceList[f[x], f[u_, v_] :> CirclePlus[u, v]]}//Flatten

给表达式 a⊕b⊕c⊕d 加括号的方法总数：

Wolfram Language code: Length[parenthesizedlist]

检验：

Wolfram Language code: CatalanNumber[3]

卡塔兰数 CatalanNumber[n] 可描述为唯一一组使得两个汉克尔行列式都等于一的数字. 对前几种情况进行验证：

Wolfram Language code: Table[Det[HankelMatrix[CatalanNumber[Range[0, n]], CatalanNumber[Range[n, 2n]]]] == Det[HankelMatrix[CatalanNumber[Range[n + 1]], CatalanNumber[Range[n + 1, 2n + 1]]]] == 1, {n, 9}]

用双阶乘验证卡塔兰数的表达式：

Wolfram Language code: Assuming[n∈Integers && n >= 0, FullSimplify[CatalanNumber[n] == (2^2n + 1(2n - 1)!!/(2n + 2)!!)]]

属性和关系  (6)

卡塔兰数的生成函数：

Wolfram Language code: GeneratingFunction[CatalanNumber[n], n, x]
Wolfram Language code: Series[%, {x, 0, 10}]
Wolfram Language code: Table[CatalanNumber[n], {n, 0, 10}]

卡塔兰数可以表示为二项式系数的差：

Wolfram Language code: CatalanNumber[n] == Binomial[2n, n] - Binomial[2n, n + 1]
Wolfram Language code: Table[%, {n, -6, 6}]
Wolfram Language code: FunctionExpand[%%]//FullSimplify

卡塔兰数可以用广义贝尔多项式表示：

Wolfram Language code: Table[BellY[Transpose[{1 / Range[n, 1, -1]!, Range[n]!}]], {n, 10}]
Wolfram Language code: Table[CatalanNumber[n], {n, 10}]

可以用 DifferenceRoot 来表示 CatalanNumber：

Wolfram Language code: DifferenceRootReduce[CatalanNumber[k], k]

FindSequenceFunction 可以识别 CatalanNumber 序列：

Wolfram Language code: Table[CatalanNumber[n], {n, 10}]
Wolfram Language code: FindSequenceFunction[%, n]

CatalanNumber 的指数母函数：

Wolfram Language code: ExponentialGeneratingFunction[CatalanNumber[n], n, x]

可能存在的问题  (1)

按照惯例，卡塔兰数 TemplateBox[{{-, 1}}, CatalanNumber] 使用其二项式形式的表示定义：

Wolfram Language code: With[{n = -1}, {CatalanNumber[n], Binomial[2n, n] - Binomial[2n, n + 1]}]

此值不同于解析函数的极限值：

Wolfram Language code: FunctionExpand[CatalanNumber[n]]
Wolfram Language code: Limit[%, n -> -1]

巧妙范例  (2)

只有形式为 CatalanNumber[2k-1] 的 Catalan 数为奇：

Wolfram Language code: Table[Mod[CatalanNumber[2^n - 1], 10], {n, 20}]

由卡塔兰数之和组成的汉克尔矩阵的行列式：

Wolfram Language code: Table[Det[HankelMatrix[CatalanNumber[Range[0, n]] + CatalanNumber[Range[n + 1]], CatalanNumber[Range[n, 2n]] + CatalanNumber[Range[n + 1, 2n + 1]]]], {n, 0, 9}]

与斐波那契数的表达式进行比较：

Wolfram Language code: Table[Fibonacci[2n + 3], {n, 0, 9}]
Wolfram Research (2007)，CatalanNumber，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CatalanNumber.html （更新于 2014 年）.

文本

Wolfram Research (2007)，CatalanNumber，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CatalanNumber.html （更新于 2014 年）.

CMS

Wolfram 语言. 2007. "CatalanNumber." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/CatalanNumber.html.

APA

Wolfram 语言. (2007). CatalanNumber. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CatalanNumber.html 年

BibTeX

@misc{reference.wolfram_2026_catalannumber, author="Wolfram Research", title="{CatalanNumber}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/CatalanNumber.html}", note=[Accessed: 07-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_catalannumber, organization={Wolfram Research}, title={CatalanNumber}, year={2014}, url={https://reference.wolfram.com/language/ref/CatalanNumber.html}, note=[Accessed: 07-August-2026]}