WOLFRAM

Wolfram言語 ＆ システムドキュメントセンター

Cyclotomic[n,x]

x について n 次の円周等分多項式を与える．

詳細
Details and Options Details and Options
例題  
例  
スコープ  
アプリケーション  
特性と関係  
おもしろい例題  
関連項目
テクニカルノート
関連するガイド
関連リンク
履歴
引用書式

Cyclotomic

Cyclotomic[n,x]

x について n 次の円周等分多項式を与える．

詳細

  • 第 次の円周等分多項式 はと定義される．この積は より小さく，また に対して互いに素である整数 について取られる．

例題

すべて開く すべて閉じる

例  (1)

5番目の円周等分多項式を与える：

Wolfram Language code: Cyclotomic[5, x]

根はの原始の五次の根である：

Wolfram Language code: Solve[Cyclotomic[5, x] == 0, x]

スコープ  (1)

TraditionalFormによる表示：

Wolfram Language code: Cyclotomic[n, x]//TraditionalForm

アプリケーション  (6)

因数分解した多項式をCyclotomicと比較する：

Wolfram Language code: Factor[x ^ 11 - 1]
Wolfram Language code: Cyclotomic[11, x]

1における連続する円周等分多項式の値：

Wolfram Language code: Table[Cyclotomic[n, 1], {n, 2, 20}]

を小数展開したときの循環節が一意的であるunique primesを計算する：

Wolfram Language code: up[n_] := If[Length[#] === 1, #[[1, 1]]]&[FactorInteger[Cyclotomic[n, 10] / GCD[Cyclotomic[n, 10], n]]]
Wolfram Language code: Select[Table[up[n], {n, 30}], NumberQ]
Wolfram Language code: RealDigits[1 / %]//Column

円周等分多項式をプロットする：

Wolfram Language code: Plot[Evaluate[Table[Cyclotomic[k, z], {k, 0, 10}]], {z, -1, 1}]

Cyclotomicの根の引数をプロットする：

Wolfram Language code: ListPlot[Table[{Arg[#], n}& /@ (z /. NSolve[Cyclotomic[n, z] == 0, z]), {n, 50}], PlotMarkers -> None]

円周等分多項式の項の次数と数をプロットする：

Wolfram Language code: {ListPlot[Table[Exponent[Cyclotomic[n, x], x], {n, 500}]], ListPlot[Table[Length[Cyclotomic[n, x]], {n, 500}]]}

特性と関係  (7)

円周等分多項式を積分する：

Wolfram Language code: Integrate[1 / Cyclotomic[3, x], x]

円周等分多項式を拡大体上で因数分解する：

Wolfram Language code: Factor[Cyclotomic[5, x]]
Wolfram Language code: Factor[Cyclotomic[5, x], Extension -> {(-1) ^ (1 / 5)}]

定義から円周等分多項式を生成する：

Wolfram Language code: c[n_, z_] := Collect[Product[z - E^(2 π I k/n), {k, Select[Range[n], CoprimeQ[#, n]&]}], z, FullSimplify]
Wolfram Language code: Table[c[n, z], {n, 10}]

について有効な別の定義を使う：

Wolfram Language code: c[n_, z_] := Cancel[Times@@((1 - z ^ #) ^ MoebiusMu[n / #]& /@ Divisors[n])]
Wolfram Language code: Table[c[n, z], {n, 6}]
Wolfram Language code: Table[Cyclotomic[n, z], {n, 6}]

円周等分多項式の積を形成する：

Wolfram Language code: f[n_, z_] := Expand[Times@@(Cyclotomic[#, z]& /@ Divisors[n])]
Wolfram Language code: Table[f[n, z], {n, 1, 8}]

複素平面上で円周等分多項式の逆関数のリーマン(Riemann) 面をプロットする：

Wolfram Language code: ParametricPlot3D[Evaluate[{Re[Cyclotomic[10, x + I y]], Im[Cyclotomic[10, x + I y]], x}], {x, -2, 2}, {y, -2, 2}, Mesh -> False, BoxRatios -> 1]

50次の円周等分多項式の連続する導関数の複素根をプロットする：

Wolfram Language code: Graphics[Point[Flatten[Map[{Re[#], Im[#]}&, Table[z /. NSolve[D[Cyclotomic[50, z], {z, k}] == 0, z], {k, EulerPhi[50] - 2}], {-1}], 1]]]

おもしろい例題  (2)

係数が0と±1以外の最初の円周等分多項式：

Wolfram Language code: Cyclotomic[105, x]

連続する円周等分多項式の非零係数：

Wolfram Language code: ArrayPlot[CoefficientList[Array[Cyclotomic[#, x]&, 40], x], ColorRules -> {0 -> StandardYellow, _ -> StandardBlue}]
Wolfram Research (1988), Cyclotomic, Wolfram言語関数， https://reference.wolfram.com/language/ref/Cyclotomic.html.

テキスト

Wolfram Research (1988), Cyclotomic, Wolfram言語関数， https://reference.wolfram.com/language/ref/Cyclotomic.html.

CMS

Wolfram Language. 1988. "Cyclotomic." Wolfram Language & System Documentation Center. Wolfram Research. https://reference.wolfram.com/language/ref/Cyclotomic.html.

APA

Wolfram Language. (1988). Cyclotomic. Wolfram Language & System Documentation Center. Retrieved from https://reference.wolfram.com/language/ref/Cyclotomic.html

BibTeX

@misc{reference.wolfram_2026_cyclotomic, author="Wolfram Research", title="{Cyclotomic}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/Cyclotomic.html}", note=[Accessed: 10-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cyclotomic, organization={Wolfram Research}, title={Cyclotomic}, year={1988}, url={https://reference.wolfram.com/language/ref/Cyclotomic.html}, note=[Accessed: 10-September-2026]}