WOLFRAM

Wolfram 语言与系统参考资料中心

ControllableModelQ[sys]

如果系统 sys 可控，生成 True，否则生成 False.

ControllableModelQ[{sys,sub}]

如果子系统 sub 可控，生成 True.

更多信息和选项
Details and Options Details and Options
范例  
基本范例  
范围  
选项  
Method  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

ControllableModelQ

ControllableModelQ[sys]

如果系统 sys 可控，生成 True，否则生成 False.

ControllableModelQ[{sys,sub}]

如果子系统 sub 可控，生成 True.

更多信息和选项

  • ControllableModelQ 也被称作可到达的模型.
  • 如果对于任意初始状态 和任意最终状态 ，存在某个控制输入能在有限时间内驱动状态从 到 ，则称该状态空间模型是可控的.
  • 系统 sys 可以是一个标准或描述符 StateSpaceModel 或 AffineStateSpaceModel.
  • 可以指定下列子系统 sub： » »
  • All整个系统
    "Fast"快变子系统
    "Slow"慢变子系统
    {λ1,…}具有本征模 的子系统
  • "Fast" 和 "Slow" 子系统主要应用于 KroneckerModelDecomposition 中所介绍的描述符状态空间模型.
  • 本征模 λi 在 JordanModelDecomposition 中有介绍.
  • ControllableModelQ 接受具有以下设置的 Method 选项：
  • Automatic自动选择适当的测试
    "Distribution"使用可控性分布的秩
    "Gramian"使用可控性格拉姆矩阵的秩或正的确定性
    "Matrix"使用可控性矩阵的秩
    "PBH"使用 Popov–Belevitch–Hautus 秩测试

范例

打开所有单元 关闭所有单元

基本范例  (2)

一个可控系统：

