WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CityData[name,"property"]

指定された名前の都市の指定された特性の値を返す．

CityData[name]

名前が name と一致する都市の完全な詳細のリストを返す．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
都市名と認識  
都市の集まり  
都市の情報  
アプリケーション  
特性と関係  
考えられる問題  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

CityData

CityData[name,"property"]

指定された名前の都市の指定された特性の値を返す．

CityData[name]

名前が name と一致する都市の完全な詳細のリストを返す．

詳細

  • 都市の完全な詳細は{"city","region","country"}で与えられる．ここで，"region"は州，地方，その他の行政区分である．
  • 都市，地域，国の名前は，"NewYork"，"BritishColumbia"，"UnitedStates"のような標準的な形式で与えられる．
  • CityData["city"]は，"city"という名前の世界中の大都市を人口の降順に並べたリストを返す．
  • CityData[{"city","country"}]は，指定された国にある"city"という名前のすべての都市の完全な詳細を返す．結果は人口の降順に並べられる．
  • CityData[{"city","country"},"property"]は，与えられた国で指定の名前を持つ都市中で人口が最大のものの"property"の値を返す．
  • CityData[{"city","region","country"},"property"]は，完全都市指定{"city","region","country"}で表された特定の都市の"property"の値を返す．
  • 特定の地域あるいは国に指定された名前の都市が2つ以上ある場合，その都市の標準名は識別のために国名等の付加的な情報を含むようになる．
  • CityData[{All,"region","country"}]は，ある国の指定の地域にあるすべての都市を人口の降順に並べたリストを返す．
  • CityData[{Large,"region","country"}]は，指定地域のすべての大都市のリストを返す．大都市とは，一般に人口十万人以上の都市と定義される．
  • CityData[{All,"country"}]とCityData[{Large,"country"}]はそれぞれ指定国のすべての参照可能都市と大都市を返す．
  • CityData[]またはCityData[All]は世界中のすべての参照可能都市のリストを返す．
  • 都市に使われる一般的な特性
  • "Coordinates"都市中央の緯度と経度
    "Elevation"都市の中央の高度（メートル）
    "Latitude"都市の中央の緯度
    "LocationLink"その都市を中心にした地図のURI
    "Longitude"都市の中央の経度
    "Population"推定総人口
    "TimeZone"UTCと相対的な現在の時刻帯
  • 名前および識別関連特性
  • "AlternateNames"別名
    "Country"その都市がある国
    "FullName"主な完全英語名（例："New York, New York"）
    "Name"主な短縮英語名（例："New York"）
    "Region"州，地方，その他の行政区分
    "RegionName"その地域の英語名または現地語名
  • CityData["name","property","ann"]は特性に関連するさまざまな注釈を与える．典型的な注釈には次のようなものがある．
  • "Date"データが参照する日付
    "Description"特性についての説明
    "Units"値が与えられている単位
    "UnitsName"使用されている単位の英語名
    "UnitsNotation"使用されている単位の表記法
    "UnitsStandardName"使用されている単位のWolfram言語における標準名

例題

すべて開く すべて閉じる

例  (5)

世界中でLondonという名前の都市をすべて人口の降順で並べる：

Wolfram Language code: CityData["London"]

イギリスのロンドンの人口を求める：

Wolfram Language code: CityData["London", "Population"]

オンタリオのロンドンの人口を求める：

Wolfram Language code: CityData[{"London", "Ontario", "Canada"}, "Population"]

イギリスのロンドンの中心の緯度と経度を求める：

Wolfram Language code: CityData["London", "Coordinates"]

都市の英語名を求める：

Wolfram Language code: CityData["NewLondon", "Name"]
Wolfram Language code: CityData["NewLondon", "FullName"]

バヌアツのすべての参照可能都市を求める：

Wolfram Language code: CityData[{All, "Vanuatu"}]

スコープ  (13)

都市名と認識  (6)

Wolfram言語の標準的な名前はすべてのスペースを省略する：

