CriticalSection

CriticalSection[var,expr]

並列計算のためのロック var を取得し，expr を評価し，ロック var を解放する．

CriticalSection[{var₁,var₂,…},expr]

すべての変数 var_iを同時にロックする．

詳細

任意の並列カーネル上で同時実行できる同じロック変数の危険域が最高で1つ許容される．
ロックとして使われる変数はマスターカーネルの値を持っていてはならない．
WithLock[var,expr]はCriticalSection[var,expr]に等しい．

例題

すべて開くすべて閉じる

例 (5)

1ブロックのコードを他のスレッドの干渉から保護する：

Wolfram Language code: SetSharedVariable[xs];Clear[xslock];

Wolfram Language code:

xs = 0;
ParallelDo[CriticalSection[xslock, xs = xs + 1], {10}];
xs

更新コードへのアクセスから保護しないと，サブカーネルが結果を上書きしてしまうかもしれない：

Wolfram Language code:

xs = 0;
ParallelDo[xs = xs + 1, {10}];
xs

ロック変数は sym[index]の形でもよい：

Wolfram Language code: ParallelTable[CriticalSection[{locks[Mod[i, 2]]}, i], {i, 10}]

インデックス付きの2つのロック変数を使って更新操作のソースインデックスと宛先インデックスを保護する：

Wolfram Language code:

Clear[locks];size = 10; bins = ConstantArray[0, size];
SetSharedVariable[bins]

Wolfram Language code:

ParallelDo[
	With[{i = RandomInteger[{1, size - 1}]}, CriticalSection[{locks[i], locks[i + 1]}, bins[[i]]++;bins[[i + 1]]--]], {100}];
bins

Wolfram Language code: Total[%]

アプリケーション (1)

別々の読書き操作はスレッドセーフではない：

Wolfram Language code: n = 0;SetSharedVariable[n]

Wolfram Language code: ParallelEvaluate[n = n + 1]

Wolfram Language code: n

CriticalSectionを使ってコードセクション全体を原子的にする：

Wolfram Language code: n = 0;SetSharedVariable[n];Clear[nlock]

Wolfram Language code: ParallelEvaluate[CriticalSection[nlock, n = n + 1]]

Wolfram Language code: n

特性と関係 (1)

ロックはカーネルIDを局所変数に書込むことで得られる：

Wolfram Language code: Monitor[ParallelEvaluate[CriticalSection[lock, Pause[0.5];$KernelID]], lock]

危険域の代りに共有関数を使って同期することができる：

Wolfram Language code:

mlist = {};
include[e_] := (mlist = Union[mlist, {e}];)
SetSharedFunction[include]

Wolfram Language code: ParallelDo[include[RandomInteger[10]], {10}]

Wolfram Language code: mlist

これより効率は下がるが，共有変数と危険域を使うこともできる：

Wolfram Language code:

slist = {};SetSharedVariable[slist];
Clear[lock]

Wolfram Language code: ParallelDo[e = RandomInteger[10];CriticalSection[lock, slist = Union[slist, {e}]], {10}]

Wolfram Language code: slist

WithLockはCriticalSectionがシンボルに動作するのと同じように動作する：

Wolfram Language code: SetSharedVariable[xs];

Wolfram Language code:

xs = 0;
ParallelDo[WithLock[xslock, xs = xs + 1], {10}];
xs

考えられる問題 (1)

ロック変数は危険域で使用される前に値を持ってはならない：

Wolfram Language code: Clear[lock]

Wolfram Language code: ParallelEvaluate[CriticalSection[lock, Print[$KernelID]]]

ロック変数に値があるときに起るデッドロックは放棄することで解消できる：

Wolfram Language code: lock = 5;

Wolfram Language code: ParallelEvaluate[CriticalSection[lock, Print[$KernelID]]]

おもしろい例題 (1)

デッドロックが回避できる「食事をする哲学者」：

Wolfram Language code: rp := Pause[RandomReal[4]];

Wolfram Language code:

PrintTemporary[Dynamic[Array[forks, $KernelCount]]];
Clear[forks];forks[_] := Null;
With[{nf = $KernelCount}, 
	ParallelTable[
	With[{i1 = i, i2 = Mod[i + 1, nf, 1]}, 
	Do[Print[i, " thinking"];rp;Print[i, " hungry"];
	CriticalSection[{forks[i1], forks[i2]}, Print[i, " eating"];rp], 
	{2}]], 
	{i, nf}]];