WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CauchyWindow[x]

x のコーシー(Cauchy)窓関数を表す．

CauchyWindow[x,α]

パラメータ α を使う．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

CauchyWindow

CauchyWindow[x]

x のコーシー(Cauchy)窓関数を表す．

CauchyWindow[x,α]

パラメータ α を使う．

詳細

  • CauchyWindowは，アベル(Abel)窓としても知られているが，一般に，データを短いセグメントで処理する必要がある信号処理アプリケーションで使われる窓関数である．
  • 窓関数には，データ値を漸減して各セグメントの終りで0に近付ける平滑化効果がある．
  • CauchyWindow[x,α]は 1/(4 alpha^2 x^2+1) -1/2<=x<=1/2; 0 TemplateBox[{x}, Abs]>1/2; に等しい
  • CauchyWindow[x]はCauchyWindow[x,3]と等価である．
  • CauchyWindowは自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (3)

1Dコーシー窓の形：

Wolfram Language code: Plot[CauchyWindow[x], {x, -1, 1}, Exclusions -> None]

2Dコーシー窓の形：

Wolfram Language code: Plot3D[CauchyWindow[x]CauchyWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All, Exclusions -> None]

コーシー窓を表す連続関数を抽出する：

Wolfram Language code: FunctionExpand[CauchyWindow[x]]

パラメータ化されたコーシー窓：

Wolfram Language code: FunctionExpand[CauchyWindow[x, α]]

スコープ  (6)

数値的に評価する：

Wolfram Language code: CauchyWindow[0.1]

指定されたパラメータを使った1Dコーシー窓の形：

Wolfram Language code: Plot[CauchyWindow[x, 2], {x, -1, 1}, Exclusions -> None]

パラメータ α の関数としての形の変化：

Wolfram Language code: Plot3D[CauchyWindow[x, α], {α, 0, 5}, {x, -1, 1}]

平行移動され広げられたコーシー窓：

Wolfram Language code: Plot[CauchyWindow[(x - 1) / 2], {x, -1, 3}, Exclusions -> None]

円形の台を持つ2Dコーシー窓：

Wolfram Language code: Plot3D[CauchyWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All, Exclusions -> None]

長さ15の離散コーシー窓：

Wolfram Language code: ListPlot[Array[CauchyWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

15×10の2D離散コーシー窓：

Wolfram Language code: ListPointPlot3D[Array[CauchyWindow[#1] CauchyWindow[#2]&, {15, 10}, {{-1 / 2, 1 / 2}}], Filling -> Axis, PlotRange -> All]

アプリケーション  (2)

窓指定を使ってサンプルPowerSpectralDensityを計算する：

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

スペクトルを計算する：

Wolfram Language code: spec = PowerSpectralDensity[data, w, CauchyWindow];

窓関数を使わずに計算されたスペクトル密度と比較する：

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

プロットは，窓がスペクトル密度を平坦化したことを示している：

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotRange -> All, PlotLegends -> {"no window", "with window"}]

この過程の理論的なスペクトル密度と比較する：

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

時系列推定に窓指定を使う：

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

スペクトル推定器に窓を指定する：

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> CauchyWindow}]

特性と関係  (3)

CauchyWindow[x,0]はディリクレ窓に等しい：

Wolfram Language code: FunctionExpand[CauchyWindow[x, 0]] == FunctionExpand[DirichletWindow[x]]

コーシー窓の下の面積：

Wolfram Language code: area = Integrate[CauchyWindow[x], {x, -∞, ∞}]

正規化することで単位面積の窓を作る：

Wolfram Language code: Plot[{CauchyWindow[x], CauchyWindow[x] / area}, {x, -1, 1}]

コーシー窓のフーリエ変換：

Wolfram Language code: f = FourierTransform[CauchyWindow[x], x, w]

コーシー窓のパワースペクトル：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 80}]

考えられる問題  (1)

Arrayに記号として渡す場合には，コーシー窓の2Dサンプリングはサンプルの各行に異なるパタメータを用いる：

Wolfram Language code: Array[CauchyWindow, {30, 30}, {{-1 / 2, 1 / 2}}]//ListPlot3D

代りに純関数を使う：

Wolfram Language code: ListPlot3D[Array[CauchyWindow[#1] CauchyWindow[#2]&, {30, 30}, {{-1 / 2, 1 / 2}}], PlotRange -> All]
Wolfram Research (2012), CauchyWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/CauchyWindow.html.

テキスト

Wolfram Research (2012), CauchyWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/CauchyWindow.html.

CMS

Wolfram Language. 2012. "CauchyWindow." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CauchyWindow.html.

APA

Wolfram Language. (2012). CauchyWindow. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CauchyWindow.html

BibTeX

@misc{reference.wolfram_2026_cauchywindow, author="Wolfram Research", title="{CauchyWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CauchyWindow.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cauchywindow, organization={Wolfram Research}, title={CauchyWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/CauchyWindow.html}, note=[Accessed: 10-September-2026]}