Wolfram Language code: CityData["LosAngeles"]

スペースを含む名前で表示できる都市：

Wolfram Language code: CityData["Los Angeles"]

"Name"特性はスペースを含む普通の名前を返す：

Wolfram Language code: CityData["LosAngeles", "Name"]

チリのロサンゼルスを指定する：

Wolfram Language code: CityData[{"LosAngeles", "Chile"}]

Fresnoという名前を持つ世界中の都市：

Wolfram Language code: CityData["Fresno"]

Fresnoという名前を持つアメリカ合衆国の都市：

Wolfram Language code: CityData[{"Fresno", "UnitedStates"}]

テキサスのFresnoを指定する：

Wolfram Language code: CityData[{"Fresno", "TX"}]

同じ名前を持つ複数の都市はcounty（郡）や他の情報によって識別される：

Wolfram Language code: CityData[{"Jefferson", "Wisconsin"}]

基本的な名前は同じである：

Wolfram Language code: CityData[#, "Name"]& /@ %

小さい都市の完全名はcounty（郡）の情報を含んでいる：

Wolfram Language code: CityData[#, "FullName"]& /@ %%

Beijingの別名：

Wolfram Language code: CityData["Beijing", "AlternateNames"]

Frogという名前の都市は世界中どこにもない：

Wolfram Language code: CityData["Frog"]

都市の集まり  (3)

Tuvaluの参照可能な都市：

Wolfram Language code: CityData[{All, "Tuvalu"}]

ベルギーの大都市（人口，100,000人以上）：

Wolfram Language code: CityData[{Large, "Belgium"}]
Wolfram Language code: CityData[#, "Population"]& /@ %

オハイオ州の大きな都市：

Wolfram Language code: CityData[{Large, "Ohio", "UnitedStates"}]

イリノイ州のすべての参照可能都市：

Wolfram Language code: CityData[{All, "Illinois", "UnitedStates"}]//Short

都市の情報  (4)

シカゴ中央の緯度と経度：

Wolfram Language code: CityData["Chicago", "Coordinates"]

シカゴの高度(m)：

Wolfram Language code: CityData["Chicago", "Elevation"]

シカゴのWebマップへのリンク：

Wolfram Language code: CityData["Chicago", "LocationLink"]

シカゴのある州：

Wolfram Language code: CityData["Chicago", "Region"]

アプリケーション  (9)

アメリカ合衆国内で与えられた場所から最も近い大都市を求める関数：

Wolfram Language code: nc = Nearest[CityData[#, "Coordinates"] -> #& /@ CityData[{Large, "UnitedStates"}]]

イリノイ州シャンペーンに最も近い3つの大都市：

Wolfram Language code: nc[CityData[{"Champaign", "Illinois"}, "Coordinates"], 3]

日本の都市の位置をプロット：

Wolfram Language code: ListPlot[Reverse[CityData[#, "Coordinates"]]& /@ CityData[{All, "Japan"}], PlotRange -> {{120, 150}, {20, 50}}]

ドイツとベルギー両方の国に存在する都市名：

Wolfram Language code: Intersection[Part[#, 2, 1]& /@ CityData[{All, "Germany"}], Part[#, 2, 1]& /@ CityData[{All, "Belgium"}]]

アメリカ合衆国のいくつかの州の人口のランクプロット：

Wolfram Language code: ListLogPlot[Reverse[Sort[CityData[#, "Population"]& /@ CityData[{All, #, "UnitedStates"}]]]& /@ {"Alabama", "Alaska", "Arizona", "Arkansas", "California"}]

オーストラリアの大都市を都市名を表示するツールチップ付きでプロット：

Wolfram Language code: Graphics[{Gray, CountryData["Australia", "Polygon"], PointSize[Large], Red, Tooltip[Point[Reverse[CityData[#, "Coordinates"]]], CityData[#, "Name"]]& /@ CityData[{Large, "Australia"}]}]

より大きい都市をより大きな透明な円でプロット：

Wolfram Language code: Graphics[{Gray, CountryData["NewZealand", "Polygon"], Opacity[0.3, Blue], Disk[Reverse[CityData[#, "Coordinates"]], Log[10. ^ 9, QuantityMagnitude[CityData[#, "Population"]]]]& /@ CityData[{All, "NewZealand"}]}]

ドイツの大都市を回るセールスマン巡回問題：

Wolfram Language code: Graphics[{Gray, CountryData["Germany", "Polygon"], Thick, Green, Line[#[[Last[FindShortestTour[#]]]]&[Reverse[CityData[#, "Coordinates"]]& /@ CityData[{Large, "Germany"}]]]}]

州内の都市の高度に基づき，コロラド州の3Dのと等高線プロットを作成：

Wolfram Language code: ListPlot3D[{CityData[#, "Longitude"], CityData[#, "Latitude"], CityData[#, "Elevation"]}& /@ CityData[{All, "Colorado", "UnitedStates"}], ColorFunction -> "Topographic", MeshFunctions -> {#3&}]

コロラド州の都市の人口，高度の離散プロット：

Wolfram Language code: ListLogPlot[{CityData[#, "Elevation"], CityData[#, "Population"]}& /@ CityData[{All, "Colorado", "UnitedStates"}]]

特性と関係  (2)

CityData は人口が多いものから少ないものへの順で都市を表示する：

Wolfram Language code: Take[CityData[{All, "Albania"}], 10]

CountryDataは国で最も大きい都市を表示できる：

Wolfram Language code: CountryData["Albania", "LargestCities"]

ニューヨークを中心としたランベルト方位投影地図を作成：

Wolfram Language code: Graphics[{Gray, CountryData[#, {"SchematicPolygon", {"LambertAzimuthal", CityData["NewYork", "Coordinates"]}}]& /@ CountryData[]}]

考えられる問題  (3)

CityDataは完全な都市だけを含む．都市の部分は含まれない：

Wolfram Language code: CityData["Manhattan"]

都市によっては，都市名，属している行政区分，国名が同じこともある：

Wolfram Language code: CityData["Singapore"]

一つの州で同じ名前を持つ複数の都市がある場合もある：

Wolfram Language code: CityData[{"Kendall", "Wisconsin"}]

小さい都市にはcounty（郡）または他の識別する情報が付けられる：

Wolfram Language code: CityData[#, "FullName"]& /@ %

おもしろい例題  (2)

世界で最もよくある10個の都市名：

Wolfram Language code: Take[SortBy[Tally[Part[#, 2, 1]& /@ CityData[]], Last], -10]

San Joseという都市の存在する国を求める：

Wolfram Language code: Tally[Part[#, 2, -1]& /@ CityData["SanJose"]]

世界で最も人口の少ない首都を求める：

Wolfram Language code: Take[SortBy[DeleteCases[CountryData[#, "CapitalCity"]& /@ CountryData[], _Missing], CityData[#, "Population"]&], 5]

その人口を求める：

Wolfram Language code: CityData[#, "Population"]& /@ %
Wolfram Research (2007), CityData, Wolfram言語関数， https://reference.wolfram.com/language/ref/CityData.html （2014年に更新）.

テキスト

Wolfram Research (2007), CityData, Wolfram言語関数， https://reference.wolfram.com/language/ref/CityData.html （2014年に更新）.

CMS

Wolfram Language. 2007. "CityData." Wolfram Language & System Documentation Center. Wolfram Research. Last Modified 2014. https://reference.wolfram.com/language/ref/CityData.html.

APA

Wolfram Language. (2007). CityData. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CityData.html

BibTeX

@misc{reference.wolfram_2026_citydata, author="Wolfram Research", title="{CityData}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/CityData.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_citydata, organization={Wolfram Research}, title={CityData}, year={2014}, url={https://reference.wolfram.com/language/ref/CityData.html}, note=[Accessed: 07-September-2026]}