WOLFRAM

Wolfram 语言与系统参考资料中心

CoordinateBoundingBoxArray[{{xmin,ymin,…},{xmax,ymax,…}}]

生成形如 {x,y,…} 的一组坐标的阵列，在每个维度上的相互间隔都是整数.

CoordinateBoundingBoxArray[{min,max},d]

在每个维度使用步长 d.

CoordinateBoundingBoxArray[{min,max},{dx,dy,…}]

在各个维度分别使用步长 dx, dy, ….

CoordinateBoundingBoxArray[{min,max},Into[n]]

把每个维度划分为 n 个相等的步长.

CoordinateBoundingBoxArray[{min,max},steps,offsets]

指定用于每个坐标点的偏移量.

CoordinateBoundingBoxArray[{min,max},steps,offsets,k]

把阵列在每个方向都扩展 k 个元素.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
属性和关系  
参见
相关指南
历史
按以下格式引用：

CoordinateBoundingBoxArray

CoordinateBoundingBoxArray[{{xmin,ymin,…},{xmax,ymax,…}}]

生成形如 {x,y,…} 的一组坐标的阵列，在每个维度上的相互间隔都是整数.

CoordinateBoundingBoxArray[{min,max},d]

在每个维度使用步长 d.

CoordinateBoundingBoxArray[{min,max},{dx,dy,…}]

在各个维度分别使用步长 dx, dy, ….

CoordinateBoundingBoxArray[{min,max},Into[n]]

把每个维度划分为 n 个相等的步长.

CoordinateBoundingBoxArray[{min,max},steps,offsets]

指定用于每个坐标点的偏移量.

CoordinateBoundingBoxArray[{min,max},steps,offsets,k]

把阵列在每个方向都扩展 k 个元素.

更多信息

  • CoordinateBoundingBoxArray 给出了规则点格中的坐标阵列.
  • 在默认情况下，每个方向上的值序列都从最小值开始，在相应的方向重复加上步长直至达到最大值.
  • 当没有指定偏移量时，坐标直接对应值序列.
  • 偏移量可以以绝对距离的形式给出，或使用 Scaled. Scaled[1/2] 能把坐标点置于每个“晶胞”的中心.
  • CoordinateBoundingBoxArray 中的值可以是 Quantity 对象.

范例

打开所有单元 关闭所有单元

基本范例  (3)

2维点的网格：

Wolfram Language code: CoordinateBoundingBoxArray[{{3, -1}, {8, 2}}]
Wolfram Language code: Graphics[Point[Flatten[%, 1]], Frame -> True]

指定离散化步长的三维点阵列：

Wolfram Language code: CoordinateBoundingBoxArray[{{3, -1, 0}, {6, 2, Pi}}, {0.7, 1.5, Pi / 2.}]
Wolfram Language code: Graphics3D[Point[Flatten[%, 2]]]

返回网格晶胞的中心点：

Wolfram Language code: bounds = {{3, 8}, {-1, 2}};
Wolfram Language code: CoordinateBoundingBoxArray[Transpose[bounds], 1, Center]
Wolfram Language code: Graphics[Point[Flatten[%, 1]], Frame -> True, GridLines -> Range@@@bounds, PlotRange -> bounds]

范围  (6)

提供了坐标阵列的角落位置，采用默认的离散化值、偏移量和填充值：

Wolfram Language code: CoordinateBoundingBoxArray[{{3, -1, 0}, {8, 2, 2}}]

为所有维度指定公共的离散化步长：

Wolfram Language code: CoordinateBoundingBoxArray[{{3, -2}, {9, 2}}, 2]

为不同维度指定各自晶胞的大小：

Wolfram Language code: CoordinateBoundingBoxArray[{{3, -2}, {9, 2}}, {2, 0.5}]

以 Quantity 对象作为参数：

Wolfram Language code: CoordinateBoundingBoxArray[{{Quantity[3, "Meters"], Quantity[-2, "Seconds"]}, {Quantity[9, "Meters"], Quantity[2, "Seconds"]}}, {Quantity[4., "Feet"], Quantity[0.5, "Seconds"]}]
Wolfram Language code: Normal[%]

