WOLFRAM

Wolfram 语言与系统参考资料中心

ChannelReceiverFunction[fun]

表示一个信道接收函数，对收到的所有消息应用 fun.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

ChannelReceiverFunction

ChannelReceiverFunction[fun]

表示一个信道接收函数，对收到的所有消息应用 fun.

更多信息和选项

  • CloudDeploy[ChannelReceiverFunction[…]] 给出一个 CloudObject，含有指定信道接收器消息应发往的信道的元信息.
  • CloudDeploy[ChannelReceiverFunction[…]"curi"] 把接收器部署到 ChannelObject["curi"].
  • CloudDeploy[ChannelReceiverFunction[…]channel] 把接收器部署到 ChannelObject[…] 指定的信道.
  • CloudDeploy[ChannelReceiverFunction[…]] 等价于 CloudDeploy[ChannelReceiverFunction[…]Automatic].
  • 在部署的 ChannelReceiverFunction[fun] 中，只要收到消息，就会计算 fun[assoc]. 关联 assoc 中包含有与 ChannelListen 相同的元素，除了ChannelListener 对象特有的元素.
  • CloudDeploy[ChannelReceiverFunction[fun]] 设置在云中执行的信道接收器函数，并且不需要在任何特定 Wolfram 语言会话中有活动的监听器.
  • 函数 fun 在信道接收器函数的所有者的环境中进行计算.
  • 信道接收器函数不能由本身从信道接收器函数内发送的消息触发.

范例

打开所有单元 关闭所有单元

基本范例  (3)

定义一个接收器函数：

