WOLFRAM

Wolfram 语言与系统参考资料中心

CoordinateBoundsArray[{{xmin,xmax},{ymin,ymax},…}]

生成形如 {x,y,…} 的一组坐标的阵列，在每个维度上的相互间隔都是整数.

CoordinateBoundsArray[{xrange,yrange,…},d]

在每个维度使用步长 d.

CoordinateBoundsArray[{xrange,yrange,…},{dx,dy,…}]

在各个维度分别使用步长 dx, dy, ….

CoordinateBoundsArray[{xrange,yrange,…},Into[n]]

把每个维度划分为 n 个相等的步长.

CoordinateBoundsArray[{xrange,yrange,…},steps,offsets]

指定用于每个坐标点的偏移量.

CoordinateBoundsArray[{xrange,yrange,…},steps,offsets,k]

把阵列在每个方向都扩展 k 个元素.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
参见
相关指南
历史
按以下格式引用：

CoordinateBoundsArray

CoordinateBoundsArray[{{xmin,xmax},{ymin,ymax},…}]

生成形如 {x,y,…} 的一组坐标的阵列，在每个维度上的相互间隔都是整数.

CoordinateBoundsArray[{xrange,yrange,…},d]

在每个维度使用步长 d.

CoordinateBoundsArray[{xrange,yrange,…},{dx,dy,…}]

在各个维度分别使用步长 dx, dy, ….

CoordinateBoundsArray[{xrange,yrange,…},Into[n]]

把每个维度划分为 n 个相等的步长.

CoordinateBoundsArray[{xrange,yrange,…},steps,offsets]

指定用于每个坐标点的偏移量.

CoordinateBoundsArray[{xrange,yrange,…},steps,offsets,k]

把阵列在每个方向都扩展 k 个元素.

更多信息

  • CoordinateBoundsArray 给出了规则点格中的坐标阵列.
  • 在默认情况下，每个方向上的值序列都从最小值开始，在相应的方向重复加上步长直至达到最大值.
  • 当没有指定偏移量时，坐标直接对应值序列.
  • 偏移量可以以绝对距离的形式给出，或使用 Scaled. Scaled[1/2] 能把坐标点置于每个"晶胞"的中心.
  • CoordinateBoundsArray 中的值可以是 Quantity 对象.

范例

打开所有单元 关闭所有单元

基本范例  (3)

二维点的网格：

Wolfram Language code: CoordinateBoundsArray[{{3, 8}, {-1, 2}}]
Wolfram Language code: Graphics[Point[Flatten[%, 1]], Frame -> True]

指定离散化步长的三维点阵列：

Wolfram Language code: CoordinateBoundsArray[{{3, 6}, {-1, 2}, {0, Pi}}, {0.7, 1.5, Pi / 2.}]
Wolfram Language code: Graphics3D[Point[Flatten[%, 2]]]

返回网格晶胞的中心点：

Wolfram Language code: bounds = {{3, 8}, {-1, 2}};
Wolfram Language code: CoordinateBoundsArray[bounds, 1, Center]
Wolfram Language code: Graphics[Point[Flatten[%, 1]], Frame -> True, GridLines -> Range@@@bounds, PlotRange -> bounds]

范围  (6)

提供了坐标阵列的角落位置，采用默认的离散化值、偏移量和填充值：

Wolfram Language code: CoordinateBoundsArray[{{3, 8}, {-1, 2}, {0, 2}}]

为所有维度指定公共的离散化步长：

Wolfram Language code: CoordinateBoundsArray[{{3, 9}, {-2, 2}}, 2]

为不同维度指定各自晶胞的大小：

Wolfram Language code: CoordinateBoundsArray[{{3, 9}, {-2, 2}}, {2, 0.5}]

以 Quantity 对象作为参数：

Wolfram Language code: CoordinateBoundsArray[{Quantity[{3, 9}, "Meters"], Quantity[{-2, 2}, "Seconds"]}, {Quantity[4., "Feet"], Quantity[0.5, "Seconds"]}]
Wolfram Language code: Normal[%]

返回网格晶胞的中心点：

Wolfram Language code: bounds = {{6, 16}, {-2, 4}};
Wolfram Language code: CoordinateBoundsArray[bounds, 2, Center]
Wolfram Language code: Graphics[Point[Flatten[%, 1]], Frame -> True, GridLines -> {Range[6, 16, 2], Range[-2, 4, 2]}, PlotRange -> bounds]

