WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

ConnesWindow[x]

x のコンヌ(Connes)窓関数を表す．

ConnesWindow[x,α]

パラメータ α を使う．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

ConnesWindow

ConnesWindow[x]

x のコンヌ(Connes)窓関数を表す．

ConnesWindow[x,α]

パラメータ α を使う．

詳細

  • ConnesWindowは，一般に，データを短いセグメントで処理する必要がある信号処理アプリケーションで使われる窓関数はである．
  • 窓関数には，データ値を漸減して各セグメントの終りで0に近付ける平滑化効果がある．
  • ConnesWindow[x,α]は ((alpha^2-4 x^2)^2)/(alpha^4) -1/2<=x<=1/2; 0 TemplateBox[{x}, Abs]>1/2; に等しい．
  • ConnesWindow[x]はConnesWindow[x,1]と等価である．
  • ConnesWindowは自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (3)

1Dコンヌ窓の形：

Wolfram Language code: Plot[ConnesWindow[x], {x, -1, 1}]

2Dコンヌ窓の形：

Wolfram Language code: Plot3D[ConnesWindow[x]ConnesWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

コンヌ窓を表す連続関数を抽出する：

Wolfram Language code: FunctionExpand[ConnesWindow[x]]

パラメータ化されたコンヌ窓：

Wolfram Language code: FunctionExpand[ConnesWindow[x, α]]

スコープ  (6)

数値的に評価する：

Wolfram Language code: ConnesWindow[0.1]

指定されたパラメータを使った1Dコンヌ窓の形：

Wolfram Language code: Plot[ConnesWindow[x, 1.5], {x, -1, 1}, Exclusions -> None]

パラメータ α の関数としての形の変化：

Wolfram Language code: Plot3D[ConnesWindow[x, α], {α, 1, 5}, {x, -1, 1}, Exclusions -> None]

平行移動され広げられたコンヌ窓：

Wolfram Language code: Plot[ConnesWindow[(x - 1) / 2], {x, -1, 3}]

円形の台を持つ2Dコンヌ窓：

Wolfram Language code: Plot3D[ConnesWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

長さ15の離散コンヌ窓：

Wolfram Language code: ListPlot[Array[ConnesWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

15×10の2D離散コンヌ窓：

Wolfram Language code: ListPointPlot3D[Array[ConnesWindow[#1] ConnesWindow[#2]&, {15, 10}, {{-1 / 2, 1 / 2}}], Filling -> Axis]

アプリケーション  (3)

長さ11の移動平均フィルタを作る：

Wolfram Language code: h = ConstantArray[1 / 11., 11]

コンヌ窓を使ってフィルタを漸減させる：

Wolfram Language code: w = Array[ConnesWindow, Length[h], {-1 / 2, 1 / 2}]; fir = h w;

2つのフィルタのパワースペクトルの対数振幅プロット：

Wolfram Language code: LogLinearPlot[Evaluate[20Log[10, Abs@ListFourierSequenceTransform[#, ω]]& /@ {h, fir}], {ω, 0.0314, Pi}, GridLines -> Automatic]

窓指定を使ってサンプルPowerSpectralDensityを計算する：

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

スペクトルを計算する：

Wolfram Language code: spec = PowerSpectralDensity[data, w, ConnesWindow];

窓関数を使わずに計算されたスペクトル密度と比較する：

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

プロットは，窓がスペクトル密度を平坦化したことを示している：

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotRange -> All, PlotLegends -> {"no window", "with window"}]

この過程の理論的なスペクトル密度と比較する：

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

時系列推定に窓指定を使う：

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

スペクトル推定器に窓を指定する：

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> ConnesWindow}]

特性と関係  (2)

コンヌ窓の下の面積：

Wolfram Language code: area = Integrate[ConnesWindow[x], {x, -∞, ∞}]

正規化することで単位面積の窓を作る：

Wolfram Language code: Plot[{ConnesWindow[x], ConnesWindow[x] / area}, {x, -1, 1}]

コンヌ窓のフーリエ変換：

Wolfram Language code: f = FourierTransform[ConnesWindow[x], x, w]

コンヌ窓のパワースペクトル：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 80}]

考えられる問題  (1)

Arrayに記号として渡す場合には，コンヌ窓の2Dサンプリングはサンプルの各行に異なるパラメータを用いる：

Wolfram Language code: Array[ConnesWindow, {30, 30}, {{-1 / 2, 1 / 2}}]//ListPlot3D

代りに純関数を使う：

Wolfram Language code: Array[ConnesWindow[#1] ConnesWindow[#2]&, {30, 30}, {{-1 / 2, 1 / 2}}]//ListPlot3D
Wolfram Research (2012), ConnesWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/ConnesWindow.html.

テキスト

Wolfram Research (2012), ConnesWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/ConnesWindow.html.

CMS

Wolfram Language. 2012. "ConnesWindow." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/ConnesWindow.html.

APA

Wolfram Language. (2012). ConnesWindow. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/ConnesWindow.html

BibTeX

@misc{reference.wolfram_2026_conneswindow, author="Wolfram Research", title="{ConnesWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/ConnesWindow.html}", note=[Accessed: 08-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_conneswindow, organization={Wolfram Research}, title={ConnesWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/ConnesWindow.html}, note=[Accessed: 08-September-2026]}