Wolfram Language code: f = ChannelReceiverFunction[{#Message, #MessageID}&]

将该函数应用于表示信道代理器消息的关联：

Wolfram Language code: f[<|"Message" -> "message", "MessageID" -> "id"|>]

定义接收器函数，将传入的消息记录到云对象：

Wolfram Language code: f = ChannelReceiverFunction[CloudPut[#Message, CloudObject[ "LastMessage"]]&]

部署该函数：

Wolfram Language code: object = CloudDeploy[f]

获取接收器的目标信道：

Wolfram Language code: channel = ChannelObject[object]

往信道发送一条消息：

Wolfram Language code: ChannelSend[channel, "hello"]

读取云对象：

Wolfram Language code: CloudGet[CloudObject["LastMessage"]]

清理：

Wolfram Language code: DeleteChannel[channel]; DeleteObject[object];

定义将输入消息记录到数据仓的接收器函数：

Wolfram Language code: bin = CreateDatabin[]; f = ChannelReceiverFunction[DatabinAdd[bin, #]&]

部署函数：

Wolfram Language code: object = CloudDeploy[f]

获取接收器函数的目标信道：

Wolfram Language code: channel = ChannelObject[object]

向信道发送消息：

Wolfram Language code: ChannelSend[channel, "hello"]

检查数据仓的内容：

Wolfram Language code: bin["Entries"]

Wolfram Data Drop 对时间戳进行了特殊处理，并且可以在单独的属性中（或与 “FullEntries” 属性中的条目正文一起）使用：

Wolfram Language code: bin["Timestamps"]

清理：

Wolfram Language code: DeleteChannel[channel]; DeleteObject[{object, bin}];

范围  (7)

应用于关联：

Wolfram Language code: ChannelReceiverFunction[#&][<|"Message" -> <|"a" -> "b"|>, "MessageID" -> "id"|>]

应用于表示 JSON 对象的字符串：

Wolfram Language code: ChannelReceiverFunction[#Message&]["{\"x\":\"1\"}"]

部署到匿名云对象和匿名信道对象：

Wolfram Language code: obj = CloudDeploy[ChannelReceiverFunction[#&]]
Wolfram Language code: ChannelObject[obj]

清理：

Wolfram Language code: DeleteChannel[%]; DeleteObject[obj];

部署到指定信道对象：

Wolfram Language code: obj = CloudDeploy[ChannelReceiverFunction[#&] -> "channel"]
Wolfram Language code: ChannelObject[obj]

清理：

Wolfram Language code: DeleteChannel[%]; DeleteObject[obj];

部署到指定云对象：

Wolfram Language code: obj = CloudDeploy[ChannelReceiverFunction[#&], "cloudObject"]
Wolfram Language code: ChannelObject[obj]

清理：

Wolfram Language code: DeleteChannel[%]; DeleteObject[obj];

部署到指定信道对象和指定云对象：

Wolfram Language code: obj = CloudDeploy[ChannelReceiverFunction[#&] -> "channel", "cloudObject"]
Wolfram Language code: ChannelObject[obj]

清理：

Wolfram Language code: DeleteChannel[%]; DeleteObject[obj];

指定对象作为目标：

Wolfram Language code: obj = CloudDeploy[ChannelReceiverFunction[#&] -> ChannelObject["channel"], CloudObject["x"]]
Wolfram Language code: ChannelObject[obj]

清理：

Wolfram Language code: DeleteChannel[%]; DeleteObject[obj];

应用  (3)

部署一个将传入消息添加到数据仓的信道：

Wolfram Language code: bin = CreateDatabin[]
Wolfram Language code: obj = CloudDeploy[ChannelReceiverFunction[DatabinAdd[bin, <|"Data" -> #Message|>]&] -> "channel"]

往信道发送一条消息并从数据仓取回内容：

Wolfram Language code: ChannelSend["channel", "hello"]
Wolfram Language code: bin["Entries"]

清理：

Wolfram Language code: DeleteObject[{bin, obj}]; DeleteChannel["channel"];

定义接收器函数，将包含字符串 "URGENT" 的消息发送到优先信道，其余的发送到普通信道 (bulk channel)：

Wolfram Language code: f = ChannelReceiverFunction[ChannelSend[If[StringContainsQ[#Message, "URGENT"], "priority", "bulk"], #Message]&]

创建两个信道，并将接收器函数部署到自动创建的第三个通道：

Wolfram Language code: CreateChannel /@ {"priority", "bulk"} obj = CloudDeploy[f -> "dispatcher"]

开始监听信道：

Wolfram Language code: priority = ChannelListen["priority"]
Wolfram Language code: bulk = ChannelListen["bulk"]

在调度信道上发送常规和紧急消息：

Wolfram Language code: Scan[ChannelSend["dispatcher", #]&, {"URGENT message", "low priority"}]

收到的消息：

Wolfram Language code: priority["Message"]
Wolfram Language code: bulk["Message"]

清理：

Wolfram Language code: DeleteChannel[{"priority", "bulk", "dispatcher"}]; DeleteObject[obj];

如果消息到达时无人监听，则部署发送电子邮件警报的接收器函数：

Wolfram Language code: channel = "withAlert"; CreateChannel[channel];
Wolfram Language code: obj = CloudDeploy[ChannelReceiverFunction[If[ChannelSubscribers[channel] === {}, SendMail[<|"To" -> $WolframID, "Subject" -> "missed message from " <> #RequesterWolframID, "Body" -> #Message|>]]&] -> channel]

在信道上发送消息，检查邮箱获取电子邮件警报：

Wolfram Language code: ChannelSend[channel, "Are you there?"]

清理：

Wolfram Language code: DeleteChannel[channel]; DeleteObject[obj];

属性和关系  (1)

部署 ChannelReceiverFunction 将会设置相关信道对象的 ChannelBrokerAction：

Wolfram Language code: CloudDeploy[ChannelReceiverFunction[#&]]
Wolfram Language code: Options[ChannelObject[%], ChannelBrokerAction]
Wolfram Research (2017)，ChannelReceiverFunction，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ChannelReceiverFunction.html （更新于 2020 年）.

文本

Wolfram Research (2017)，ChannelReceiverFunction，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ChannelReceiverFunction.html （更新于 2020 年）.

CMS

Wolfram 语言. 2017. "ChannelReceiverFunction." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2020. https://reference.wolfram.com/language/ref/ChannelReceiverFunction.html.

APA

Wolfram 语言. (2017). ChannelReceiverFunction. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ChannelReceiverFunction.html 年

BibTeX

@misc{reference.wolfram_2026_channelreceiverfunction, author="Wolfram Research", title="{ChannelReceiverFunction}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/ChannelReceiverFunction.html}", note=[Accessed: 18-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_channelreceiverfunction, organization={Wolfram Research}, title={ChannelReceiverFunction}, year={2020}, url={https://reference.wolfram.com/language/ref/ChannelReceiverFunction.html}, note=[Accessed: 18-August-2026]}