WOLFRAM

Wolfram 语言与系统参考资料中心

CosineWindow[x]

表示关于 x 的余弦窗函数.

CosineWindow[x,α]

使用参数 α.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
可能存在的问题  
参见
相关指南
历史
按以下格式引用：

CosineWindow

CosineWindow[x]

表示关于 x 的余弦窗函数.

CosineWindow[x,α]

使用参数 α.

更多信息

  • CosineWindow 是一个窗函数，通常用于需要对数据进行短片段处理的信号处理应用中.
  • 窗口函数通过在每个片段的末端将数据值逐渐减小到零的方法而具有平滑效果.
  • CosineWindow[x,α] 等于 （对于 ），否则为 0.
  • CosineWindow[x] 等价于 CosineWindow[x,1].
  • CosineWindow 动线性作用于列表.

范例

打开所有单元 关闭所有单元

基本范例  (3)

一维余弦窗的形状：

Wolfram Language code: Plot[CosineWindow[x], {x, -1, 1}]

二维余弦窗的形状：

Wolfram Language code: Plot3D[CosineWindow[x]CosineWindow[y], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

提取表示余弦窗的连续函数：

Wolfram Language code: FunctionExpand[CosineWindow[x]]

参数化余弦窗：

Wolfram Language code: FunctionExpand[CosineWindow[x, α]]

范围  (6)

数值计算：

Wolfram Language code: CosineWindow[0.1]

使用指定参数的一维余弦窗的形状：

Wolfram Language code: Plot[CosineWindow[x, 3], {x, -1, 1}]

以参数 α 的函数表示的形状变化：

Wolfram Language code: Plot3D[CosineWindow[x, α], {α, 0, 5}, {x, -1, 1}]

cosine 窗的变换和伸缩：

Wolfram Language code: Plot[CosineWindow[(x - 1) / 2], {x, -1, 3}]

在圆形支持下的二维余弦窗：

Wolfram Language code: Plot3D[CosineWindow[Sqrt[x ^ 2 + y ^ 2]], {x, -1, 1}, {y, -1, 1}, PlotRange -> All]

长度为15的离散余弦窗：

Wolfram Language code: ListPlot[Array[CosineWindow, 15, {-1 / 2, 1 / 2}], Filling -> Axis]

离散15×10 二维余弦窗：

Wolfram Language code: ListPointPlot3D[Array[CosineWindow[#1] CosineWindow[#2]&, {15, 10}, {{-1 / 2, 1 / 2}}], Filling -> Axis]

应用  (3)

创建长度为11的平均移动滤波器：

Wolfram Language code: h = ConstantArray[1 / 11., 11]

使用余弦窗对滤波器进行锥化：

Wolfram Language code: w = Array[CosineWindow, Length[h], {-1 / 2, 1 / 2}]; fir = w h / Total[w h];

两个滤波器的功率谱的对数幅度图：

Wolfram Language code: LogLinearPlot[Evaluate[20Log[10, Abs@ListFourierSequenceTransform[#, ω]]& /@ {h, fir}], {ω, 0.1, Pi}, GridLines -> Automatic]

使用窗指定计算样本 PowerSpectralDensity：

Wolfram Language code: proc = ARMAProcess[1, {.5}, {.3}, 1]; data = RandomFunction[proc, {50}];

计算谱：

Wolfram Language code: spec = PowerSpectralDensity[data, w, CosineWindow];

与不用窗函数计算得到的谱密度进行比较：

Wolfram Language code: sd = PowerSpectralDensity[data, w];
Wolfram Language code: sd === spec

图形显示窗使谱密度平滑：

Wolfram Language code: Plot[{sd, spec}, {w, -π, π}, PlotRange -> All, PlotLegends -> {"no window", "with window"}]

与过程的理论谱密度进行比较：

Wolfram Language code: Plot[{spec, Evaluate@PowerSpectralDensity[proc, w]}, {w, -π, π}, PlotLegends -> {"data", "process"}]

使用窗指定进行时间序列估计：

Wolfram Language code: data = RandomFunction[ARMAProcess[1, {.3}, {.4}, 1], {300}];

指定谱估计的窗：

Wolfram Language code: EstimatedProcess[data, ARMAProcess[1, 1], ProcessEstimator -> {"SpectralEstimator", "Window" -> CosineWindow}]

属性和关系  (3)

CosineWindow[x,0] 等价于狄利克雷窗：

Wolfram Language code: FunctionExpand[CosineWindow[x, 0]] == FunctionExpand[DirichletWindow[x]]

cosine 窗下的面积：

Wolfram Language code: area = Integrate[CosineWindow[x], {x, -∞, ∞}]

规范化以创建单位面积的窗：

Wolfram Language code: Plot[{CosineWindow[x], CosineWindow[x] / area}, {x, -1, 1}]

cosine 窗的傅里叶变换：

Wolfram Language code: f = FourierTransform[CosineWindow[x], x, w]

cosine 窗的功率谱：

Wolfram Language code: LogLinearPlot[20 Log[10, Abs[f]], {w, .1, 80}]

可能存在的问题  (1)

当作为符号传递给 Array 时，cosine 窗的二维采样对样本的每一行使用不同的参数：

Wolfram Language code: Array[CosineWindow, {30, 30}, {{-.5, .5}}]//N//ListPlot3D

使用纯函数：

Wolfram Language code: Array[CosineWindow[#1] CosineWindow[#2]&, {30, 30}, {{-1 / 2, 1 / 2}}]//ListPlot3D
Wolfram Research (2012)，CosineWindow，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CosineWindow.html.

文本

Wolfram Research (2012)，CosineWindow，Wolfram 语言函数，https://reference.wolfram.com/language/ref/CosineWindow.html.

CMS

Wolfram 语言. 2012. "CosineWindow." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/CosineWindow.html.

APA

Wolfram 语言. (2012). CosineWindow. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/CosineWindow.html 年

BibTeX

@misc{reference.wolfram_2026_cosinewindow, author="Wolfram Research", title="{CosineWindow}", year="2012", howpublished="\url{https://reference.wolfram.com/language/ref/CosineWindow.html}", note=[Accessed: 13-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cosinewindow, organization={Wolfram Research}, title={CosineWindow}, year={2012}, url={https://reference.wolfram.com/language/ref/CosineWindow.html}, note=[Accessed: 13-September-2026]}