WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ClassPriors

Classifyとその関連の関数のオプションであり，訓練集合から導き出されるものとは関係なく，出力クラスに想定される明示的な優先確率を指定する．

詳細
Details and Options Details and Options
例題  
例  
アプリケーション  
関連項目
履歴
引用書式

ClassPriors

ClassPriors

Classifyとその関連の関数のオプションであり，訓練集合から導き出されるものとは関係なく，出力クラスに想定される明示的な優先確率を指定する．

詳細

  • ClassPriors<|class1p1,class2p2,…|>は，特定の入力をクラス classiにあるものとして分類する優先確率が piとなるように指定する．
  • デフォルトで，優先分類は訓練集合のクラス頻度によって計算される．
  • ClassPriors<|class1p1,class2p2,…|>では，分布の正規化を確実にするために，指定されていない優先分類が再スケールされたデフォルト値に設定される．

例題

すべて開く すべて閉じる

例  (1)

偏った訓練集合について分類器を訓練する：

Wolfram Language code: trainingset = {1 -> "a", 2 -> "b", 3 -> "a", 4 -> "b", 5 -> "b", 6 -> "b", 7 -> "b"};
Wolfram Language code: c = Classify[trainingset]

新たな例のクラス確率を求める：

Wolfram Language code: c[2.5, "Probabilities"]

クラスについて，一様ではない優先分布を設定する：

Wolfram Language code: c[2.5, "Probabilities", ClassPriors -> <|"a" -> 0.5, "b" -> 0.5|>]

分類器内にクラスの優先分布を設定する：

Wolfram Language code: c = Classify[trainingset, ClassPriors -> <|"a" -> 0.5, "b" -> 0.5|>]
Wolfram Language code: c[2.5, "Probabilities"]

指定されていないクラスの優先分布は残りの確率質量の関数である：

Wolfram Language code: c[2.5, "Probabilities", ClassPriors -> <|"a" -> 0.8|>]
Wolfram Language code: c[2.5, "Probabilities", ClassPriors -> <|"a" -> 1|>]

アプリケーション  (3)

組込み言語の分類器を，2言語に制限する：

Wolfram Language code: Classify["Language", {"What is this language?", "¿Qué idioma es ese?", "Quelle est cette langue?"}, ClassPriors -> <|Entity["Language", "English"] -> 0.5, Entity["Language", "Spanish"] -> 0.5|>]

バランスの取れた訓練集合について有機体が病気に罹ったかどうかが分かるように，分類器を訓練する：

Wolfram Language code: c = Classify[{{1., 3.2, "Y"} -> "Diseased", {2.4, -3.1, "N"} -> "Healthy", {-2.1, 4.2, "N"} -> "Diseased", {2.7, -10, "N"} -> "Healthy", {-4., 6.2, "Y"} -> "Diseased", {2.5, 7., "Y"} -> "Healthy"}]

新たな有機体が病気である確率を求める：

Wolfram Language code: c[{0.8, 2.2, "Y"}, "Probabilities"]

病気の有機体が母集団の1%に過ぎないというこれまでの知識に立脚し，同じ有機体が病気である確率を求める：

Wolfram Language code: c[{0.8, 2.2, "Y"}, "Probabilities", ClassPriors -> <|"Diseased" -> 0.01|>]

Webサイトのユーザが指定の製品を買うかどうかをユーザ動作に基づいて予測できるように，分類器を訓練する：

Wolfram Language code: c = Classify[{ {1.7, False, 1.3, True} -> "will buy", {-4, False, 1.1, True} -> "won't buy", {5.7, True, 1.2, True} -> "will buy", {7.3, False, 1.3, False} -> "won't buy", {-2.3, False, 1.8, True} -> "won't buy", {3.2, True, 1.4, True} -> "won't buy" }]

その製品を買う確率モデルを，外気温の関数として定義し，可視化する：

Wolfram Language code: prior[temp_] := 0.15 + ArcTan[-0.1 * temp] / 10;
Wolfram Language code: Plot[prior[temp], {temp, -20, 40}, PlotRange -> {0, 1}]

このモデルとWeatherDataを利用して，追加の訓練を行わずにパリ在住のユーザについてのパフォーマンスを向上させる：

Wolfram Language code: c[{7.2, False, 1.5, True}, "Probabilities", ClassPriors -> <|"will buy" -> prior[QuantityMagnitude[WeatherData["Paris", "Temperature"]]]|>]
Wolfram Research (2014), ClassPriors, Wolfram言語関数， https://reference.wolfram.com/language/ref/ClassPriors.html.

テキスト

Wolfram Research (2014), ClassPriors, Wolfram言語関数， https://reference.wolfram.com/language/ref/ClassPriors.html.

CMS

Wolfram Language. 2014. "ClassPriors." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ClassPriors.html.

APA

Wolfram Language. (2014). ClassPriors. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ClassPriors.html

BibTeX

@misc{reference.wolfram_2026_classpriors, author="Wolfram Research", title="{ClassPriors}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/ClassPriors.html}", note=[Accessed: 09-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_classpriors, organization={Wolfram Research}, title={ClassPriors}, year={2014}, url={https://reference.wolfram.com/language/ref/ClassPriors.html}, note=[Accessed: 09-September-2026]}