WOLFRAM

Wolfram 语言与系统参考资料中心

CoplanarPoints[{p1,p2,p3,p4,…,pn}]

检验点 p1,p2,p3,p4,…,pn 是否共面.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
基础应用  
几何  
属性和关系  
参见
相关指南
历史
按以下格式引用：

CoplanarPoints

CoplanarPoints[{p1,p2,p3,p4,…,pn}]

检验点 p1,p2,p3,p4,…,pn 是否共面.

更多信息

  • CoplanarPoints 也被称为线性相关.
  • 通常用于检验一组点是否位于同一平面上.
  • 若点 p4,…,pn 位于穿过点 p1、p2 和 p3 的平面上，则 CoplanarPoints[{p1,p2,p3,p4,…,pn}] 给出 True.
  • 对于共面点 p1、p2、p3 和 p4 来说，矩阵 {p2-p1,p3-p1,p4-p1} 的秩小于等于 2.

范例

打开所有单元 关闭所有单元

基本范例  (2)

点 {0,0,0}，{1,1,-2}，{-1,2,-1}，{3,-4,1} 共面：

Wolfram Language code: pts = {{0, 0, 0}, {1, 1, -2}, {-1, 2, -1}, {3, -4, 1}};
Wolfram Language code: CoplanarPoints[pts]

绘制这些点：

Wolfram Language code: Graphics3D[{InfinitePlane[pts[[1 ;; 3]]], Red, Point[pts]}]

求包含点 {0,0,0}, {1,1,-2} 和 {-1,2,-1} 的平面的方程式：

Wolfram Language code: CoplanarPoints[{{0, 0, 0}, {1, 1, -2}, {-1, 2, -1}, {x, y, z}}]

范围  (4)

CoplanarPoints 作用于二维点：

Wolfram Language code: CoplanarPoints[{{1, 2}, {3, 4}, {5, 6}}]

三维点：

Wolfram Language code: CoplanarPoints[{{1, 2, 1}, {3, 4, 1}, {5, 6, 1}, {7, 8, 1}}]

n 维点：

Wolfram Language code: CoplanarPoints[{{0, 0, 1, 1}, {1, 0, 1, 0}, {0, 1, 0, 1}, {0, 1, 1, 1}, {0, 0, 0, 1}}]

CoplanarPoints 作用于数字坐标：

Wolfram Language code: CoplanarPoints[{{1, 2}, {3, 4}, {5, 6}}]

符号坐标：

Wolfram Language code: CoplanarPoints[{{1, a, 1}, {a, 2, 1}, {1, 2, 1}, {a, b, c}}]

CoplanarPoints 用于一组坐标上：

Wolfram Language code: CoplanarPoints[{{1, 2, 1}, {3, 4, 1}, {5, 6, 1}, {7, 8, 1}}]

点的列表：

Wolfram Language code: CoplanarPoints[{Point[{b, 0, 1}], Point[{a, 1, 1}], Point[{a, 3, 1}], Point[{a, b, c}]}]

多个点：

Wolfram Language code: CoplanarPoints[Point[{{b, 0, 1}, {a, 1, 1}, {a, 3, 1}, {a, b, c}}]]

CoplanarPoints 用于较大的集合：

Wolfram Language code: pts = RandomPoint[Polygon[{{0, 0, 0}, {1, 0, 0}, {1, 1, 0}}], 10 ^ 6];
Wolfram Language code: CoplanarPoints[pts]//AbsoluteTiming

应用  (5)

基础应用  (4)

求两点位于穿过原点的平面上的条件：

Wolfram Language code: CoplanarPoints[{{0, 0, 0}, {0, 1, 0}, {a, 2, b}, {c, 3, d}}]

显式实例：

Wolfram Language code: {{a, 2, b}, {c, 3, d}} /. FindInstance[% && a ≠ 0, {a, b, c, d}, Reals, 3]

位于同一平面上的二维点：

