WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

CosineWindow[x]

x の余弦窓関数を表す．

CosineWindow[x,α]

指数 α を使う．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
考えられる問題  
関連項目
関連するガイド
履歴
引用書式

CosineWindow

CosineWindow[x]

x の余弦窓関数を表す．

CosineWindow[x,α]

指数 α を使う．

詳細

  • CosineWindowは，一般に，データを短いセグメントで処理する必要がある信号処理アプリケーションで使われる窓関数である．
  • 窓関数には，データ値を漸減して各セグメントの終りで0に近付ける平滑化効果がある．
  • CosineWindow[x,α]は， ではに等しく，その他の場合は0である．
  • CosineWindow[x]はCosineWindow[x,1]と等価である．
  • CosineWindowは自動的にリストに縫い込まれる．

例題

すべて開く すべて閉じる

例  (3)

1D余弦窓の形：

Wolfram Language code: Plot[CosineWindow[x], {x, -1, 1}]

2D余弦窓の形：

Wolfram Language code: Plot3D[CosineWindow[x]CosineWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

余弦窓を表す連続関数を抽出する：

Wolfram Language code: FunctionExpand[CosineWindow[x]]

パラメータ化された余弦窓：

Wolfram Language code: FunctionExpand[CosineWindow[x, α]]

スコープ  (6)

数値的に評価する：

Wolfram Language code: CosineWindow[0.1]

指定された指数を使った1D余弦窓の形：

Wolfram Language code: Plot[CosineWindow[x, 3], {x, -1, 1}]

パラメータ α の関数としての形の変化：

Wolfram Language code: Plot3D[CosineWindow[x, α], {α, 0, 5}, {x, -1, 1}]

平行移動され広げられた余弦窓：

Wolfram Language code: Plot[CosineWindow[(x - 1) / 2], {x, -1, 3}]

円形の台を持つ2D余弦窓：

Wolfram Language code: Plot3D[CosineWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

長さ15の離散余弦窓：

Wolfram Language code: ListPlot[Array[CosineWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

15×10の2Dの離散余弦窓：

Wolfram Language code: ListPointPlot3D[Array[CosineWindow[#1] CosineWindow[#2]&, {15, 10}, {{-1 / 2, 1 / 2}}], Filling -> Axis]

アプリケーション  (3)

長さ11の移動平均フィルタを作る：

Wolfram Language code: h = ConstantArray[1 / 11., 11]

余弦窓を使ってフィルタを漸減させる：

Wolfram Language code: w = Array[CosineWindow, Length[h], {-1 / 2, 1 / 2}]; fir = w h / Total[w h];

2つのフィルタのパワースペクトルの対数振幅プロット：

Wolfram Language code: LogLinearPlot[Evaluate[20Log[10, Abs@ListFourierSequenceTransform[#, ω]]& /@ {h, fir}], {ω, 0.1, Pi}, GridLines -> Automatic]

窓指定を使ってサンプルPowerSpectralDensityを計算する：

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

スペクトルを計算する：

Wolfram Language code: spec = PowerSpectralDensity[data, w, CosineWindow];

窓関数を使わずに計算されたスペクトル密度と比較する：

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

プロットは，窓がスペクトル密度を平坦化したことを示している：

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotRange -> All, PlotLegends -> {"no window", "with window"}]

この過程の理論的なスペクトル密度と比較する：

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

時系列推定に窓指定を使う：

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

スペクトル推定器に窓を指定する：

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> CosineWindow}]

特性と関係  (3)

CosineWindow[x,0]はディリクレ窓に等しい：

Wolfram Language code: FunctionExpand[CosineWindow[x, 0]] == FunctionExpand[DirichletWindow[x]]

余弦窓の下の面積：

Wolfram Language code: area = Integrate[CosineWindow[x], {x, -∞, ∞}]

正規化することで単位面積の窓を作る：

Wolfram Language code: Plot[{CosineWindow[x], CosineWindow[x] / area}, {x, -1, 1}]

余弦窓のフーリエ変換：

Wolfram Language code: f = FourierTransform[CosineWindow[x], x, w]

余弦窓のパワースペクトル：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 80}]

考えられる問題  (1)

Arrayに記号として渡す場合には，余弦窓の2Dサンプリングはサンプルの各行に異なる指数を用いる：

Wolfram Language code: Array[CosineWindow, {30, 30}, {{-.5, .5}}]//N//ListPlot3D

代りに純関数を使う：

Wolfram Language code: Array[CosineWindow[#1] CosineWindow[#2]&, {30, 30}, {{-1 / 2, 1 / 2}}]//ListPlot3D
Wolfram Research (2012), CosineWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/CosineWindow.html.

テキスト

Wolfram Research (2012), CosineWindow, Wolfram言語関数， https://reference.wolfram.com/language/ref/CosineWindow.html.

CMS

Wolfram Language. 2012. "CosineWindow." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/CosineWindow.html.

APA

Wolfram Language. (2012). CosineWindow. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/CosineWindow.html

BibTeX

@misc{reference.wolfram_2026_cosinewindow, author="Wolfram Research", title="{CosineWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CosineWindow.html}", note=[Accessed: 07-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cosinewindow, organization={Wolfram Research}, title={CosineWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/CosineWindow.html}, note=[Accessed: 07-September-2026]}