WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CoordinateBoundsArray[{{xmin,xmax},{ymin,ymax},…}]

各次元で整数ステップの{x,y,…}座標の配列を生成する．

CoordinateBoundsArray[{xrange,yrange,…},d]

各次元にステップ d を使う．

CoordinateBoundsArray[{xrange,yrange,…},{dx,dy,…}]

連続する次元にステップ dx，dy，…を使う．

CoordinateBoundsArray[{xrange,yrange,…},Into[n]]

各次元で n 個の等間隔ステップに分割する．

CoordinateBoundsArray[{xrange,yrange,…},steps,offsets]

各座標点に使用するオフセットを指定する．

CoordinateBoundsArray[{xrange,yrange,…},steps,offsets,k]

配列を全方向に k 要素分拡張する．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
関連項目
関連するガイド
履歴
引用書式

CoordinateBoundsArray

CoordinateBoundsArray[{{xmin,xmax},{ymin,ymax},…}]

各次元で整数ステップの{x,y,…}座標の配列を生成する．

CoordinateBoundsArray[{xrange,yrange,…},d]

各次元にステップ d を使う．

CoordinateBoundsArray[{xrange,yrange,…},{dx,dy,…}]

連続する次元にステップ dx，dy，…を使う．

CoordinateBoundsArray[{xrange,yrange,…},Into[n]]

各次元で n 個の等間隔ステップに分割する．

CoordinateBoundsArray[{xrange,yrange,…},steps,offsets]

各座標点に使用するオフセットを指定する．

CoordinateBoundsArray[{xrange,yrange,…},steps,offsets,k]

配列を全方向に k 要素分拡張する．

詳細

  • CoordinateBoundsArrayは，正則格子上の点についての座標の配列を与える．
  • デフォルトの場合，各方向に選ばれる値の列は，最小値から始め最大値に達するまでその方向に対応するステップを繰り返し足すことで得られる．
  • オフセットが指定されていない場合，座標は値の列に直接対応する．
  • オフセットは絶対距離によって，あるいはScaledを使って与えることができる．Scaled[1/2]は，座標点を各「セル」の中心に置く．
  • CoordinateBoundsArrayにおける値はQuantityオブジェクトでよい．

例題

すべて開く すべて閉じる

例  (3)

二次元の点格子：

Wolfram Language code: CoordinateBoundsArray[{{3, 8}, {-1, 2}}]
Wolfram Language code: Graphics[Point[Flatten[%, 1]], Frame -> True]

指定された離散化ステップによる，3Dの点の配列：

Wolfram Language code: CoordinateBoundsArray[{{3, 6}, {-1, 2}, {0, Pi}}, {0.7, 1.5, Pi / 2.}]
Wolfram Language code: Graphics3D[Point[Flatten[%, 2]]]

格子のセルの中心点を返す：

Wolfram Language code: bounds = {{3, 8}, {-1, 2}};
Wolfram Language code: CoordinateBoundsArray[bounds, 1, Center]
Wolfram Language code: Graphics[Point[Flatten[%, 1]], Frame -> True, GridLines -> Range@@@bounds, PlotRange -> bounds]

スコープ  (6)

デフォルトの離散化，オフセット，充填で，座標配列の境界を与える：

Wolfram Language code: CoordinateBoundsArray[{{3, 8}, {-1, 2}, {0, 2}}]

すべての次元に共通の離散化ステップを指定する：

Wolfram Language code: CoordinateBoundsArray[{{3, 9}, {-2, 2}}, 2]

各次元にそれぞれのセルサイズを指定する：

Wolfram Language code: CoordinateBoundsArray[{{3, 9}, {-2, 2}}, {2, 0.5}]

引数をQuantityオブジェクトとして与える：

Wolfram Language code: CoordinateBoundsArray[{Quantity[{3, 9}, "Meters"], Quantity[{-2, 2}, "Seconds"]}, {Quantity[4., "Feet"], Quantity[0.5, "Seconds"]}]
Wolfram Language code: Normal[%]

格子のセルの中心点を返す：

Wolfram Language code: bounds = {{6, 16}, {-2, 4}};
Wolfram Language code: CoordinateBoundsArray[bounds, 2, Center]
Wolfram Language code: Graphics[Point[Flatten[%, 1]], Frame -> True, GridLines -> {Range[6, 16, 2], Range[-2, 4, 2]}, PlotRange -> bounds]