Wolfram Language code: ControllableModelQ[StateSpaceModel[{{{Subscript[a, 1], 0}, {0, Subscript[a, 2]}}, {{Subscript[b, 1]}, {Subscript[b, 2]}}, {{1, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

一个不可控系统，原因是无法影响第二个状态：

Wolfram Language code: ControllableModelQ[StateSpaceModel[{{{Subscript[a, 1], 0}, {0, Subscript[a, 2]}}, {{Subscript[b, 1]}, {0}}, {{1, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

范围  (6)

测试带有近似系数的系统的可控性：

Wolfram Language code: ControllableModelQ[StateSpaceModel[{{{-5., -2.}, {6., 2.}}, {{1.}, {-1.}}, {{1., 1.}}, {{0.}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

精确的系数：

Wolfram Language code: ControllableModelQ[StateSpaceModel[{{{-5, -2}, {6, 2}}, {{1}, {-1}}, {{1, 1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

符号式系数：

Wolfram Language code: ControllableModelQ[StateSpaceModel[{{{0, (-p)*z}, {1, -p - z}}, {{z}, {1}}, {{0, 1}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

多输入系统：

Wolfram Language code: ControllableModelQ[StateSpaceModel[{{{-1, 0}, {0, -3}}, {{1, 0}, {0, 1}}, {{1, -2}}, {{0, 2}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

离散时间系统：

Wolfram Language code: ControllableModelQ[StateSpaceModel[{{{0, 1}, {-0.4, -1}}, {{0}, {1}}, {{0.68, 1.7}}, {{0}}}, SamplingPeriod -> 0.1, SystemsModelLabels -> None]]

描述符系统：

Wolfram Language code: ssm = StateSpaceModel[{{{-1, 0, 1}, {-2, 2, 2}, {0, 0, 0}}, {{0}, {1}, {1}}, {{4, 0, -3}}, {{0}}, {{-2, 2, 2}, {0, 0, 0}, {1, 2, 0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: ControllableModelQ[ssm]

可控性等同于慢速和快速模式的可控性（C-可控性）：

Wolfram Language code: {ControllableModelQ[{ssm, "Slow"}], ControllableModelQ[{ssm, "Fast"}]}

检测单个本征模式的可控性：

Wolfram Language code: ssm = StateSpaceModel[{{{-28, 40, 50}, {2, -6, -4}, {-15, 24, 27}}, {{-8}, {1}, {-5}}, {{1, -4, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];

由于本征模式为 ，所以系统是不可控的：

Wolfram Language code: modes = Eigenvalues[First[Normal[ssm]]]
Wolfram Language code: Table[{λ, ControllableModelQ[{ssm, λ}]}, {λ, modes}]

这可以在约当式中看到，其中无法影响第三个状态：

Wolfram Language code: JordanModelDecomposition[ssm]//Last

检验 AffineStateSpaceModel 的可控性：

Wolfram Language code: ControllableModelQ[AffineStateSpaceModel[{{Subscript[x, 2], 0}, {{0}, {Subscript[x, 1]}}}, {Subscript[x, 1], Subscript[x, 2]}, Automatic, {Automatic, Automatic}, Automatic, SamplingPeriod -> None]]

如果给出操作点 ，则测验的是 的可控性：

Wolfram Language code: ControllableModelQ[AffineStateSpaceModel[{{Subscript[x, 1], Subscript[x, 2]}, {{Subscript[x, 1]}, {1}}}, {{Subscript[x, 1], 0}, {Subscript[x, 2], 0}}, Automatic, {Automatic, Automatic}, Automatic, SamplingPeriod -> None, SystemsModelLabels -> {None, {}, None}]]

系统对一个通用点而言是可控的：

Wolfram Language code: ControllableModelQ[AffineStateSpaceModel[{{Subscript[x, 1], Subscript[x, 2]}, {{Subscript[x, 1]}, {1}}}, {Subscript[x, 1], Subscript[x, 2]}, Automatic, {Automatic, Automatic}, Automatic, SamplingPeriod -> None]]

选项  (7)

Method  (7)

默认情况下，可控性矩阵用于精确和符号系统：

Wolfram Language code: ssm = StateSpaceModel[{{{-1, 4}, {2, 3}}, {{1}, {0}}, {{1, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: ControllableModelQ[ssm, Method -> "Matrix"]

如果 ControllabilityMatrix 满秩，则系统是可控的：

Wolfram Language code: cm = ControllabilityMatrix[ssm];
Wolfram Language code: MatrixRank[cm]

可控性格拉姆矩阵用于稳定的数值系统：

Wolfram Language code: ssm = StateSpaceModel[{{{0, 1., 0}, {0, 0, 1.}, {-1., -3., -5.}}, {{0}, {0}, {1.}}, {{1., 0, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: ControllableModelQ[ssm, Method -> "Gramian"]

如果 ControllabilityGramian 满秩，则系统是可控的：

Wolfram Language code: cg = ControllabilityGramian[ssm];
Wolfram Language code: MatrixRank[cg]

对于可控性格拉姆矩阵，这相当于它是正定的：

Wolfram Language code: PositiveDefiniteMatrixQ[cg]

PBH 秩检验用于所有其他数值系统：

Wolfram Language code: ssm = StateSpaceModel[{{{-0.8, 0.2}, {-0.2, 0}}, {{0.5}, {0.01}}, {{1, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: ControllableModelQ[ssm, Method -> "PBH"]

由于 对于所有 是满秩的，所以系统是可控的：

Wolfram Language code: {a, b} = Normal[ssm][[{1, 2}]];
Wolfram Language code: MatrixRank /@ Table[ArrayFlatten[{{λ IdentityMatrix[2] - a, b}}], {λ, Eigenvalues[a]}]

可控性分布用于输入线性系统：

Wolfram Language code: ControllableModelQ[AffineStateSpaceModel[{{0, Subscript[x, 1]}, {{1 + Subscript[x, 1]}, {0}}}, {Subscript[x, 1], Subscript[x, 2]}, Automatic, {Automatic, Automatic}, Automatic, SamplingPeriod -> None], Method -> "Distribution"]

对于线性系统，基于可控性矩阵和分布的检验是等价的：

Wolfram Language code: Table[ControllableModelQ[AffineStateSpaceModel[{{Subscript[x, 1] + Subscript[x, 2], -Subscript[x, 1]}, {{1}, {0}}}, {Subscript[x, 1], Subscript[x, 2]}, {Subscript[, 1]}, {Automatic, Automatic}, Automatic, SamplingPeriod -> None], Method -> m], {m, {"Matrix", "Distribution"}}]

线性化系统的可控性意味着输入线性系统的可控性：

Wolfram Language code: asys = AffineStateSpaceModel[{{Subscript[x, 1] + Subscript[x, 2], (-Subscript[x, 1])*Subscript[x, 2]}, {{Subscript[x, 2]}, {1}}}, {Subscript[x, 1], Subscript[x, 2]}, Automatic, {Automatic, Automatic}, Automatic, SamplingPeriod -> None];
Wolfram Language code: lsys = StateSpaceModel[asys];
Wolfram Language code: {ControllableModelQ[asys], ControllableModelQ[lsys]}

对于线性化系统，输入线性系统的矩阵检验使用 "Matrix" 方法：

Wolfram Language code: ControllableModelQ[asys, Method -> "Matrix"]

使用无控制输入，系统服从漂移矢量场 ：

Wolfram Language code: asys = AffineStateSpaceModel[{{-14*Subscript[x, 3], 0, -19*Subscript[x, 3]}, {{Subscript[x, 1] + 2*Subscript[x, 2] + 4*Subscript[x, 3]}, {2*Subscript[x, 2]}, {3*Subscript[x, 3]}}}, {Subscript[x, 1], Subscript[x, 2], Subscript[x, 3]}, Automatic, {Automatic, Automatic, Automatic}, Automatic, SamplingPeriod -> None];

如果漂移矢量场也可以用于移动状态：则系统是弱可控的：

Wolfram Language code: ControllableModelQ[asys, Method -> {"Distribution", "DriftVectorField" -> True}]

如果不包括漂移矢量场，该系统是不可控的：

Wolfram Language code: ControllableModelQ[asys]

应用  (5)

所有三个质量的位置和速度都可以由施加在 的力控制：

Wolfram Language code: ControllableModelQ[StateSpaceModel[{{{0, 1, 0, 0, 0, 0}, {-(Subscript[k, 1] + Subscript[k, 2])/Subscript[m, 1], 0, Subscript[k, 2]/Subscript[m, 1], 0, 0, 0}, {0, 0, 0, 1, 0, 0}, {Subscript[k, 2]/Subscript[m, 2], 0, -(Subscript[k, 2] + Subscript[k, 3])/Subscript[m, 2], 0, Subscript[k, 3]/Subscript[m, 2], 0}, {0, 0, 0, 0, 0, 1}, {0, 0, Subscript[k, 3]/Subscript[m, 3], 0, -Subscript[k, 3]/Subscript[m, 3], 0}}, {{0}, {0}, {0}, {0}, {0}, {Subscript[m, 3]^(-1)}}, {{1, 0, 0, 0, 0, 0}, {0, 0, 1, 0, 0, 0}}, {{0}, {0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

以电容器电压和电感电流作为状态的电路：

Wolfram Language code: ssm = StateSpaceModel[{{{-𝒞^(-1)/Subscript[R, 1], 0}, {0, (-L^(-1))*Subscript[R, 2]}}, {{1/(𝒞*Subscript[R, 1])}, {L^(-1)}}}, SamplingPeriod -> None, SystemsModelLabels -> None];

在一般情况下，该系统是可控的：

Wolfram Language code: ControllableModelQ[ssm]

然而，如果 ，该系统是不可控的：

Wolfram Language code: ControllableModelQ[ssm /. L -> Subscript[R, 1] Subscript[R, 2]𝒞]

用驱动和转向作为输入的独轮车：

Wolfram Language code: asys = AffineStateSpaceModel[{{0, 0, 0}, {{Cos[θ], 0}, {Sin[θ], 0}, {0, 1}}}, {x, y, θ}, Automatic, {Automatic, Automatic, Automatic}, Automatic, SamplingPeriod -> None];

该系统是可控的，但线性化的系统不是：

Wolfram Language code: {ControllableModelQ[asys], ControllableModelQ[StateSpaceModel@asys]}

停车问题：

Wolfram Language code: veh = AffineStateSpaceModel[{{0, 0, 0, 0}, {{Cos[θ + ϕ], 0}, {Sin[θ + ϕ], 0}, {Sin[θ], 0}, {0, 1}}}, {x, y, ϕ, θ}, Automatic, {Automatic, Automatic, Automatic, Automatic}, Automatic, SamplingPeriod -> None];

该系统是可控的，但线性化的系统不是：

Wolfram Language code: {ControllableModelQ[veh], ControllableModelQ[StateSpaceModel@veh]}

一个旋转的刚性卫星，使用欧拉运动方程建模：

Wolfram Language code: sat[j1_, j2_, j3_] := AffineStateSpaceModel[{{((j2 - j3)*Subscript[ω, 2]* Subscript[ω, 3])/j1, ((-j1 + j3)*Subscript[ω, 1]* Subscript[ω, 3])/j2, ((j1 - j2)*Subscript[ω, 1]* Subscript[ω, 2])/j3}, {{j1^(-1), 0, 0}, {0, j2^(-1), 0}, {0, 0, j3^(-1)}}}, {Subscript[ω, 1], Subscript[ω, 2], Subscript[ω, 3]}, {Subscript[τ, 1], Subscript[τ, 2], Subscript[τ, 3]}, {Automatic, Automatic, Automatic}, Automatic, SamplingPeriod -> None]

在主矩和促动器组合取不同值时的可控性：

Wolfram Language code: controllableQ[j1_, j2_, j3_] := Table[{i, ControllableModelQ[SystemsModelExtract[sat[j1, j2, j3], i]]}, {i, Subsets[Range[3], {1, 3}]}]

用网格显示结果：

Wolfram Language code: grid[res_, color_] := Grid[res, Background -> {None, {{color, None}}}, Frame -> True]

如果 ，带有任意两个促动器的系统是可控的：

Wolfram Language code: Grid[controllableQ[Subscript[J, 1], Subscript[J, 2], Subscript[J, 3]], Frame -> All]

如果 ，带有促动器1和2或带有任意一个促动器的系统是不可控的：

Wolfram Language code: Grid[controllableQ[Subscript[J, 1], Subscript[J, 1], Subscript[J, 3]], Frame -> All]

如果 ，系统仅在三个促动器都存在的情况下是可控的：

Wolfram Language code: Grid[controllableQ[Subscript[J, 1], Subscript[J, 1], Subscript[J, 1]], Frame -> All]

属性和关系  (7)

对角线系统是可控的，假定 且：

Wolfram Language code: ControllableModelQ[StateSpaceModel[{{{Subscript[λ, 1], 0}, {0, Subscript[λ, 2]}}, {{Subscript[b, 1]}, {Subscript[b, 2]}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

如果 ，第一个状态是无法控制的：

Wolfram Language code: ControllableModelQ[StateSpaceModel[{{{Subscript[λ, 1], 0}, {0, Subscript[λ, 2]}}, {{0}, {Subscript[b, 2]}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

如果 ， 第一个状态无法直接控制，但可以从第二个状态间接控制：

Wolfram Language code: ControllableModelQ[StateSpaceModel[{{{Subscript[λ, 1], 1}, {0, Subscript[λ, 1]}}, {{0}, {Subscript[b, 2]}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

如果 ，第二个状态无法直接控制，也不能从第一个状态间接控制：

Wolfram Language code: ControllableModelQ[StateSpaceModel[{{{Subscript[λ, 1], 1}, {0, Subscript[λ, 1]}}, {{Subscript[b, 1]}, {0}}}, SamplingPeriod -> None, SystemsModelLabels -> None]]

使用 JordanModelDecomposition 计算上面的典型状态空间表示：

Wolfram Language code: ssm = StateSpaceModel[{{{4, 1}, {-1, 2}}, {{-6}, {3}}, {{-4, -2}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: JordanModelDecomposition[ssm]//Last

使用 "PBH" 检验计算每个模式的可控性：

Wolfram Language code: Table[{λ, ControllableModelQ[{ssm, λ}]}, {λ, {3}}]

对于描述符系统，KroneckerModelDecomposition 是对角形式的推广：

Wolfram Language code: ssm = StateSpaceModel[{{{-5, -1, -3}, {-3, 1, -3}, {-6, -2, -2}}, {{2}, {1}, {2}}, {{1, 1, 1}}, {{0}}, {{3, 1, 2}, {4, 0, 2}, {1, 1, 1}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: kssm = Last[KroneckerModelDecomposition[ssm]]

从结构确定慢变子系统的可控性：

Wolfram Language code: SystemsModelExtract[kssm, All, All, {1, 2}]

使用原始系统计算它：

Wolfram Language code: ControllableModelQ[{ssm, "Slow"}]

确定快变子系统的可控性：

Wolfram Language code: SystemsModelExtract[kssm, All, All, {3}]

使用原始系统计算它：

Wolfram Language code: ControllableModelQ[{ssm, "Fast"}]

如果 StateSpaceModel 的描述符矩阵是满秩的，则没有快变子系统：

Wolfram Language code: ssm = StateSpaceModel[{{{-2, -2}, {8, 12}}, {{1}, {2}}, {{1, 1}}, {{0}}, {{1, 1}, {2, 3}}}, SamplingPeriod -> None, SystemsModelLabels -> None];

因此，该系统的完全可控性可以从慢变子系统进行计算：

Wolfram Language code: {ControllableModelQ[ssm], ControllableModelQ[{ssm, All}], ControllableModelQ[{ssm, "Slow"}]}

在非奇异 StateSpaceTransform 下，可控性是不变的：

Wolfram Language code: ssm = StateSpaceModel[{{{Subscript[λ, 1], 1}, {0, Subscript[λ, 1]}}, {{Subscript[b, 1]}, {0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: p = Array[Subscript[t, ##]&, {2, 2}];
Wolfram Language code: ControllableModelQ /@ {ssm, StateSpaceTransform[ssm, p]}

可控性在状态反馈下不变：

Wolfram Language code: ssm = StateSpaceModel[{{{3, 0}, {5, -2}}, {{-1}, {0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: ControllableModelQ[ssm]

使用 StateFeedbackGains 计算状态反馈：

Wolfram Language code: κ = StateFeedbackGains[ssm, {-4, -5}]

闭环系统也是可控的：

Wolfram Language code: SystemsModelStateFeedbackConnect[ssm, κ];
Wolfram Language code: ControllableModelQ[%]

可控性并不意味着它是输出可控 (OutputControllableModelQ)：

Wolfram Language code: ssm = StateSpaceModel[{{{-1.75, 0.5}, {0.375, -1.25}}, {{0}, {4}}, {{0.125, 0.25}, {0.25, 0.5}}, {{0}, {0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: {ControllableModelQ[ssm], OutputControllableModelQ[ssm]}

输出可控性并不意味着可控性：

Wolfram Language code: ssm = StateSpaceModel[{{{-1, 0, 0}, {0, -2, 0}, {0, 0, -4}}, {{1}, {0}, {-1}}, {{1, 0, 0}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: {ControllableModelQ[ssm], OutputControllableModelQ[ssm]}

可能存在的问题  (2)

对于非渐近稳定的系统，格兰姆方法是不可靠的：

Wolfram Language code: ssm = StateSpaceModel[{{{-5/2, -1, -1/4}, {3/4, 1/2, -3/8}, {-6, -8, 0}}, {{0}, {1/2}, {6}}, {{1/4, 3/2, -1/8}}, {{0}}}, SamplingPeriod -> None, SystemsModelLabels -> None];
Wolfram Language code: Table[ControllableModelQ[ssm, Method -> m], {m, {"Gramian", "Matrix", "PBH"}}]

复平面右半部分的特征值导致连续时间系统的不稳定性：

Wolfram Language code: Eigenvalues@First@Normal@ssm

对于非零漂移的仿射系统，分布仅测试可访问性：

Wolfram Language code: asys = AffineStateSpaceModel[{{Subscript[x, 2]^2, 0}, {{0}, {Subscript[x, 1]}}}, {Subscript[x, 1], Subscript[x, 2]}, Automatic, {Automatic, Automatic}, Automatic, SamplingPeriod -> None];
Wolfram Language code: ControllableModelQ[asys]

随机初始条件和随机输入信号发生器：

Wolfram Language code: ic = RandomReal[{-2, 2}, 2];u[t_] := Interpolation[Transpose[{Range[0, 1, 0.1], RandomReal[{-1, 1}, 11]}], t]

模拟具有初始输入的系统10次：

Wolfram Language code: Table[StateResponse[{asys, ic}, u[t], {t, 0, 1}], {10}];

该系统不能被移到初始点的左边：

Wolfram Language code: ParametricPlot[%, {t, 0, 1}, PlotRange -> All, AspectRatio -> 1 / GoldenRatio]
Wolfram Research (2010)，ControllableModelQ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ControllableModelQ.html （更新于 2014 年）.

文本

Wolfram Research (2010)，ControllableModelQ，Wolfram 语言函数，https://reference.wolfram.com/language/ref/ControllableModelQ.html （更新于 2014 年）.

CMS

Wolfram 语言. 2010. "ControllableModelQ." Wolfram 语言与系统参考资料中心. Wolfram Research. 最新版本 2014. https://reference.wolfram.com/language/ref/ControllableModelQ.html.

APA

Wolfram 语言. (2010). ControllableModelQ. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/ControllableModelQ.html 年

BibTeX

@misc{reference.wolfram_2026_controllablemodelq, author="Wolfram Research", title="{ControllableModelQ}", year="2014", howpublished="\url{https://reference.wolfram.com/language/ref/ControllableModelQ.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_controllablemodelq, organization={Wolfram Research}, title={ControllableModelQ}, year={2014}, url={https://reference.wolfram.com/language/ref/ControllableModelQ.html}, note=[Accessed: 10-September-2026]}