Wolfram 语言与系统参考资料中心

CriticalSection

CriticalSection[var,expr]

为并行计算获取锁定 var，计算 expr，然后解开锁定 var.

CriticalSection[{var₁,var₂,…},expr]

同时锁定所有变量 var_i.

范例

打开所有单元关闭所有单元

基本范例 (1)

保护代码块不受其它线程的干扰：

Wolfram Language code: SetSharedVariable[xs];Clear[xslock];

Wolfram Language code:

xs = 0;
ParallelDo[CriticalSection[xslock, xs = xs + 1], {10}];
xs

如果不对进入更新代码的途径加以保护，子内核可能会覆盖结果：

Wolfram Language code:

xs = 0;
ParallelDo[xs = xs + 1, {10}];
xs

范围 (2)

锁定变量的形式可以是 sym[index]:

Wolfram Language code: ParallelTable[CriticalSection[{locks[Mod[i, 2]]}, i], {i, 10}]

使用两个索引锁定变量来保护更新操作的源索引和目标索引：

Wolfram Language code:

Clear[locks];size = 10; bins = ConstantArray[0, size];
SetSharedVariable[bins]

Wolfram Language code:

ParallelDo[
	With[{i = RandomInteger[{1, size - 1}]}, CriticalSection[{locks[i], locks[i + 1]}, bins[[i]]++;bins[[i + 1]]--]], {100}];
bins

Wolfram Language code: Total[%]

应用 (1)

单独的读写操作不是线程安全的：

Wolfram Language code: n = 0;SetSharedVariable[n]

Wolfram Language code: ParallelEvaluate[n = n + 1]

Wolfram Language code: n

使用 CriticalSection 使整个代码段不可分割（atomic）：

Wolfram Language code: n = 0;SetSharedVariable[n];Clear[nlock]

Wolfram Language code: ParallelEvaluate[CriticalSection[nlock, n = n + 1]]

Wolfram Language code: n

属性和关系 (3)

通过将内核的 ID 写入锁定变量来获得锁：

Wolfram Language code: Monitor[ParallelEvaluate[CriticalSection[lock, Pause[0.5];$KernelID]], lock]

共享函数可用于临界区的同步化：

Wolfram Language code:

mlist = {};
include[e_] := (mlist = Union[mlist, {e}];)
SetSharedFunction[include]

Wolfram Language code: ParallelDo[include[RandomInteger[10]], {10}]

Wolfram Language code: mlist

使用共享变量和临界区效率较低：

Wolfram Language code:

slist = {};SetSharedVariable[slist];
Clear[lock]

Wolfram Language code: ParallelDo[e = RandomInteger[10];CriticalSection[lock, slist = Union[slist, {e}]], {10}]

Wolfram Language code: slist

WithLock 与 CriticalSection 处理符号的方式相同：

Wolfram Language code: SetSharedVariable[xs];

Wolfram Language code:

xs = 0;
ParallelDo[WithLock[xslock, xs = xs + 1], {10}];
xs

可能存在的问题 (1)

锁定变量在其被用于一个临界区之前不能有值：

Wolfram Language code: Clear[lock]

Wolfram Language code: ParallelEvaluate[CriticalSection[lock, Print[$KernelID]]]

当锁定变量确实有一个值时出现的死锁可以通过中止来打破：

Wolfram Language code: lock = 5;

Wolfram Language code: ParallelEvaluate[CriticalSection[lock, Print[$KernelID]]]

巧妙范例 (1)

进餐的哲学家问题，无死锁：

Wolfram Language code: rp := Pause[RandomReal[4]];

Wolfram Language code:

PrintTemporary[Dynamic[Array[forks, $KernelCount]]];
Clear[forks];forks[_] := Null;
With[{nf = $KernelCount}, 
	ParallelTable[
	With[{i1 = i, i2 = Mod[i + 1, nf, 1]}, 
	Do[Print[i, " thinking"];rp;Print[i, " hungry"];
	CriticalSection[{forks[i1], forks[i2]}, Print[i, " eating"];rp], 
	{2}]], 
	{i, nf}]];