WOLFRAM

Wolfram 语言与系统参考资料中心

Cyclotomic[n,x]

给出关于 x 的 n 阶割圆多项式.

更多信息
Details and Options Details and Options
范例  
基本范例  
范围  
应用  
属性和关系  
巧妙范例  
参见
技术笔记
相关指南
相关链接
历史
按以下格式引用：

Cyclotomic

Cyclotomic[n,x]

给出关于 x 的 n 阶割圆多项式.

更多信息

  • 阶数为 的割圆多项式 定义为 ，其中乘积取遍小于 且相对 为素的所有 .

范例

打开所有单元 关闭所有单元

基本范例  (1)

给出第五个割圆多项式：

Wolfram Language code: Cyclotomic[5, x]

这些根是 的5次原根：

Wolfram Language code: Solve[Cyclotomic[5, x] == 0, x]

范围  (1)

TraditionalForm 格式：

Wolfram Language code: Cyclotomic[n, x]//TraditionalForm

应用  (6)

比较一个因式分解的多项式与 Cyclotomic：

Wolfram Language code: Factor[x ^ 11 - 1]
Wolfram Language code: Cyclotomic[11, x]

连续割圆多项式在 1 处的值：

Wolfram Language code: Table[Cyclotomic[n, 1], {n, 2, 20}]

对于 的十进制展开具有独特周期 唯一素数 (unique primes) 进行计算：

Wolfram Language code: up[n_] := If[Length[#] === 1, #[[1, 1]]]&[FactorInteger[Cyclotomic[n, 10] / GCD[Cyclotomic[n, 10], n]]]
Wolfram Language code: Select[Table[up[n], {n, 30}], NumberQ]
Wolfram Language code: RealDigits[1 / %]//Column

绘制割圆多项式：

Wolfram Language code: Plot[Evaluate[Table[Cyclotomic[k, z], {k, 0, 10}]], {z, -1, 1}]

绘制 Cyclotomic 根的变量：

Wolfram Language code: ListPlot[Table[{Arg[#], n}& /@ (z /. NSolve[Cyclotomic[n, z] == 0, z]), {n, 50}], PlotMarkers -> None]

绘制割圆多项式的次数和项数：

Wolfram Language code: {ListPlot[Table[Exponent[Cyclotomic[n, x], x], {n, 500}]], ListPlot[Table[Length[Cyclotomic[n, x]], {n, 500}]]}

属性和关系  (7)

Integrate a cyclotomic polynomial:

Wolfram Language code: Integrate[1 / Cyclotomic[3, x], x]

在扩展域内，分解割圆多项式：

Wolfram Language code: Factor[Cyclotomic[5, x]]
Wolfram Language code: Factor[Cyclotomic[5, x], Extension -> {(-1) ^ (1 / 5)}]

根据定义创建一个割圆多项式：

Wolfram Language code: c[n_, z_] := Collect[Product[z - E^(2 π I k/n), {k, Select[Range[n], CoprimeQ[#, n]&]}], z, FullSimplify]
Wolfram Language code: Table[c[n, z], {n, 10}]

使用另一种定义，对于 有效：

Wolfram Language code: c[n_, z_] := Cancel[Times@@((1 - z ^ #) ^ MoebiusMu[n / #]& /@ Divisors[n])]
Wolfram Language code: Table[c[n, z], {n, 6}]
Wolfram Language code: Table[Cyclotomic[n, z], {n, 6}]

形成割圆多项式的积：

Wolfram Language code: f[n_, z_] := Expand[Times@@(Cyclotomic[#, z]& /@ Divisors[n])]
Wolfram Language code: Table[f[n, z], {n, 1, 8}]

在复平面内，绘制一个割圆多项式逆的黎曼曲面：

Wolfram Language code: ParametricPlot3D[Evaluate[{Re[Cyclotomic[10, x + I y]], Im[Cyclotomic[10, x + I y]], x}], {x, -2, 2}, {y, -2, 2}, Mesh -> False, BoxRatios -> 1]

绘制 50 阶割圆多项式的连续导数的复数根：

Wolfram Language code: Graphics[Point[Flatten[Map[{Re[#], Im[#]}&, Table[z /. NSolve[D[Cyclotomic[50, z], {z, k}] == 0, z], {k, EulerPhi[50] - 2}], {-1}], 1]]]

巧妙范例  (2)

系数非 0 或 ±1 的第一个割圆多项式：

Wolfram Language code: Cyclotomic[105, x]

连续割圆多项式的非零系数：

Wolfram Language code: ArrayPlot[CoefficientList[Array[Cyclotomic[#, x]&, 40], x], ColorRules -> {0 -> StandardYellow, _ -> StandardBlue}]
Wolfram Research (1988)，Cyclotomic，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Cyclotomic.html.

文本

Wolfram Research (1988)，Cyclotomic，Wolfram 语言函数，https://reference.wolfram.com/language/ref/Cyclotomic.html.

CMS

Wolfram 语言. 1988. "Cyclotomic." Wolfram 语言与系统参考资料中心. Wolfram Research. https://reference.wolfram.com/language/ref/Cyclotomic.html.

APA

Wolfram 语言. (1988). Cyclotomic. Wolfram 语言与系统参考资料中心. 追溯自 https://reference.wolfram.com/language/ref/Cyclotomic.html 年

BibTeX

@misc{reference.wolfram_2026_cyclotomic, author="Wolfram Research", title="{Cyclotomic}", year="1988", howpublished="\url{https://reference.wolfram.com/language/ref/Cyclotomic.html}", note=[Accessed: 11-September-2026]}

BibLaTeX

@online{reference.wolfram_2026_cyclotomic, organization={Wolfram Research}, title={Cyclotomic}, year={1988}, url={https://reference.wolfram.com/language/ref/Cyclotomic.html}, note=[Accessed: 11-September-2026]}