WOLFRAM

Wolfram 语言与系统参考资料中心

CityData[name,"property"]

给出指定名称的城市的指定属性值.

CityData[name]

给出名称与 name 一致的城市的完整说明列表.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
城市名称与识别  
城市集合  
城市信息  
应用  
属性和关系  
可能存在的问题  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

CityData

CityData[name,"property"]

给出指定名称的城市的指定属性值.

CityData[name]

给出名称与 name 一致的城市的完整说明列表.

更多信息

  • 一个城市的完整说明为 {"city","region","country"}，这里 "region" 为州、省或其它行政区域.
  • 城市、区域和国家的名称按标准形式给出，如 "NewYork"、"BritishColumbia" 和 "UnitedStates".
  • CityData["city"] 给出全世界所有名称为 "city" 的城市的列表，并按人口递减规律排列.
  • CityData[{"city","country"}] 给出指定国家中所有名称为 "city" 的完整说明. 其结果按人口递减规律排列.
  • CityData[{"city","country"},"property"] 给出指定名称的国家中人口最多城市的 "property" 值.
  • CityData[{"city","region","country"},"property"] 给出由完整的城市说明 {"city","region","country"} 所表示的特定城市的 "property" 值.
  • 若一特定区域和国家内含有名称相同的城市，则城市的标准名称中将包含附加的识别信息，如县的名称.
  • CityData[{All,"region","country"}] 给出一个国家指定区域内所有可获城市的列表，并按人口递减规律排列.
  • CityData[{Large,"region","country"}] 给出指定区域中所有大城市的列表. 大城市一般定义为人口在100,000 之上的城市.
  • CityData[{All,"country"}] 和 CityData[{Large,"country"}] 分别给出指定国家中所有可获城市和所有大城市.
  • CityData[] 或 CityData[All] 给出全世界所有可获城市的列表.
  • 城市的标准属性性包括：
  • "Coordinates"市中心的经纬度
    "Elevation"以米为单位的市中心的海拔
    "Latitude"市中心的纬度
    "LocationLink"城市地图的 URI
    "Longitude"市中心的经度
    "Population"估计总人口
    "TimeZone"现对于 UTC 的当前时区
  • 名称及相关识别属性包括：
  • "AlternateNames"别名
    "Country"城市所在国家
    "FullName"主要英文全名（ 如 "New York, New York" ）
    "Name"主要英文缩写名（如 "New York" ）
    "Region"州、省或其他行政区域
    "RegionName"区域的英文或当地名称
  • CityData["name","property","ann"] 给出与属性有关的不同注解. 标准注解包括：
  • "Date"数据所指日期
    "Description"属性的描述
    "Units"值的单位
    "UnitsName"所用单位的英语名
    "UnitsNotation"所用单位的符号
    "UnitsStandardName"所用单位的 Wolfram 语言标准名称

范例

打开所有单元 关闭所有单元

基本范例  (5)

查找全世界所有名称为伦敦的城市，并按人口递减规律排列：

Wolfram Language code: CityData["London"]

查找英国伦敦的人口数：

Wolfram Language code: CityData["London", "Population"]

查找安大略湖伦敦的人口数：

Wolfram Language code: CityData[{"London", "Ontario", "Canada"}, "Population"]

查找英国伦敦市中心的经纬度：

Wolfram Language code: CityData["London", "Coordinates"]

给出城市的英文名：

Wolfram Language code: CityData["NewLondon", "Name"]
Wolfram Language code: CityData["NewLondon", "FullName"]

瓦努阿图的所有城市：

Wolfram Language code: CityData[{All, "Vanuatu"}]

范围  (13)

城市名称与识别  (6)

标准 Wolfram 语言名称忽略所有空格：

Wolfram Language code: CityData["LosAngeles"]

可要求城市名含有空格：

Wolfram Language code: CityData["Los Angeles"]

"Name" 属性给出含有空格的惯名：

Wolfram Language code: CityData["LosAngeles", "Name"]

指定智利的洛杉矶：

Wolfram Language code: CityData[{"LosAngeles", "Chile"}]

世界上所有名为弗雷斯诺的城市：

Wolfram Language code: CityData["Fresno"]

名为弗雷斯诺的美国城市：

Wolfram Language code: CityData[{"Fresno", "UnitedStates"}]

指定德克萨斯州的弗雷斯诺：

Wolfram Language code: CityData[{"Fresno", "TX"}]

同一州内多个城市同名的，由县或其它信息加以区别：

Wolfram Language code: CityData[{"Jefferson", "Wisconsin"}]

基本名称是相同的：