Wolfram Language code: CoplanarPoints[{{1, 2}, {3, 4}, {5, 6}}]
Wolfram Language code: CoplanarPoints[RandomPoint[Disk[], 5000]]
Wolfram Language code: CoplanarPoints[RandomReal[1, {5000, 2}]]

求包含一个点击的平面的方程式：

Wolfram Language code: pts = {{0, 0, 0}, {1, 1, -2}, {-1, 2, -1}};
Wolfram Language code: CoplanarPoints[Append[pts, {x, y, z}]]

绘制共面点：

Wolfram Language code: pts = {{0, 0, 0}, {1, 0, 0}, {1, 1, 1}};
Wolfram Language code: CoplanarPoints[pts]
Wolfram Language code: Graphics3D[{InfinitePlane[pts], Red, PointSize[Large], Point[pts]}]

几何  (1)

多面体的一个面位于某平面上：

Wolfram Language code: poly = OuterPolyhedron[Polyhedron[{{-1/2, -1/2, -1/2}, {-1/2, -1/2, 1/2}, {-1/2, 1/2, -1/2}, {-1/2, 1/2, 1/2}, {1/2, -1/2, -1/2}, {1/2, -1/2, 1/2}, {1/2, 1/2, -1/2}, {1/2, 1/2, 1/2}}, {{8, 4, 2, 6}, {8, 6, 5, 7}, {8, 7, 3, 4}, {4, 3, 1, 2}, {1, 3, 7, 5}, {2, 1, 5, 6}}]];
Wolfram Language code: faces = poly[[2]]
Wolfram Language code: CoplanarPoints[PolyhedronCoordinates[poly][[#]]]& /@ faces

属性和关系  (5)

对于共面点而言，PositivelyOrientedPoints 返回 False：

Wolfram Language code: pts = {{0, 0, 0}, {1, 1, -2}, {-1, 2, -1}, {3, -4, 1}};
Wolfram Language code: {CoplanarPoints[pts], PositivelyOrientedPoints[pts]}

对于共面点而言，NegativelyOrientedPoints 返回 False：

Wolfram Language code: pts = {{0, 0, 0}, {1, 1, -2}, {-1, 2, -1}, {3, -4, 1}};
Wolfram Language code: {CoplanarPoints[pts], NegativelyOrientedPoints[pts]}

共线点也共面：

Wolfram Language code: pts = RandomPoint[Line[{{0, 0, 0}, {1, 1, 1}}], 5];
Wolfram Language code: {CollinearPoints[pts], CoplanarPoints[pts]}

使用 RegionMember 检验点是否共面：

Wolfram Language code: RegionMember[Line[{{0, 0, 1}, {1, 1, 1}}], {2, 2, 1}]
Wolfram Language code: CoplanarPoints[{{0, 0, 1}, {1, 1, 1}, {2, 2, 1}}]

使用 InfinitePlane 绘制图形图像：

Wolfram Language code: pts = {{0, 0, 0}, {1, 0, 0}, {1, 1, 1}};
Wolfram Language code: Graphics3D[{InfinitePlane[pts], Red, PointSize[Large], Point[pts]}]
Wolfram Research (2020)，CoplanarPoints，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoplanarPoints.html.

文本

Wolfram Research (2020)，CoplanarPoints，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CoplanarPoints.html.

CMS

Wolfram 语言. 2020. "CoplanarPoints." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CoplanarPoints.html.

APA

Wolfram 语言. (2020). CoplanarPoints. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CoplanarPoints.html 年

BibTeX

@misc{reference.wolfram_2026_coplanarpoints, author="Wolfram Research", title="{CoplanarPoints}", year="2020", howpublished="\url{https://reference.wolfram.com/language/ref/CoplanarPoints.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_coplanarpoints, organization={Wolfram Research}, title={CoplanarPoints}, year={2020}, url={https://reference.wolfram.com/language/ref/CoplanarPoints.html}, note=[Accessed: 07-September-2026]}