数值偏移量被解释为绝对偏移量：

Wolfram Language code: CoordinateBoundsArray[bounds, 2, {0.5, 1.8}]
Wolfram Language code: Graphics[Point[Flatten[%, 1]], Frame -> True, GridLines -> {Range[6, 16, 2], Range[-2, 4, 2]}, PlotRange -> bounds]

用 Scaled 指定相对偏移量：

Wolfram Language code: CoordinateBoundsArray[bounds, 2, {Scaled[0.25], Scaled[0.9]}]

返回额外的点层或移除它们中的部分：

Wolfram Language code: bounds = {{3, 8}, {-1, 2}};
Wolfram Language code: CoordinateBoundsArray[bounds, 1, Center, {{-1, 3}, {2, 1}}]
Wolfram Language code: Graphics[Point[Flatten[%, 1]], Frame -> True, GridLines -> Range@@@bounds, PlotRange -> {{-1, 12}, {-5, 6}}]

指定分划数：

Wolfram Language code: CoordinateBoundsArray[{{3, 8}, {-1, 2}}, {Into[3], Into[2]}]
Wolfram Language code: Most[Dimensions[%]] - 1

应用  (1)

计算美国经纬度的界限：

Wolfram Language code: bounds = GeoBounds[Entity["Country", "UnitedStates"]]

用 CoordinateBoundsArray 生成坐标数组，步长为 2 度：

Wolfram Language code: pos = GeoPosition[CoordinateBoundsArray[bounds, 2]]

在地图上绘制这些坐标：

Wolfram Language code: GeoGraphics[{Point[pos], GeoBoundsRegion[bounds]}, GeoGridLines -> Automatic]

在柱面投影上绘制这些点：

Wolfram Language code: Show[%, GeoProjection -> "Mercator"]

属性和关系  (4)

CoordinateBounds 返回 0 偏移量的输入边界：

Wolfram Language code: CoordinateBoundsArray[{{3, 8}, {-1, 2}}]
Wolfram Language code: CoordinateBounds[%]

使用其它偏移量结果完全不同：

Wolfram Language code: CoordinateBoundsArray[{{3, 8}, {-1, 2}}, 1, Center]
Wolfram Language code: CoordinateBounds[%]

CoordinateBoundingBoxArray 使用角落位置代替范围列表：

Wolfram Language code: CoordinateBoundingBoxArray[{{3, -1, 2}, {8, 2, 4}}]
Wolfram Language code: % === CoordinateBoundsArray[{{3, 8}, {-1, 2}, {2, 4}}]

CoordinateBoundsArray 可以返回坐标列表的阵列，即使在只有一维的情况下：

Wolfram Language code: CoordinateBoundsArray[{{0, 10}}, 2]

Range 可以返回那些单独坐标的列表：

Wolfram Language code: Range[0, 10, 2]

CoordinateBoundsArray 用 Into 指定分划数目：

Wolfram Language code: CoordinateBoundsArray[{{0, 10}}, Into[5]]

Subdivide 可以返回那些单独坐标的列表：

Wolfram Language code: Subdivide[0, 10, 5]
Wolfram Research (2015)，CoordinateBoundsArray，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoordinateBoundsArray.html.

文本

Wolfram Research (2015)，CoordinateBoundsArray，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoordinateBoundsArray.html.

CMS

Wolfram 语言. 2015. "CoordinateBoundsArray." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CoordinateBoundsArray.html.

APA

Wolfram 语言. (2015). CoordinateBoundsArray. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CoordinateBoundsArray.html 年

BibTeX

@misc{reference.wolfram_2026_coordinateboundsarray, author="Wolfram Research", title="{CoordinateBoundsArray}", year="2015", howpublished="\url{https://reference.wolfram.com/language/ref/CoordinateBoundsArray.html}", note=[Accessed: 11-August-2026]}

BibLaTeX

@online{reference.wolfram_2026_coordinateboundsarray, organization={Wolfram Research}, title={CoordinateBoundsArray}, year={2015}, url={https://reference.wolfram.com/language/ref/CoordinateBoundsArray.html}, note=[Accessed: 11-August-2026]}