Wolfram Language code: CityData[#, "Name"]& /@ %

较小城市的完整名称含有县的信息：

Wolfram Language code: CityData[#, "FullName"]& /@ %%

查找北京的别名：

Wolfram Language code: CityData["Beijing", "AlternateNames"]

全世界没有一个城市名为 Frog：

Wolfram Language code: CityData["Frog"]

城市集合  (3)

查找图瓦卢的所有城市：

Wolfram Language code: CityData[{All, "Tuvalu"}]

查找比利时的大城市（人口总数超过 100,000）：

Wolfram Language code: CityData[{Large, "Belgium"}]
Wolfram Language code: CityData[#, "Population"]& /@ %

俄亥俄州的大城市：

Wolfram Language code: CityData[{Large, "Ohio", "UnitedStates"}]

查找伊利诺州的所有城市：

Wolfram Language code: CityData[{All, "Illinois", "UnitedStates"}]//Short

城市信息  (4)

芝加哥市中心的坐标：

Wolfram Language code: CityData["Chicago", "Coordinates"]

芝加哥的海拔（单位：米）：

Wolfram Language code: CityData["Chicago", "Elevation"]

城市地图的超级链接：

Wolfram Language code: CityData["Chicago", "LocationLink"]

芝加哥所位于的区域：

Wolfram Language code: CityData["Chicago", "Region"]

应用  (9)

创建一个函数，用以查找美国境内距给定位置最近的大城市：

Wolfram Language code: nc = Nearest[CityData[#, "Coordinates"] -> #& /@ CityData[{Large, "UnitedStates"}]]

查找距伊利诺伊州香槟市最近的3个大城市：

Wolfram Language code: nc[CityData[{"Champaign", "Illinois"}, "Coordinates"], 3]

绘制日本所有城市的位置：

Wolfram Language code: ListPlot[Reverse[CityData[#, "Coordinates"]]& /@ CityData[{All, "Japan"}], PlotRange -> {{120, 150}, {20, 50}}]

找出德国和比利时的同名城市：

Wolfram Language code: Intersection[Part[#, 2, 1]& /@ CityData[{All, "Germany"}], Part[#, 2, 1]& /@ CityData[{All, "Belgium"}]]

绘制美国多个州的人口排名图：

Wolfram Language code: ListLogPlot[Reverse[Sort[CityData[#, "Population"]& /@ CityData[{All, #, "UnitedStates"}]]]& /@ {"Alabama", "Alaska", "Arizona", "Arkansas", "California"}]

绘制澳大利亚的大城市，并有工具提示它们的名称：

Wolfram Language code: Graphics[{Gray, CountryData["Australia", "Polygon"], PointSize[Large], Red, Tooltip[Point[Reverse[CityData[#, "Coordinates"]]], CityData[#, "Name"]]& /@ CityData[{Large, "Australia"}]}]

用较大的透明圆盘绘制大城市：

Wolfram Language code: Graphics[{Gray, CountryData["NewZealand", "Polygon"], Opacity[0.3, Blue], Disk[Reverse[CityData[#, "Coordinates"]], Log[10. ^ 9, QuantityMagnitude[CityData[#, "Population"]]]]& /@ CityData[{All, "NewZealand"}]}]

获得旅行推销员的德国大城市行程：

Wolfram Language code: Graphics[{Gray, CountryData["Germany", "Polygon"], Thick, Green, Line[#[[Last[FindShortestTour[#]]]]&[Reverse[CityData[#, "Coordinates"]]& /@ CityData[{Large, "Germany"}]]]}]

用州内各城市的海拔绘制美国科罗拉多州的三维等高线图：

Wolfram Language code: ListPlot3D[{CityData[#, "Longitude"], CityData[#, "Latitude"], CityData[#, "Elevation"]}& /@ CityData[{All, "Colorado", "UnitedStates"}], ColorFunction -> "Topographic", MeshFunctions -> {#3&}]

绘制科罗拉多州各城市人口相对海拔的散点图：

Wolfram Language code: ListLogPlot[{CityData[#, "Elevation"], CityData[#, "Population"]}& /@ CityData[{All, "Colorado", "UnitedStates"}]]

属性和关系  (2)

CityData 按人口由多至少列出城市：

Wolfram Language code: Take[CityData[{All, "Albania"}], 10]

CountryData 可以给出一个国家中最大的城市：

Wolfram Language code: CountryData["Albania", "LargestCities"]

以纽约城为中心制作朗伯方位角投射图：

Wolfram Language code: Graphics[{Gray, CountryData[#, {"SchematicPolygon", {"LambertAzimuthal", CityData["NewYork", "Coordinates"]}}]& /@ CountryData[]}]

可能存在的问题  (3)

CityData 包含的是城市的全部，而不是城市的一部分：

Wolfram Language code: CityData["Manhattan"]

有时城市、区域和国家可能同名：

Wolfram Language code: CityData["Singapore"]

同一州可以有多个城市同名：

Wolfram Language code: CityData[{"Kendall", "Wisconsin"}]

较小的城市含有县或其它识别信息：

Wolfram Language code: CityData[#, "FullName"]& /@ %

巧妙范例  (2)

查找 10 个世界上最通用的城市名：

Wolfram Language code: Take[SortBy[Tally[Part[#, 2, 1]& /@ CityData[]], Last], -10]

查找拥有城市名 San Jose 的国家：

Wolfram Language code: Tally[Part[#, 2, -1]& /@ CityData["SanJose"]]

查找世界上拥有最少登记人口的首都：

Wolfram Language code: Take[SortBy[DeleteCases[CountryData[#, "CapitalCity"]& /@ CountryData[], _Missing], CityData[#, "Population"]&], 5]

查找人口数：

Wolfram Language code: CityData[#, "Population"]& /@ %
Wolfram Research (2007)，CityData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CityData.html （更新于 2014 年）.

文本

Wolfram Research (2007)，CityData，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CityData.html （更新于 2014 年）.

CMS

Wolfram 语言. 2007. "CityData." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/CityData.html.

APA

Wolfram 语言. (2007). CityData. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CityData.html 年

BibTeX

@misc{reference.wolfram_2026_citydata, author="Wolfram Research", title="{CityData}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/CityData.html}", note=[Accessed: 15-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_citydata, organization={Wolfram Research}, title={CityData}, year={2014}, url={https://reference.wolfram.com/language/ref/CityData.html}, note=[Accessed: 15-September-2026]}