数値オフセットは絶対であると解釈される：

Wolfram Language code: CoordinateBoundsArray[bounds, 2, {0.5, 1.8}]
Wolfram Language code: Graphics[Point[Flatten[%, 1]], Frame -> True, GridLines -> {Range[6, 16, 2], Range[-2, 4, 2]}, PlotRange -> bounds]

Scaledを使って任意の相対的オフセットを指定する：

Wolfram Language code: CoordinateBoundsArray[bounds, 2, {Scaled[0.25], Scaled[0.9]}]

追加的な点の層を返すか，そのうちのいくつかを除くかする：

Wolfram Language code: bounds = {{3, 8}, {-1, 2}};
Wolfram Language code: CoordinateBoundsArray[bounds, 1, Center, {{-1, 3}, {2, 1}}]
Wolfram Language code: Graphics[Point[Flatten[%, 1]], Frame -> True, GridLines -> Range@@@bounds, PlotRange -> {{-1, 12}, {-5, 6}}]

下位区分の数を指定する：

Wolfram Language code: CoordinateBoundsArray[{{3, 8}, {-1, 2}}, {Into[3], Into[2]}]
Wolfram Language code: Most[Dimensions[%]] - 1

アプリケーション  (1)

アメリカ合衆国の境界の経緯度を計算する：

Wolfram Language code: bounds = GeoBounds[Entity["Country", "UnitedStates"]]

CoordinateBoundsArrayを使ってステップ2度で座標配列を生成する：

Wolfram Language code: pos = GeoPosition[CoordinateBoundsArray[bounds, 2]]

これらの座標を地理の地図上にプロットする：

Wolfram Language code: GeoGraphics[{Point[pos], GeoBoundsRegion[bounds]}, GeoGridLines -> Automatic]

点を円筒図法でプロットする：

Wolfram Language code: Show[%, GeoProjection -> "Mercator"]

特性と関係  (4)

CoordinateBoundsは，0オフセットについての入力境界を返す：

Wolfram Language code: CoordinateBoundsArray[{{3, 8}, {-1, 2}}]
Wolfram Language code: CoordinateBounds[%]

他のオフセットでは，結果は異なる：

Wolfram Language code: CoordinateBoundsArray[{{3, 8}, {-1, 2}}, 1, Center]
Wolfram Language code: CoordinateBounds[%]

CoordinateBoundingBoxArrayは，範囲のリストではなくコーナー位置表記を使う：

Wolfram Language code: CoordinateBoundingBoxArray[{{3, -1, 2}, {8, 2, 4}}]
Wolfram Language code: % === CoordinateBoundsArray[{{3, 8}, {-1, 2}, {2, 4}}]

CoordinateBoundsArrayは，たとえ一次元であっても，座標のリストの配列を返す：

Wolfram Language code: CoordinateBoundsArray[{{0, 10}}, 2]

Rangeはそれら個別の座標のリストを返す：

Wolfram Language code: Range[0, 10, 2]

CoordinateBoundsArrayはIntoを使って下位区分の数を指定する：

Wolfram Language code: CoordinateBoundsArray[{{0, 10}}, Into[5]]

Subdivideは，それら個別の座標のリストを返す：

Wolfram Language code: Subdivide[0, 10, 5]
Wolfram Research (2015), CoordinateBoundsArray, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoordinateBoundsArray.html.

テキスト

Wolfram Research (2015), CoordinateBoundsArray, Wolfram言語関数， https://reference.wolfram.com/language/ref/CoordinateBoundsArray.html.

CMS

Wolfram Language. 2015. "CoordinateBoundsArray." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CoordinateBoundsArray.html.

APA

Wolfram Language. (2015). CoordinateBoundsArray. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CoordinateBoundsArray.html

BibTeX

@misc{reference.wolfram_2026_coordinateboundsarray, author="Wolfram Research", title="{CoordinateBoundsArray}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/CoordinateBoundsArray.html}", note=[Accessed: 04-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coordinateboundsarray, organization={Wolfram Research}, title={CoordinateBoundsArray}, year={2015}, url={https://reference.wolfram.com/language/ref/CoordinateBoundsArray.html}, note=[Accessed: 04-September-2026]}