返回网格晶胞的中心点：

Wolfram Language code: corners = {{6, -2}, {16, 4}};
Wolfram Language code: CoordinateBoundingBoxArray[corners, 2, Center]
Wolfram Language code: Graphics[Point[Flatten[%, 1]], Frame -> True, GridLines -> {Range[6, 16, 2], Range[-2, 4, 2]}, PlotRange -> Transpose[corners]]

数值偏移量被解释为绝对偏移量：

Wolfram Language code: CoordinateBoundingBoxArray[corners, 2, {0.5, 1.8}]
Wolfram Language code: Graphics[Point[Flatten[%, 1]], Frame -> True, GridLines -> {Range[6, 16, 2], Range[-2, 4, 2]}, PlotRange -> Transpose[corners]]

用 Scaled 指定相对偏移量：

Wolfram Language code: CoordinateBoundingBoxArray[corners, 2, {Scaled[0.25], Scaled[0.9]}]

返回额外的点层或移除它们中的部分：

Wolfram Language code: corners = {{3, -1}, {8, 2}};
Wolfram Language code: CoordinateBoundingBoxArray[corners, 1, Center, {{-1, 3}, {2, 1}}]
Wolfram Language code: Graphics[Point[Flatten[%, 1]], Frame -> True, GridLines -> Range@@@Transpose[corners], PlotRange -> {{-1, 12}, {-5, 6}}]

指定分划数：

Wolfram Language code: CoordinateBoundingBoxArray[{{3, -1}, {8, 2}}, {Into[3], Into[2]}]
Wolfram Language code: Most[Dimensions[%]] - 1

属性和关系  (4)

CoordinateBoundingBox 返回 0 偏移量的角落位置：

Wolfram Language code: CoordinateBoundingBoxArray[{{3, -1}, {8, 2}}]
Wolfram Language code: CoordinateBoundingBox[%]

使用其它偏移量结果完全不同：

Wolfram Language code: CoordinateBoundingBoxArray[{{3, -1}, {8, 2}}, 1, Center]
Wolfram Language code: CoordinateBoundingBox[%]

CoordinateBoundsArray 使用范围列表代替角落位置：

Wolfram Language code: CoordinateBoundsArray[{{3, 8}, {-1, 2}, {2, 4}}]
Wolfram Language code: % === CoordinateBoundingBoxArray[{{3, -1, 2}, {8, 2, 4}}]

CoordinateBoundingBoxArray 可以返回坐标列表的阵列，即使在只有一维的情况下：

Wolfram Language code: CoordinateBoundingBoxArray[{{0}, {10}}, 2]

Range 可以返回那些单独坐标的列表：

Wolfram Language code: Range[0, 10, 2]

CoordinateBoundingBoxArray 用 Into 指定分划数目：

Wolfram Language code: CoordinateBoundingBoxArray[{{0}, {10}}, Into[5]]

Subdivide 可以返回那些单独坐标的列表：

Wolfram Language code: Subdivide[0, 10, 5]
Wolfram Research (2015)，CoordinateBoundingBoxArray，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoordinateBoundingBoxArray.html.

文本

Wolfram Research (2015)，CoordinateBoundingBoxArray，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoordinateBoundingBoxArray.html.

CMS

Wolfram 语言. 2015. "CoordinateBoundingBoxArray." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CoordinateBoundingBoxArray.html.

APA

Wolfram 语言. (2015). CoordinateBoundingBoxArray. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CoordinateBoundingBoxArray.html 年

BibTeX

@misc{reference.wolfram_2026_coordinateboundingboxarray, author="Wolfram Research", title="{CoordinateBoundingBoxArray}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/CoordinateBoundingBoxArray.html}", note=[Accessed: 16-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coordinateboundingboxarray, organization={Wolfram Research}, title={CoordinateBoundingBoxArray}, year={2015}, url={https://reference.wolfram.com/language/ref/CoordinateBoundingBoxArray.html}, note=[Accessed: 16-September-2026]}